Save image/bitmap into Access Memo w/o going to HDD [RESOLVED]

[jkothia]

I am creating a bitmap/image in my app and want to store it into a memo field in Access table. I can write the bitmap to the HDD as a bmp file, and then read it and insert it into memo field using APPENDCHUNK.

I WANT TO AVOID CREATING A FILE ON HDD.

Also, need a way to retrieve this data back from the database, to redisplay it whenever needed (and to verify the save process ).

Using:
VB.NET 2003
ADODB
Windows XP

[<ABX]

show us the code.

[jkothia]

I should have included in the subject matter: Need help.

This is my implementation of the recommended way I found in documentation for vb.net:

Dim bm As Bitmap = New Bitmap(100, 100)
Dim g As Graphics
g = Graphics.FromImage(bm)
g.Clear(Color.White)
Dim fn As New System.Drawing.Font("Arial", 10, FontStyle.Regular)
Dim drawBrush As New SolidBrush(Color.Black)
g.DrawString("Hello, World", fn, drawBrush, 10, 10)
bm.Save("c:\temp\hw.bmp")
'read bmp into byte array
Dim img As Image = bm
Dim mst As MemoryStream = New MemoryStream
img.Save(mst, System.Drawing.Imaging.ImageFormat.Bmp)
mst.Flush()
 
Dim byteA() As Byte
byteA = mst.GetBuffer
Dim CONNSTR As String = "Provider=Microsoft.Jet.OLEDB.4.0;DATA SOURCE=C:\TEMP\DB1.MDB"
Dim conn As Connection = New Connection
conn.Open(CONNSTR)
Dim rsWrite As ADODB.Recordset = New Recordset
'bmp is a table in db1.mb with bmp field as memo and len_bmp as number
rsWrite.Open("SELECT * FROM BMP", conn, CursorTypeEnum.adOpenDynamic, LockTypeEnum.adLockOptimistic)
rsWrite.AddNew()
rsWrite("BMP").AppendChunk(byteA)
rsWrite("LEN_BMP").Value = byteA.Length
rsWrite.Update()
rsWrite.MoveFirst()
 
rsWrite.Close()
rsWrite.Open("SELECT * FROM BMP", conn)
rsWrite.MoveFirst()
Dim byteB() As Byte = rsWrite("BMP").GetChunk(rsWrite("LEN_BMP").Value)

I get following exception at the last Dim byteB statement.

"An unhandled exception of type 'System.InvalidCastException' occurred in WindowsApplication6.exe

Additional information: Specified cast is not valid"

Apparently GetChunk returns String (or Object?) and conversion to byte() is needed. Don't know how!. HELP!!!

[jkothia]

See related thread:
http://www.vbforums.com/showthread.php?s=&threadid=284306

[jkothia]

Sorry, I closed the other thread without really posting code.

This code snipped requires button1, button2, picturebox1, picturebox2, a Microsoft Access database c:\temp\db1.mdb with an EMPTY table bmp with column bmp as OLE Object with a primary key column.

Clicking on Button1 creates a bmp/image, stores it in database, and shows it in picturebox1.

Button2 retrieves the same image and shows it in pictureBox2.

Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        Dim ssql As String
        Dim sConn As String
        Dim objDA As OleDbDataAdapter
        Dim objDS As New System.Data.DataSet
        Dim objRow As Data.DataRow
        Dim objDt As Data.DataTable
        Dim objcb As OleDbCommandBuilder
 
        ' create an image in memory or use      Me.PictureBox1.Image = Image.FromFile(fromwhereever)
        Dim bmp As Bitmap = New Bitmap(100, 100)
        Dim g As Graphics = Graphics.FromImage(bmp)
        Dim fn As Font = New Font("Arial", 10, FontStyle.Regular)
        Dim br As New SolidBrush(Color.Black)
        g.Clear(Color.White)
        g.DrawString("Hello, World", fn, br, 0, 0)
        Me.PictureBox1.Image = bmp
 
        Dim mst As System.IO.MemoryStream = New MemoryStream
        Me.PictureBox1.Image.Save(mst, System.Drawing.Imaging.ImageFormat.Bmp)
        Dim mydata() As Byte
        mydata = mst.GetBuffer
 
        ' the database part
        sConn = "Provider=Microsoft.Jet.OLEDB.4.0;DATA SOURCE=C:\TEMP\DB1.MDB"
        ssql = "SELECT * FROM bmp"
        objDA = New OleDbDataAdapter(ssql, sConn)
        objcb = New OleDbCommandBuilder(objDA)
        objDA.Fill(objDS, "BMP")
        objDt = objDS.Tables("BMP")
        objRow = objDt.NewRow()
        objRow("BMP") = mydata
        objDS.Tables("BMP").Rows.Add(objRow)
 
        objDA.Update(objDS, "BMP")
    End Sub
    
    Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
        Dim ssql As String
        Dim sConn As String
        Dim objDA As OleDbDataAdapter
        Dim objDS As New System.Data.DataSet
        Dim objRow As Data.DataRow
        Dim objDt As Data.DataTable
        Dim objcb As OleDbCommandBuilder
 
        sConn = "Provider=Microsoft.Jet.OLEDB.4.0;DATA SOURCE=C:\TEMP\DB1.MDB"
        ssql = "SELECT * FROM bmp"
        objDA = New OleDbDataAdapter(ssql, sConn)
        objcb = New OleDbCommandBuilder(objDA)
        objDA.Fill(objDS, "BMP")
        objDt = objDS.Tables("BMP")
        objRow = objDt.Rows(0)
        Dim b() As Byte
        b = objRow("BMP")
 
        Dim mst As MemoryStream = New MemoryStream
        mst.Write(b, 0, b.Length - 1)
        Me.PictureBox2.Image = Image.FromStream(mst)
 
 
    End Sub