[RESOLVED] UserControl

[Ordinary Guy]

How to prevent executing code in Initialize event more than one time

I want to execute the code on first time run only. If closing app or changing from UserControl to parent Form while in design mode I do not want the code executed again. I tried Ambient.UserMode but that causes error

[Eduardo-]

Private Sub UserControl_Initialize()
    Static sFirst As Boolean
    
    If Not sFirst Then
        
        ' code...
        
        sFirst = True
    End If
End Sub

[Ordinary Guy]

I already tried that and it doesn't seem to work. What happens is when I close the app it cycles back to the Initialize and the boolean is again False so it enters the code again which is what I don't want.

[dreammanor]

Option Explicit

Private m_Initialized As Boolean

Private Sub DoInitialize()
    
    If m_Initialized = False Then
        m_Initialized = True
        
        '=====================================
        ' place some initialize code
        '=====================================
    
        Debug.Print "Initialized " & Now
        
    End If
    
End Sub

Private Sub UserControl_Initialize()
    Call DoInitialize
End Sub

[Eduardo-]

I already tried that and it doesn't seem to work. What happens is when I close the app it cycles back to the Initialize and the boolean is again False so it enters the code again which is what I don't want.

Add a bas module and put a public variable:

Public gInitialized as Boolean

Private Sub UserControl_Initialize()
    If Not gInitialized Then
        
        ' code...
        
        gInitialized = True
    End If
End Sub

[SamOscarBrown]

I already tried that and it doesn't seem to work. What happens is when I close the app it cycles back to the Initialize and the boolean is again False so it enters the code again which is what I don't want.

Are you saying WHEN you are closing it, or when you re-run the app?

[Ordinary Guy]

Option Explicit

Private m_Initialized As Boolean

Private Sub DoInitialize()
    
    If m_Initialized = False Then
        m_Initialized = True
        
        '=====================================
        ' place some initialize code
        '=====================================
    
        Debug.Print "Initialized " & Now
        
    End If
    
End Sub

Private Sub UserControl_Initialize()
    Call DoInitialize
End Sub

No, no, no. That's the same as previously posted except you just put it in another sub but the effect is the same

Add a bas module and put a public variable:

Public gInitialized as Boolean

Private Sub UserControl_Initialize()
    If Not gInitialized Then
        
        ' code...
        
        gInitialized = True
    End If
End Sub

Nope, using a .BAS doesn't change the situation

Are you saying WHEN you are closing it, or when you re-run the app?

I'm saying when I close (closing) the running app (press on X button or a Command button)

There are 4 time the Initialized event is entered (and thus executes the code in the event)

1) When project is launched - double clicking on .vbp file - that's bad

2) When in Design Mode I move from viewing UserControl to parent Form - that's bad

3) When I run the app - this is the only time I want it to enter the Initialize event

4) When I close the app (still in running mode) it enters the event before it returns to Design Mode - that's bad

This wouldn't be a problem if all I was doing was to initialize a few variables but that is not what I am doing. In the Initialize event (and I'm guessing that I shouldn't be doing this here) I Shell another application because I want that other app up and running without any user intervention. If not the Initialize event where else can I do this - can't use the Show event, that's even worse

What's happening is when the Initialize event is entered these 4 times all variables have been set back to the design mode values. This means I shell the other app 4 times and I can see 4 entries in the Task Manager

The only way I am able to prevent this is to call a public sub in the UC from the Form Load of the Parent Form to run these first time instructions but this then means that the UC is dependant on the parent Form which I don't want

[ThEiMp]

When I use a UserControl, when I open, save, compile my ActiveX Controls, they execute with the UserControl_Initalize Handler, too. So then I am perplex into what do to here, too. So then Bump

[dilettante]

Initialize is for basic, static initialization.

Many things should be initialized within InitProperties for a newly created instance.

For created instances use ReadProperties, when Ambient.UserMode is valid because at that point the control has been sited on its container.

