Reading a web page......

[Jigabug]

Alright,

I need a bit of help here. I need to read a file online (the address is http://www.angelfire.com/ca2/TJTurtle/textfile.txt and I want to read the "y" and store it. For 3 points and a Tim-Bit, how would I go about doing this?

BONUS: For triple points and a snack-pack of the Tim-Bits, how would I read http://xml.imood.org/moods.cgi and only store the stuff between <count> and </count>?

SUPER BONUS!!!! I'll bump the points to 50 and toss you 100 Tim-Bits if you can tell me how to store all of the stuff between each of the <base> and </base> tags too.

Let me know!

[chrisjk]

For 3 points and a Tim-Bit:

Slap an Inet control on a form, and use this

Private Sub Command1_Click()
 
Text1.Text = Inet1.OpenURL("http://www.angelfire.com/ca2/TJTurtle/textfile.txt")
 
End Sub

'm going for the triple points and a snack-pack of the Tim-Bits, but for 100 Tim-Bits, you must be joking!

[chrisjk]

Right, where's my triple points and a snack-pack of the Tim-Bits?!

Dim strFile As String
Dim strCount As String
Dim intPos As Long
Dim intPos1 As Long
 
strFile = Inet1.OpenURL("http://xml.imood.org/moods.cgi")
 
'extract <count></count>
intPos = InStr(1, strFile, "<count>", vbTextCompare)
 
If intPos > 0 Then
    intPos1 = InStr(intPos + 7, strFile, "</count>", vbTextCompare)
        If intPos1 > 0 Then
            'extract info
            strCount = Mid$(strFile, intPos + 7, intPos1 - (intPos + 7))
        End If
End If
 
Text1.Text = strCount

[sunburnt]

Looks like I win it all;

Dim M%,N%,strText$,CurBase$
strText = Inet1.OpenURL("http://xml.imood.org/moods.cgi")
Do While Inet1.StillExecuting
  DoEvents
Loop
  startInt = 1
  Do
    M = InStr(startInt, strText, "<base>")
    If M = 0 Then Exit Do
    M = M + Len("<base>")
    N = InStr(M, strText, "</base>")
    CurBase$ = Mid$(strText, M, N - M)
    Debug.Print CurBase$
    startInt = M
  Loop

[DaoK]

They have an API to do it without Inet control.

[chrisjk]

Originally posted by DaoK
They have an API to do it without Inet control.

Care to grace us with the name of that API?

[DaoK]

Mathew Gates gave me that code few month ago:

Private Declare Function URLDownloadToFile Lib "urlmon" Alias _
"URLDownloadToFileA" (ByVal pCaller As Long, ByVal szURL As _
String, ByVal szFileName As String, ByVal dwReserved As Long, _
ByVal lpfnCB As Long) As Long
 
Private Function DownloadFile(URL As String, _
    LocalFilename As String) As Boolean
    Dim lngRetVal As Long
    lngRetVal = URLDownloadToFile(0, URL, LocalFilename, 0, 0)
    If lngRetVal = 0 Then DownloadFile = True
End Function
 
Private Sub Command1_Click()
    DownloadFile "http://www.mypage.com/txtfile.txt", "c:\txtfile.txt"
 
    Open "C:\txtfile.txt" For Input As #1
        Text1.Text = Input(LOF(1), 1)
    Close #1
End Sub

[DaoK]

I really like that api because you dont need the Inet OCX and it more stable ( that what Matthew told me ).

[DaoK]

DO you know how to add a progress bar on that code ?

[Jigabug]

Wow!

I guess the Tim-Bits helped! Now, you non-Canadians, what ARE Tim-Bits?

Oh, and you Canadians cann fill 'em in.

[chrisjk]

Originally posted by Jigabug
Now, you non-Canadians, what ARE Tim-Bits?

Haven't got a clue

[DaoK]

canada have Tim Bits

[Jigabug]

Of COURSE we do! We have them on every other corner almost!

[DaoK]

[Jigabug]

For some extra fun, how would I get an Image/Picture box to open an online picture?

[chrisjk]

by

a) using a webbrowser control instead
b) saving the file to a local disk using inet or that API code and displaying it from there

[DaoK]

Private Declare Function URLDownloadToFile Lib "urlmon" _
Alias "URLDownloadToFileA" (ByVal pCaller As Long, ByVal szURL _
As String, ByVal szFileName As String, ByVal dwReserved As Long, _
ByVal lpfnCB As Long) As Long
 
Private Function DownloadFile(URL As String, _
LocalFilename As String) As Boolean
    Dim lngRetVal As Long
    lngRetVal = URLDownloadToFile(0, URL, LocalFilename, 0, 0)
    If lngRetVal = 0 Then DownloadFile = True
 
End Function
 
 
Private Sub Command1_Click()
 
    Dim Success As Boolean
    Success = DownloadFile("http://www.vbsquare.com/images/vbsquare.gif", "C:\vbsquare.gif")
    If Success = True Then
        Picture1.Picture = LoadPicture("C:\vbsquare.gif")
    Else
        Msgbox "Could not load image!", 16
    End If
 
End Sub

[DaoK]

Matthew Gates CopyRight for that code two.

[Jigabug]

Now, is there any way for it to be put RIGHT up against the top and left edges? It seems to like putting itself in a bit.

[DaoK]

I do not understand you ?

[[Digital-X-Treme]]

Originally posted by Jigabug
For some extra fun, how would I get an Image/Picture box to open an online picture?

