Windows 10 Dark Mode & VB6 apps

[Krool]

I guess there are a few more (new) themes available since Mith posted the list on June 2023.

For example for the TabStrip the following works properly. (TabStrip1.BackColor = vbBlack to conform to Form's BackColor)

SetWindowTheme TabStrip1.hWnd, 0, StrPtr("DarkMode_DarkTheme::Tab")

[Krool]

OptionButton with white text color. (NO Hooks needed !!)

SetWindowTheme OptionButtonW1.hWnd, StrPtr("DarkMode_DarkTheme"), 0

However, you should set the ForeColor of the OptionButtonW (or CheckBoxW) still to a white color so the focus rect is then visible on the dark theme.

I "guess" finally they do the "proper" themes with "DarkMode_DarkTheme". So, "DarkTheme" is the way to go for win32 controls instead of "Explorer".

[Krool]

Here a list of all the "_DarkTheme" names. I guess these should be preferred over the "_Explorer".



And yes, for example the Status bar (previously DarkMode::ExplorerStatusBar) did not theme the size grip. Now it is done properly. (DarkMode_DarkTheme::Status)



Probably will add a VisualTheme property to all VBCCR controls where you can set between 0 - Normal and 1 - Dark and it will take care everything.
But some controls seems to be still missing. DatePicker and MonthView for example.

[wqweto]

Looks promising. I’ll test these on Aero Lite theme.

[Mith]

OptionButton with white text color. (NO Hooks needed !!)

SetWindowTheme OptionButtonW1.hWnd, StrPtr("DarkMode_DarkTheme"), 0

Doenst work for me using Windows 10. I guess this is only supported with win11?

edit: i tested my app with win11 and "DarkMode_DarkTheme" and i can confirm that this works with win11 (OptionButton /checkbox) but unfortunately not with any older windows version like win10!

[Mith]

the background-color of the ImageCombo-control is not correct with "DarkMode_DarkTheme" (win11) because of the rounded corners:



can we get a background-color property for this control?

i guess an additional background-color property for the dropdown-list is not possible, or?

Call SetDarkMode_DarkTheme(icFolderIcon.hwnd)
Call SetDarkMode_DarkTheme(icFolderIcon.hWndEdit)
Call SetDarkMode_DarkTheme(icFolderIcon.hWndCombo)
Call SetDarkMode_DarkTheme(icFolderIcon.hWndList)

[Mith]

i tried to fix the ImageCombo-background-color issue with this code, but it doesnt work.

any ideas?

Call SetControlBackColor(icFolderIcon.hwnd, gDarkMode_BackColor)
Call SetControlBackColor(icFolderIcon.hWndEdit, gDarkMode_BackColor)
Call SetControlBackColor(icFolderIcon.hWndCombo, gDarkMode_BackColor)
Call SetControlBackColor(icFolderIcon.hWndUserControl, gDarkMode_BackColor)
Public Sub SetControlBackColor(ByRef hwnd As Long, ByVal New_Color As OLE_COLOR)
        'Const SB_SETBKCOLOR = &H2001
10      OleTranslateColor New_Color, 0, New_Color
20      SendMessageAny hwnd, SB_SETBKCOLOR, 0, ByVal New_Color
End Sub

[Mith]

There is another display-issue when using the ListViewW-control with Windows11.

Every column in Report Mode (.GridLines=false) has a light border at the right side:



This right-border is also shown when a column is hidden (.width=0):



This issue doesnt happen when using Win10.

Does anyone know how to fix this?

Call SetDarkMode_DarkTheme(ListView.hwnd)
Call SetDarkMode_DarkTheme(ListView.hwndHeader)

[Crapahute]

Doenst work for me using Windows 10. I guess this is only supported with win11?

edit: i tested my app with win11 and "DarkMode_DarkTheme" and i can confirm that this works with win11 (OptionButton /checkbox) but unfortunately not with any older windows version like win10!

It doesn't work for me either with Windows 11 23H2

[Mith]

It doesn't work for me either with Windows 11 23H2

My test was with 25H2 (26200.7462).

[Chris_G33]

I do not get that working for richtextcontrols (krools VBCCR)
None is working:
SetWindowTheme c.hWnd, StrPtr("DarkMode_DarkTheme"), 0&
SetWindowTheme c.hWndUserControl, StrPtr("DarkMode_DarkTheme"), 0&
SetWindowTheme c.hWnd, StrPtr("DarkMode_Explorer"), 0&
SetWindowTheme c.hWndUserControl, StrPtr("DarkMode_Explorer"), 0&

Can anyone please post code for that. Thank you

[Mith]

I do not get that working for richtextcontrols (krools VBCCR)
Can anyone please post code for that. Thank you

Call SetDarkModeExplorer(RTB1.hwnd)
RTB1.TextMode = 0 'Richtext

{load or set text}

With RTB1
.SelStart = 0
.SelLength = .textLength
.SelColor = gDarkMode_FontColor
.SelLength = 0
End With

[Chris_G33]

Call SetDarkModeExplorer(RTB1.hwnd)
...

Thanks, but what does SetDarkModeExplorer(...) do? Code?

[Chris_G33]

Ah, I got it working:
ScrollBars = vbBoth
has to be set before SetWindowTheme

[Krool]

the background-color of the ImageCombo-control is not correct with "DarkMode_DarkTheme" (win11) because of the rounded corners:



can we get a background-color property for this control?

i guess an additional background-color property for the dropdown-list is not possible, or?

Call SetDarkMode_DarkTheme(icFolderIcon.hwnd)
Call SetDarkMode_DarkTheme(icFolderIcon.hWndEdit)
Call SetDarkMode_DarkTheme(icFolderIcon.hWndCombo)
Call SetDarkMode_DarkTheme(icFolderIcon.hWndList)

Yes. Need to implement it. The edges are easy. The rest needs to involve some API hooks upon WM_DRAWITEM. It's on my list.

[Krool]

the background-color of the ImageCombo-control is not correct with "DarkMode_DarkTheme" (win11) because of the rounded corners:



can we get a background-color property for this control?

i guess an additional background-color property for the dropdown-list is not possible, or?

Call SetDarkMode_DarkTheme(icFolderIcon.hwnd)
Call SetDarkMode_DarkTheme(icFolderIcon.hWndEdit)
Call SetDarkMode_DarkTheme(icFolderIcon.hWndCombo)
Call SetDarkMode_DarkTheme(icFolderIcon.hWndList)

ImageCombo has now BackColor/ForeColor property.

[Mith]

Krool released OCX v1.8.105 with support for BackColor/ForeColor and .AllowImageHighlight for the ImageCombo!

The update fixes the white corners (Win11) and the white background color of the DropDown list (win10) by using .BackColor!

Bonus: .AllowImageHighlight=false prevents the icon from being displayed with a shadow layer after the user made a selection in the DropDown list.

Dark Mode Win10:



Dark Mode Win11:

[Crapahute]

I have improved my test program :
TestDarkMode.zip

I have some questions, in particular (commented lines don't work for me):

Progressbar

Select Case TypeName(obj)
            
            Case "ProgressBar"
                ' ???
'                SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode_DarkTheme::Progress")
'                obj.BackColor = FRMBACKCOLOR
'                obj.ForeColor = FRMFORECOLOR
'                bFound = True

TabStrip and CoolBar

Case "TabStrip"
                'obj.VisualStyles = False
                'SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode_DarkTheme::Tab")
                'SetWindowTheme obj.hwnd, StrPtr("DarkMode_Explorer"), 0&
                'SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode::ExplorerStatusBar") '<- ???
                SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode::FileExplorerBannerContainer") '<- ???
                obj.BackColor = FRMBACKCOLOR
                bFound = True
                
            Case "CoolBar"
                SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode::FileExplorerBannerContainer") '<- ???
                obj.BackColor = FRMBACKCOLOR
                obj.ForeColor = FRMFORECOLOR
                bFound = True

[Mith]

afaik you only have to use StrPtr("DarkMode_DarkTheme") without ":: ...". does this help?

[Crapahute]

Yes it does for ProgressBar and Coolbar. Not for TabStrip.

            Case "TabStrip"
                'SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode_DarkTheme")
                SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode::FileExplorerBannerContainer") '<- ???
                obj.BackColor = FRMBACKCOLOR
                bFound = True
                
            Case "CoolBar"
                SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode_DarkTheme")
                obj.BackColor = FRMBACKCOLOR
                obj.ForeColor = FRMFORECOLOR
                bFound = True
            
            Case "ProgressBar"
                SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode_DarkTheme")
                obj.BackColor = FRMBACKCOLOR
                obj.ForeColor = FRMFORECOLOR
                bFound = True

[Mith]

Yes it does for ProgressBar and Coolbar. Not for TabStrip.

Currently there is no dark mode support from MS for the TabStrip control ("SysTabControl32").

More information if you want to dive deeper: https://community.notepad-plus-plus....herit-the-mode

[Crapahute]

Ok, then I stick with

SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode::FileExplorerBannerContainer")

[Mith]

Ok, then I stick with

SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode::FileExplorerBannerContainer")

Does this change any color at the TabStrip? I see no difference with Win10.

[Crapahute]

Here is what I get with my settings with Windows 11 (23H2)

TabStrip is dark.

Public Sub SetDarkMode(frm As Form, Optional bForceDarkMode As Boolean)
'
' At the end of your Form_Load(), put SetDarkMode Me
'
    If DarkMode = DRKMD_AUTO Then DarkMode = TestDarkMode
    If DarkMode = DRKMD_OFF And bForceDarkMode = False Then Exit Sub

    ' Title Bar
Dim bValue As Long
   bValue = 1
   Call DwmSetWindowAttribute(frm.hwnd, DWMWA_USE_IMMERSIVE_DARK_MODE, bValue, LenB(bValue))
    
    ' Form colors
    frm.BackColor = FRMBACKCOLOR
    frm.ForeColor = FRMFORECOLOR

Dim obj         As Object
Dim i           As Long
Dim idx         As Long
Dim lbl         As Label
Dim hCombo      As Long
Dim hUpDown     As Long
Dim pnl         As Object
Dim bFound      As Boolean
'Dim hTips As Long
'Const LVM_FIRST = &H1000
'Const LVM_GETTOOLTIPS = (LVM_FIRST + 78)

    For Each obj In frm.Controls
        
        bFound = False
        
        'ComboBox
        If (TypeOf obj Is VB.ComboBox) Then
            SetWindowTheme obj.hwnd, StrPtr("DarkMode_CFD"), 0&
            'SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode::Combobox")
            If obj.BackColor = vbWindowBackground Then obj.BackColor = FRMBACKCOLOR
            If obj.ForeColor = vbWindowText Then obj.ForeColor = FRMFORECOLOR
            bFound = True
        End If
        'Line
        If (TypeOf obj Is VB.Line) Then
            If obj.BorderColor = vbWindowText Then obj.BorderColor = WINDOWTEXTCOLOR
            bFound = True
        End If
        'Shape
        If (TypeOf obj Is VB.Shape) Then
            If obj.BorderColor = vbWindowText Then obj.BorderColor = WINDOWTEXTCOLOR
            If obj.FillColor = vbBlack Then obj.FillColor = vbWhite
            bFound = True
        End If
        'PictureBox
        If (TypeOf obj Is VB.PictureBox) Then
            If obj.BackColor = vbButtonFace Then obj.BackColor = FRMBACKCOLOR
            If obj.ForeColor = vbButtonText Then obj.ForeColor = FRMFORECOLOR
            If obj.Appearance = 0 Then
                If obj.BackColor = vbWindowBackground Then obj.BackColor = FRMBACKCOLOR
                If obj.ForeColor = vbWindowText Then obj.ForeColor = FRMFORECOLOR
            End If
            bFound = True
        End If
        
        '
        ' VBCCR ---------------------------------------------------------------------------------[
        '
        If bFound = False Then
            On Error Resume Next
            Select Case TypeName(obj)
            
            
            
            Case "ComboBoxW"
                SetWindowTheme obj.hwnd, StrPtr("DarkMode_CFD"), 0&
                'SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode_DarkTheme::Combobox")
                If obj.BackColor = vbWindowBackground Then obj.BackColor = FRMBACKCOLOR
                If obj.ForeColor = vbWindowText Then obj.ForeColor = FRMFORECOLOR
                bFound = True
                
            Case "VirtualCombo"
                SetWindowTheme obj.hwnd, StrPtr("DarkMode_CFD"), 0&
                If obj.BackColor = vbWindowBackground Then obj.BackColor = FRMBACKCOLOR
                If obj.ForeColor = vbWindowText Then obj.ForeColor = FRMFORECOLOR
                bFound = True
            Case "FontCombo"
                SetWindowTheme obj.hwnd, StrPtr("DarkMode_CFD"), 0&
                If obj.BackColor = vbWindowBackground Then obj.BackColor = FRMBACKCOLOR
                If obj.ForeColor = vbWindowText Then obj.ForeColor = FRMFORECOLOR
                bFound = True
                
            Case "ImageCombo"
                obj.VisualStyles = False
                'SetWindowTheme obj.hwnd, StrPtr("DarkMode_CFD"), 0&
                SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode_DarkTheme::Combobox")
                hCombo = FindWindowEx(obj.hwnd, 0, "ComboBox", vbNullString)
                If hCombo <> 0 Then SetWindowTheme hCombo, StrPtr("DarkMode_CFD"), 0&
                On Error Resume Next
                obj.BackColor = FRMBACKCOLOR
                obj.ForeColor = FRMFORECOLOR
                On Error GoTo 0
                bFound = True
                
            Case "ListView"
                SetWindowTheme obj.hwnd, StrPtr("DarkMode_Explorer"), 0&
                'SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode::ListView")
                SetWindowTheme obj.hWndHeader, StrPtr("DarkMode_ItemsView"), 0&
                For i = 1 To obj.ColumnHeaders.Count ' réglage des colonnes
                    obj.ColumnHeaders(i).ForeColor = CMDFORECOLOR
                Next i
                ' does not work for me or I'm missing something :
                'hTips = SendMessage(obj.hWnd, LVM_GETTOOLTIPS, 0, ByVal 0)
                'Call Win32SetWindowTheme(hTips, "DarkMode_Explorer")
                If obj.BackColor = vbWindowBackground Then obj.BackColor = FRMBACKCOLOR
                If obj.ForeColor = vbWindowText Then obj.ForeColor = FRMFORECOLOR
                bFound = True
                
            Case "ToolBar"
                'SetWindowTheme obj.hwnd, StrPtr("DarkMode_Explorer"), 0&
                SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode::Toolbar")
                'SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode_DarkTheme::Toolbar")
                For i = 1 To obj.Buttons.Count
                    obj.Buttons(i).ForeColor = TLBFORECOLOR
                Next i
                If obj.BackColor = vbButtonFace Then obj.BackColor = FRMBACKCOLOR
                If obj.InsertMarkColor = vbBlack Then obj.InsertMarkColor = vbWhite
                bFound = True
            
            Case "DTPicker"
                With obj
                .VisualStyles = False
                SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode::FileExplorerBannerContainer")
                .CalendarBackColor = FRMBACKCOLOR
                .CalendarForeColor = FRMFORECOLOR
                .CalendarTitleBackColor = FRMBACKCOLOR
                .CalendarTitleForeColor = FRMFORECOLOR
                If .UpDown = True Then
                    hUpDown = FindWindowEx(obj.hwnd, 0&, "msctls_updown32", "")
                    If hUpDown <> 0 Then SetWindowTheme hUpDown, StrPtr("DarkMode_Explorer"), 0&
                End If
                End With
                bFound = True
                
            Case "MonthView"
                With obj
                '.VisualStyles = False
                SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode::FileExplorerBannerContainer")
                .BackColor = FRMBACKCOLOR
                .ForeColor = FRMFORECOLOR
                .TitleBackColor = FRMBACKCOLOR
                .TitleForeColor = FRMFORECOLOR
                End With
                bFound = True
                
            Case "RichTextBox"
                'SetWindowTheme obj.hwnd, StrPtr("DarkMode_Explorer"), 0&
                obj.BorderStyle = 0
                obj.SelStart = 0
                obj.SelLength = Len(obj.Text)
                If obj.SelColor = vbBlack Then obj.SelColor = TXTFORECOLOR
                If obj.BackColor = vbWindowBackground Then obj.BackColor = TXTBACKCOLOR
                 bFound = True
                 
            Case "StatusBar"
                SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode::ExplorerStatusBar")
                'SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode_DarkTheme::Status")
                For Each pnl In obj.Panels
                    pnl.ForeColor = TXTFORECOLOR
                Next
                bFound = True
                
            Case "TabStrip"
                'SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode_DarkTheme")
                SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode::FileExplorerBannerContainer") '<- ???
                obj.BackColor = FRMBACKCOLOR
                bFound = True
                
            Case "CoolBar"
                SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode_DarkTheme")
                obj.BackColor = FRMBACKCOLOR
                obj.ForeColor = FRMFORECOLOR
                bFound = True
            
            Case "ProgressBar"
                SetWindowTheme obj.hwnd, 0&, StrPtr("DarkMode_DarkTheme")
                obj.BackColor = FRMBACKCOLOR
                obj.ForeColor = FRMFORECOLOR
                bFound = True
            
            End Select
            On Error GoTo 0
        End If
        '----------------------------------------------------------------------------------------]
        

        If bFound = False Then
        
            '
            ' General case
            '
            On Error Resume Next
            SetWindowTheme obj.hwnd, StrPtr("DarkMode_Explorer"), 0&
            obj.BackColor = FRMBACKCOLOR
            obj.ForeColor = FRMFORECOLOR
            On Error GoTo 0
        
            '
            ' Special cases
            '
            Select Case TypeName(obj)
            
            Case "CommandButton"
                obj.BackColor = CMDBACKCOLOR
                bFound = True
            
            Case "TextBox"
                obj.BackColor = TXTBACKCOLOR
                obj.ForeColor = TXTFORECOLOR
                obj.Appearance = 0
                obj.BorderStyle = 0
                bFound = True
            '
            ' VBCCR --------------------------------------------[
            '
            Case "CommandButtonW"
                obj.BackColor = CMDBACKCOLOR
                obj.ForeColor = CMDFORECOLOR
                bFound = True
                
            Case "TextBoxW"
                obj.BackColor = TXTBACKCOLOR
                obj.ForeColor = TXTFORECOLOR
                obj.BorderStyle = 0
                bFound = True
            '---------------------------------------------------]
            End Select
            
        End If
    Next
    '
    'Option, Check,  Frame, VBFlexGrid
    '
    If bFound = False Then
        idx = 0
        For Each obj In frm.Controls
            
            Select Case TypeName(obj)
            
            Case "OptionButton"
                If Not addLabelOption(frm, obj) Then addLabel frm, obj
                
            Case "CheckBox"
                If Not addLabelOption(frm, obj) Then addLabel frm, obj
            
            Case "Frame"
                darkFrame frm, obj
            
            Case "OptionButtonW" ' VBCCR
                On Error Resume Next
                If obj.DrawMode <> 1 Then ' If DrawMode is not set to OptDrawModeOwnerDraw
                    If Not addLabelOptionW(frm, obj) Then addLabel frm, obj
                End If
                On Error GoTo 0
                
            Case "CheckBoxW" ' VBCCR
                On Error Resume Next
                If obj.DrawMode <> 1 Then ' If DrawMode is not set to ChkDrawModeOwnerDraw
                    If Not addLabelOptionW(frm, obj) Then addLabel frm, obj
                End If
                On Error GoTo 0
                
            Case "VBFlexGrid" ' VBFlexGrid
                On Error Resume Next
                obj.GridColor = VBFLXGRD_GRIDCOLOR
                obj.BackColorFixed = TXTBACKCOLOR
                On Error GoTo 0
            
            End Select
            
        Next
    End If
    
End Sub

[Krool]

I guess there are a few more (new) themes available since Mith posted the list on June 2023.

For example for the TabStrip the following works properly. (TabStrip1.BackColor = vbBlack to conform to Form's BackColor)

SetWindowTheme TabStrip1.hWnd, 0, StrPtr("DarkMode_DarkTheme::Tab")

Mith, for me TabStrip works in DarkMode.

[Mith]

Mith, for me TabStrip works in DarkMode.

Windows 10?

[Krool]

Windows 10?

Forget Windows 10.
DarkMode_DarkTheme is the right attempt by MS to address win32 applications. Not yet 100% but.. hopefully someday. Like date picker and calendar still missing.
Everything else is not right by design. Therefore I would make a OS version check and enable dark mode only when that is met. Finish.

[Mith]

Forget Windows 10.
DarkMode_DarkTheme is the right attempt by MS to address win32 applications. Not yet 100% but.. hopefully someday. Like date picker and calendar still missing.
Everything else is not right by design. Therefore I would make a OS version check and enable dark mode only when that is met. Finish.

DarkMode_DarkTheme works only with Win11 and not with Win10!

My app supports Dark Mode for Windows 10 & 11 thats the reason i check the OS version and use different API-calls to get the correct control colors.
The Win10 dark mode is not perfect but it is still possible.

[wqweto]

> The Win10 dark mode is not perfect but it is still possible.

And it works on Win11

[Mith]

> The Win10 dark mode is not perfect but it is still possible.

And it works on Win11

Only partially, for example:

1. you dont have to ownerdraw the checkbox/optionbutton anymore when using the new "DarkMode_DarkTheme" with win11!
2. the up/down buttons inside a textbox/DatePicker dont have the dark mode style & colors with win10 but with win11 and "DarkMode_DarkTheme" it works.
3. no dark mode when using the TabStrip under win10. you have to use "DarkMode_DarkTheme" with win11.

[Krool]

Just for information. The VBFlexGrid works now better in "dark mode colors".

As you can see below the focus rect. Top is now after an update and bottom how it was before or is in a MSFlexGrid.



Reason is that the DrawFocusRect API makes an XOR operation. And there SetBkColor/SetTextColor influences the outcome.
SetTextColor is of course used but not SetBkColor. It remained still in the default color of white. Now it's set to what the background actually is.