[ThEiMp]

Yeah, I know that you can setup the ReadProperties and WriteProperties. But then really UserControl_Initalize is only for setting the values of Variables and nothing more. For setting properties that are bundled into the ActiveX Control for instance like Enabled, you can use the handler ReadProperties. But then that is only for the properties that are able to be changed by the user and also the IDE, even. Just about any kind of property that is inside a Let Public or even a Get Public. I have also used Set Public, even they can be changed. anything outside of these aren't required to be changed for any reason, something like (Name) and (Custom) and also (About) for instance, can't be changed inside the ReadProperties handler, even

[Eduardo-]

In a bas module:

Public gAppShelled As Boolean

In the usercontrol:

Private Sub UserControl_ReadProperties(PropBag As PropertyBag)
    If Not gAppShelled Then
        If Ambient.UserMode Then
            gAppShelled = True
            Shell "mspaint.exe", vbHide
        End If
    End If
End Sub

This would shell the app only once in the project, as you said.

But, what if there are more than one usercontrol placed on the form, or in several forms?
Shouldn't you shell one instance of the app for each usercontrol?

[ThEiMp]

I guess the OP wants the MsPaint.exe to be added to the Resource file, like a built into App, hey OP

Private Sub UserControl_ReadProperties(PropBag As PropertyBag)
    If gAppShelled = True Then Shell "mspaint.exe", vbHide
End Sub

[dilettante]

I guess the OP wants the MsPaint.exe to be added to the Resource file, like a built into App, ...

Er, that would probably be considered piracy. And in any case Paint.exe is changed to match each version of Windows. There is no guarantee an old version would run properly on a newer version of Windows.

This would be a very poor idea.

[ThEiMp]

Well I know IT IS piracy, but then I thought that he made his version of Paint.exe, which now reading back on the notes, here then it says that he didn't make the Paint.exe, app as per say. I am making my own apps and deploying them as virus free apps, and from a resource file, embedded into the build. but then that is totally invalid here, because they are what I have written and is a manifestation of my own thoughts, after four long years of asking the programmers what they want to see in the apps, even

[Ordinary Guy]

To what advantage would it be to put the app in the resource file. Would it make it load any faster.

[Elroy]

Say Ordinary Guy,

It sounds like you're struggling with the idea of the scope and lifetime of a variable (or boolean flag). For any VB6 program, I could think of many scope and lifetime levels. I'll outline these various levels and the ways I often use them.

• Dim in procedure. Scope: the procedure. Lifetime: that single call into the procedure.
• Static in procedure. Scope: the procedure. Lifetime: single execution of the whole app (although if it's a COM module, it'll be that instantiation of the COM module. See below.)
• Dim at module level for COM (class, form, user control) module. Scope: anywhere in that instance of the module. Lifetime: For as long as that instance of the module is in existence.
• Dim at module level for BAS module. Scope: anywhere in the module. Lifetime: single execution of the whole app.
• Public at module level for BAS module. Scope: anywhere in the app, including other COM modules. Lifetime: single execution of the whole app.
• Registry (HKCU area) (SaveSetting, GetSetting). Scope: for the particular user logged into the computer. Also, when it's read into a variable, the above applies. Lifetime: forever, unless the computer is setup such that the HKCU area is purged when the user logs off.
• Registry (HKLM area) (API calls). Scope: the whole computer. Also, same as HKCU, depends on what variable it's read into. Lifetime: typically forever.
• Some file. Scope: whoever can read the file. And yet again, it depends on what variables the file's info is read into. Lifetime: typically forever.
• File on a file server accessible by anyone using the app. Scope: whoever can read the file on the entire LAN (or WAN). Lifetime: typically forever. This is the one case where I might consider an INI file.

Maybe that'll help you get your head around some of this stuff.

All The Best,
Elroy

[Ordinary Guy]

In a bas module:

Public gAppShelled As Boolean

In the usercontrol:

