RegEx - Split on comma character, excluding those in quotationmarks.

[Atheist]

Hey there.

Given an input string like the following:
I, Need, Some, Coffee, Before, I, "Fall, Asleep"

I need to split this into parts like so:
I
Need
Some
Coffee
Before
I
Fall Asleep

Splitting on the comma character alone is easy enough, but how can I handle the quotationmarks? Regular expressions is not on my strong side, and I have been googling for quite a bit without any good results.

Thanks.

[danasegarane]

You could try this regular expression pattern..

Dim regex As System.Text.RegularExpressions.Regex = New System.Text.RegularExpressions.Regex("(""[^""]*"")|,")         ' Split on hyphens.
            Dim substrings() As String = regex.Split("I, Need, Some, Coffee, Before, I, ""Fall, Asleep""")
            For Each match As String In substrings
                Console.WriteLine("'{0}'", match)
            Next

[Atheist]

Thanks dana, this is great! Just one thing...is it possible to not include the quotation marks in the result?

[Atheist]

I found this (its C# though!), but it splits on whitespace, not comma characters. I'm not sure what do modify to make it split on comma characters instead.

            string input = "I want my coffee without \"milk and sugar\"";
            Regex regex = new Regex(@"((""((?<token>.*?)(?<!\\)"")|(?<token>[\w]+))(\s)*)", RegexOptions.None);
            List<string> result = (from Match m in regex.Matches(input)
                                   where m.Groups["token"].Success
                                   select m.Groups["token"].Value).ToList();

            foreach (string s in result)
                Console.WriteLine(s);

            Console.ReadLine();

EDIT: Disregard this, it seems like it does not split on whitespace, it finds sequences of characters, so it'll split on anything that isnt a character..which is not what I want.

[techgnome]

Thanks dana, this is great! Just one thing...is it possible to not include the quotation marks in the result?

you could do a replace on the results...

-tg

[danasegarane]

I am unable to find the pattern for that one..

[techgnome]

what? for the replace? Oh, I was thinking a little more low-tech ... string.replace ...

-tg

[MattP]

I know the thread asks for RegEx to handle this, but any reason you're not using a TextFieldParser?

        Dim input = "I, Need, Some, Coffee, Before, I, ""Fall, Asleep"""
        Dim results As String()
        Using s As New IO.MemoryStream(New ASCIIEncoding().GetBytes(input)),
            tfp As New FileIO.TextFieldParser(s)
            tfp.Delimiters = {","}
            tfp.HasFieldsEnclosedInQuotes = True
            results = tfp.ReadFields()
        End Using

[ForumAccount]

You simply adjust the regular expression pattern to not capture the double quotes:

Dim text = "I, Need, Coffee, Before, I, ""Fall, Asleep"" Otherwise, ""I'll, Die"""
Dim regex = New Regex("""([^""]*)""|,")

Dim subStrings() = regex.Split(text)
For Each match In subStrings
    Dim current = match.Trim()
    If Not current = String.Empty Then
        Console.WriteLine("{0}", current)
    End If
Next

Output:

I
Need
Coffee
Before
I
Fall, Asleep
Otherwise
I'll, Die

[Atheist]

tg:
Yeah a string.replace would work, but I figure while I'm at it I might aswell see if there is a possibility to get rid of the "s directly with the regex

MattP:
I've never seen the TextFieldParser, it looks quite handy! I would try it, but is there any reason that this is in the Microsoft.VisualBasic namespace? (This regexp expression would be used in a C# application, despite this thread being in the vb.net forum).

ForumAccount:
That looks great, there's just one problem.. when splitting a string containing "quotationmarked values", the returned string array will have empty elements before and after the value.

input: A,"B,C",D

Will thus give:

0: A
1:
2: B,C
3:
4: D

It is not an option for me to remove empty entries, because the text i am parsing might contain fields that are supposed to be empty. Is there any way to avoid the empty spaces that are "created"?

[danasegarane]

How about this one

Dim text = "I, Need, Coffee, Before, I, ""Fall, Asleep"" Otherwise, ""I'll, Die"""
            Dim regex = New Regex("""([^""]*)""|,")

            Dim subStrings = regex.Split(text).Where(Function(str) str.Trim.Length > 0)
            For Each match In subStrings
                Dim current = match.Trim()
                If Not current = String.Empty Then
                    Console.WriteLine("{0}", current)
                End If
            Next

[Atheist]

Thanks dana, but I cant check if the string in the splitted array is empty after the split. This is because the data I am splitting may contain empty fields here and there..and I can not filter them out.

[ForumAccount]

ForumAccount:
That looks great, there's just one problem.. when splitting a string containing "quotationmarked values", the returned string array will have empty elements before and after the value.

input: A,"B,C",D

Will thus give:

0: A
1:
2: B,C
3:
4: D

It is not an option for me to remove empty entries, because the text i am parsing might contain fields that are supposed to be empty. Is there any way to avoid the empty spaces that are "created"?

No, it's not possible, at least using the Split method. The MSDN says this:

If multiple matches are adjacent to one another, an empty string is inserted into the array. For example, splitting a string on a single hyphen causes the returned array to include an empty string in the position where two adjacent hyphens are found, as the following code shows.

In your case, the adjacent matches are the non-enclosed beside the quote-enclosed values. As evident in your example.

I did end up revising the pattern to exclude the spaces after the comma though (no need for .Trim()):

Dim text = "I, Need, Coffee, Before, I, ""Fall, Asleep"", Otherwise, ""I'll, Die"""
Dim regex = New Regex(",\s*|""([^""]*)""")

Dim subStrings() = regex.Split(text)
For Each match In subStrings
    Console.WriteLine("{0}", match)
Next

[Atheist]

Would it not be possible to use regex.Match instead of regex.Split? I really must avoid having arbitrary empty elements in my returned split. If there's no way to do this in regex... I will have to parse my text in some other way..

[ForumAccount]

I think I got a working pattern (not for Split):

Dim text = "A, B, C, ""D, E, F"", G, ""H, I"", J"
Dim r = New Regex("""(?<g>[^""]+)"",?(\s+)?|(?<g>[^"",]+$)|((?<g>[^"",]*),\s*)*")
Dim matches = r.Matches(text)

For Each m As Match In matches
    Dim g = m.Groups("g")
    For Each c As Capture In g.Captures
        Console.WriteLine("'{0}'", c.Value)
    Next
Next

Output:

'A'
'B'
'C'
'D, E, F'
'G'
'H, I'
'J'

The named capture group 'g' will contain all the fields, there should be no need for:

• Checking for empties (unless it is a valid empty, i.e. "A,,C")
• Trimming the result fields

I did some testing behind the scenes, if you find something that doesn't work then let me know.