Here's the fun. Using Winsock to download the file... Then load it into a picture box. See the code below. You will need to add a Picture Box control named Picture1 to a form, along with a Winsock control named Winsock1.

'Coded by [Digital-X-Treme]
Option Explicit
 
Private m_strWebPageData As String
 
Private Sub Form_Load()
    'Establish connection.
    Winsock1.Connect "vbforums.com", 80
End Sub
 
Private Sub Winsock1_Close()
 
    Dim i As Long
 
    Debug.Print "Closed..."
    Debug.Print "Transfer complete..."
    
    'Now you have the web page data, including the header.
    'The header, if HTTP compliant, is trminated by the first blank line... vbCrlf & vbCrlf
    
    'Trim the header, if any, out.
    i = InStr(1, m_strWebPageData, vbCrLf & vbCrLf)
    If i <> 0 Then
        m_strWebPageData = Mid(m_strWebPageData, i + 4)
    End If
 
    'm_strWebPageData now contains the file contents.
    
    'Save it to file...
    Open "C:\Temp.tmp_" For Binary As #1
        Put #1, , m_strWebPageData
    Close #1
    
    'Load picture from file...
    Picture1.Picture = LoadPicture("C:\Temp.tmp_")
 
End Sub
 
Private Sub Winsock1_Connect()
    Debug.Print "Connected..."
    Debug.Print "Sending request..."
    
    'Include the header field "Connection: close"
    'This indicates to HTTP/1.1 compliant servers that we want to close the connection
    'after downloading this page...
    'A trick that lets us know when the download is complete (winsock will close), so we
    'don't need to parse the header fields and find a content-length field...
    
    Winsock1.SendData "GET /images/layout/top_left.gif HTTP/1.0" & vbCrLf & "Connection: close" & vbCrLf & vbCrLf
 
    'If the server you are using is HTTP/1.0 compliant, then you shouldn't send the 'connection'
    'header field.
    'You will need to parse the response header, and grab the content length field, then
    'just keep recieveing data until the content has been downloaded...
    
End Sub
 
Private Sub Winsock1_DataArrival(ByVal bytesTotal As Long)
    Dim strData As String
 
    Winsock1.GetData strData, vbString
    m_strWebPageData = m_strWebPageData & strData
    
End Sub

Hope this helps
Laterz

[da_silvy]

Originally posted by DaoK
Mathew Gates gave me that code few month ago:

Private Declare Function URLDownloadToFile Lib "urlmon" Alias _
"URLDownloadToFileA" (ByVal pCaller As Long, ByVal szURL As _
String, ByVal szFileName As String, ByVal dwReserved As Long, _
ByVal lpfnCB As Long) As Long
 
Private Function DownloadFile(URL As String, _
    LocalFilename As String) As Boolean
    Dim lngRetVal As Long
    lngRetVal = URLDownloadToFile(0, URL, LocalFilename, 0, 0)
    If lngRetVal = 0 Then DownloadFile = True
End Function
 
Private Sub Command1_Click()
    DownloadFile "http://www.mypage.com/txtfile.txt", "c:\txtfile.txt"
 
    Open "C:\txtfile.txt" For Input As #1
        Text1.Text = Input(LOF(1), 1)
    Close #1
End Sub

Just a bit but wouldn't that code process for example a cgi script?

[DaoK]

it's an api...i do not know about the cgi...

[Jigabug]

Alright,

Now, how would i read out EVERY item inside <base> and </base> and add them to a list box? The list is at http://xml.imood.org/moods.cgi

I'm using the code posted by chrisjk, he wanted his triple points and the tim-bits.

[WALDO]

Try the microsoft XML parser. It can look across the internet for an XML source AND parse that document and extract all the <base></base> tags or whatever you want. It's a little easier than manually trying to parse the source after getting it using the Inet control or the WinInet API

[sunburnt]

Now, how would i read out EVERY item inside <base> and </base> and add them to a list box? The list is at http://xml.imood.org/moods.cgi

Check the code I posted up above. Replace debug.print with MyList.Additem.

[WALDO]

If you were using the oldest version of the XML parser:

Option Explicit
 
Private Sub Form_Load()
    Dim objXML As New MSXML.DOMDocument
    Dim blnSuccess As Boolean
    
    objXML.async = False
    blnSuccess = objXML.Load("http://xml.imood.org/moods.cgi")
    
    If Not blnSuccess Then
        MsgBox _
            "XML Error #" & objXML.parseError.errorCode & ": " & _
            objXML.parseError.reason & vbCrLf & _
            "Line " & objXML.parseError.Line & _
            ", Position " & objXML.parseError.linepos & vbCrLf & _
            objXML.parseError.srcText
        Exit Sub
    End If
    
    Dim xmlList As IXMLDOMNodeList
    Dim x As IXMLDOMNode
    Set xmlList = objXML.getElementsByTagName("imood/bundle/mood/base")
    
    For Each x In xmlList
        Debug.Print x.Text
        Me.Combo1.AddItem x.Text
    Next
    
End Sub

This code works for me!

[Jigabug]

Alright, I'm now using the sunburnt code, any ideas why it would stop at "desperate"?

[WALDO]

What is this gay ass imood crap, anyway?

[WALDO]

Use my code above and change the parameter in getElementsByTagName to:

"imood/bundle/count"

You probably don't have to bother iterating (looping) through the results since you know there's only ever going to be one count.

You can also reuse the same objXML object without going out and getting the same data again. the .xml property of that object stayed the same.