Private Sub UserControl_ReadProperties(PropBag As PropertyBag)
    If Not gAppShelled Then
        If Ambient.UserMode Then
            gAppShelled = True
            Shell "mspaint.exe", vbHide
        End If
    End If
End Sub

This would shell the app only once in the project, as you said.

It appears that I don't need the .bas module nor the checking the variable. So far I have it working with only this code:

Private Sub UserControl_ReadProperties(PropBag As PropertyBag)
 If Ambient.UserMode Then
   Shell "mspaint.exe", vbHide
 End If
End Sub

But, what if there are more than one usercontrol placed on the form, or in several forms?
Shouldn't you shell one instance of the app for each usercontrol?

MSPaint would have to be shelled for each occurance of the control

[Eduardo-]

It appears that I don't need the .bas module nor the checking the variable. So far I have it working with only this code:

Private Sub UserControl_ReadProperties(PropBag As PropertyBag)
 If Ambient.UserMode Then
   Shell "mspaint.exe", vbHide
 End If
End Sub

Yes, but as you said it should be shelled only once....

But you are right, you need to shell it only once per usercontrol. Hence my following question.

MSPaint would have to be shelled for each occurance of the control

OK, and did you think that the user may be with one instance of Paint already open? (and doing something)

You also need a way to differentiate each instance that you run, because just looking for the window with FindWindow doesn't do that.

[Ordinary Guy]

If I use the get handle by PID that wont happen

Private Sub ShellMSPaint()
 PID = Shell("C:\windows\system32\mspaint.exe", vbHide)
End Sub

Private Sub EmbedMSPaint()
 '
 ' Embed MSPaint
 '
 If PID > 0 Then
   Do
     MSPaintHwnd = GetHwnd(PID)
     If MSPaintHwnd > 0 Then Exit Do
   Loop
   
  SetParent MSPaintHwnd, UserControl.hWnd
 Else
   MsgBox "Unable To Embed MSPaint"
 End If
End Sub

Private Function GetHwnd(ByVal ProcessID As Long) As Long
 '
 ' Get Hwnd from Process ID
 '
 Dim lHwnd As Long, RetHwnd As Long, RetPID As Long
    
 lHwnd = GetDesktopWindow()
 RetHwnd = GetWindow(lHwnd, GW_CHILD)
    
 Do While RetHwnd
   If IsWindowVisible(RetHwnd) Then
     GetWindowThreadProcessId RetHwnd, RetPID
            
     If RetPID = ProcessID Then
       Exit Do
     End If
   End If
   RetHwnd = GetWindow(RetHwnd, GW_HWNDNEXT)
 Loop
    
 GetHwnd = RetHwnd
End Function

[Eduardo-]

Ok, another suggestion: do not shell mspaint.exe with the full path, not every Windows is in C:\Windows (mine is not)

mspaint.exe is in the system path, so you can shell it with just the filename (or get the Windows\system32 path with some API call).

[Ordinary Guy]

Good suggestion. I changed it to use name only

[ThEiMp]

the only reason for to add an exe into a resource is to deploy there, it will be a smaller file size and also load that much slower, because it has to inflate the file size of each of the exe files

[ThEiMp]

Ok, another suggestion: do not shell mspaint.exe with the full path, not every Windows is in C:\Windows (mine is not)

mspaint.exe is in the system path, so you can shell it with just the filename (or get the Windows\system32 path with some API call).

Shell (App.Path & "\Paint.exe"), vbNormal

[ThEiMp]

Post to the OP: How can this thread be resolved, because we haven't covered any ground work here on in the thread, here right about now, even. please post your results so that we can be able to figure out if the thread can be resolved properly, even +<

[Ordinary Guy]

Resolved at post #17

Private Sub UserControl_ReadProperties(PropBag As PropertyBag)
 If Ambient.UserMode Then
   Shell "mspaint.exe", vbHide
 End If
End Sub

[ThEiMp]

-- That was what the OP was looking for, gee sorry!!