[RESOLVED] string into array based on length

[Steve-ere]

Hi can anyone tell me how to split a string into an array based on it's length?

Say if I want the length to be 350 then every 350 chars in a textbox will be split into an array like

splittext(0) = First 350 chars
splittext(1) = Second 350 chars
splittext(2) = Third 350 chars or any chars under 350

etcetc

Thanks

[03myersd]

Try this:

        Dim str As String = "hello world!"
        Dim noChars As Integer = 4
        Dim myArr(str.Length \ noChars) As String


        For i As Integer = 1 To str.Length \ noChars
            myArr(i) = Mid(str, (noChars * i) - (noChars - 1), noChars)
            MsgBox(myArr(i))
        Next

[Steve-ere]

Thanks works great but is there any way to make it so that it can be any number below noChars?

So like

Dim str As String = "Visual"

it gets the first 4 letters into an array and then puts the 2 left over letters into the array aswell?

[gep13]

Hey,

What about ToCharArray()

http://msdn.microsoft.com/en-us/library/ezftk57x.aspx

http://msdn.microsoft.com/en-us/library/2c7h58e5.aspx

Gary

[03myersd]

        Dim str As String = "hello"
        Dim noChars As Integer = 6
        Dim myArr(str.Length \ noChars) As String

        If noChars <= str.Length Then
            For i As Integer = 1 To str.Length \ noChars
                myArr(i) = Mid(str, (noChars * i) - (noChars - 1), noChars)
                MsgBox(myArr(i))
            Next
        Else
            ReDim myArr(1)
            myArr(0) = str
            MsgBox(myArr(0))
        End If

That fixes it for if noChars is greater than the length of the string.

[03myersd]

Hey,

What about ToCharArray()

http://msdn.microsoft.com/en-us/library/ezftk57x.aspx

http://msdn.microsoft.com/en-us/library/2c7h58e5.aspx

Gary

I may be missing something, but wouldnt this only work if you were splitting it up into single characters instead of small strings?

[gep13]

I may be missing something, but wouldnt this only work if you were splitting it up into single characters instead of small strings?

Ah, my bad, I misread the first post.

[Steve-ere]

        Dim str As String = "hello"
        Dim noChars As Integer = 6
        Dim myArr(str.Length \ noChars) As String

        If noChars <= str.Length Then
            For i As Integer = 1 To str.Length \ noChars
                myArr(i) = Mid(str, (noChars * i) - (noChars - 1), noChars)
                MsgBox(myArr(i))
            Next
        Else
            ReDim myArr(1)
            myArr(0) = str
            MsgBox(myArr(0))
        End If

That fixes it for if noChars is greater than the length of the string.

Almost what I wanted! Sorry I put the last request wrong
I meant put the leftovers into a new array

Like

myArr(0) = first 6 chars
myarr(1) = last 2 chars

[techgnome]

Here's what I came up with... subtle differences:

        Dim str As String = "Visual"
        Dim noChars As Integer = 4
        Dim myArr(str.Length \ noChars) As String

        If noChars <= str.Length Then
            For i As Integer = 1 To myArr.Length
                myArr(i - 1) = Mid(str, (noChars * i) - (noChars - 1), noChars)
                 MsgBox(myArr(i - 1))
            Next
        Else
            ReDim myArr(1)
            myArr(0) = str
            MsgBox(myArr(0))
        End If

-tg

[.paul.]

which version of vb are you using? assuming vb2008 or 10, try this:

Public Class Form1
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Dim str As String = "Visual Basic.Net"
        Dim noChars As Integer = 5
        Dim myArr(If(str.Length Mod noChars = 0, (str.Length \ noChars) - 1, (str.Length \ noChars))) As String
        For x As Integer = 0 To myArr.GetUpperBound(0)
            myArr(x) = str.Substring(x * noChars, If(x * noChars + noChars <= str.Length, noChars, str.Length - (x * noChars)))
        Next
    End Sub
 
End Class

[jmcilhinney]

I don't like to be left out, so here's my contribution:

Private Function GetStringArray(ByVal text As String, ByVal charCount As Integer) As String()
    Dim textLength = text.Length
    Dim startIndex = 0
    Dim strings As New List(Of String)(CInt(Math.Ceiling(textLength / charCount)))
 
    Do While startIndex < textLength
        strings.Add(text.Substring(startIndex, _
                                   Math.Min(charCount, _
                                            textLength - startIndex)))
        startIndex += charCount
    Loop
 
    Return strings.ToArray()
End Function

[.paul.]

I don't like to be left out, so here's my contribution:

Private Function GetStringArray(ByVal text As String, ByVal charCount As Integer) As String()
    Dim textLength = text.Length
    Dim startIndex = 0
    Dim strings As New List(Of String)(CInt(Math.Ceiling(textLength / charCount)))
 
    Do While startIndex < textLength
        strings.Add(text.Substring(startIndex, _
                                   Math.Min(charCount, _
                                            textLength - startIndex)))
        startIndex += charCount
    Loop
 
    Return strings.ToArray()
End Function

is that an error where you dimensioned the list(of string)?

[jmcilhinney]

is that an error where you dimensioned the list(of string)?

Do you mean this part:

Dim strings As New List(Of String)(CInt(Math.Ceiling(textLength / charCount)))

One of the List constructors takes a capacity as an argument, and that's the one I'm using. The Capacity of a List is the number of elements it can hold, which is determined by the Length of the internal array. If you don't specify a capacity then the internal array is initially created with four elements. Each time you Add an item that takes the Count past the current Capacity, the internal array must be resized; specifically, the Length is doubled. If you know exactly how many items the List will hold, as we do in this case, you can specify the capacity when you create it and you guarantee that no array resizing will ever take place, increasing efficiency.

[.paul.]

yeah that's the part i meant. never seen that before...

[Steve-ere]

Here's what I came up with... subtle differences:

        Dim str As String = "Visual"
        Dim noChars As Integer = 4
        Dim myArr(str.Length \ noChars) As String

        If noChars <= str.Length Then
            For i As Integer = 1 To myArr.Length
                myArr(i - 1) = Mid(str, (noChars * i) - (noChars - 1), noChars)
                 MsgBox(myArr(i - 1))
            Next
        Else
            ReDim myArr(1)
            myArr(0) = str
            MsgBox(myArr(0))
        End If

-tg

Using a 4 letter word with that made a blank msgbox appear after the first

which version of vb are you using? assuming vb2008 or 10, try this:

Public Class Form1
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Dim str As String = "Visual Basic.Net"
        Dim noChars As Integer = 5
        Dim myArr(If(str.Length Mod noChars = 0, (str.Length \ noChars) - 1, (str.Length \ noChars))) As String
        For x As Integer = 0 To myArr.GetUpperBound(0)
            myArr(x) = str.Substring(x * noChars, If(x * noChars + noChars <= str.Length, noChars, str.Length - (x * noChars)))
        Next
    End Sub
 
End Class

Thanks! Works perfect :P



Thanks for the help guys, much appreciated