Can this be done?

[Balboa.sCo]

I have attached an image to demonstrate what iam about to say, i need some code that will simulate teh user clicking the login button, is this possible?

Notes on this problem,
1. Sadly the program does not load with the login button pre-selected, therefore clicking enter wont work.
2. There is no tab order(when you press tab it does not highlight the buttons).

Anyone got any ideas? please give full code as iam new to VB.

Thanks

[moeur]

Yes,

Get handle to button using FindWindowEX
Send BM_CLICK message to button

[Balboa.sCo]

moeur thanks for that reply, can u explain what FindWindowEX is? :S i am new to this stuff. or maybe provide a website that i can read up on it myself if you havent got the time as i have no idea how to use it.

Thanks

[Balboa.sCo]

Ok i done a search in google and found an MSDN page on this function however i still have no idea how to use it :S. Could someone provide me with the code i need to find out how to identify the login button habdle?

Thanks

[Pino]

Ok i done a search in google and found an MSDN page on this function however i still have no idea how to use it :S. Could someone provide me with the code i need to find out how to identify the login button habdle?

Thanks

Find window api...

http://www.mentalis.org/apilist/FindWindow.shtml

i'm not sure on the other item though will have to wait for him/her to reply for that one

[moeur]

OK, here is some code
Note that you might have to look up the correct caption and class values using SPY++

Option Explicit
 
'Returns handle to target window
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" ( _
    ByVal lpClassName As String, _
    ByVal lpWindowName As String _
) As Long
 
'Returns handle to target control
Private Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" ( _
    ByVal hWnd1 As Long, _
    ByVal hWnd2 As Long, _
    ByVal lpsz1 As String, _
    ByVal lpsz2 As String _
) As Long
 
'Sends a message to our target
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" ( _
    ByVal hwnd As Long, _
    ByVal wMsg As Long, _
    ByVal wParam As Long, _
    lParam As Any _
) As Long
 
'The message we want to send
Const BM_CLICK = &HF5
 
 
Private Sub Command1_Click()
 Dim hWndForm As Long ' handle to target window
 Dim hWndButton As Long ' handle to the button
 Dim strCaptionForm As String 'caption of the target form
 Dim strClassButton As String ' Button Class
 Dim strCaptionButton As String ' Button Caption
 
'Get the correct values from SPY++
strCaptionForm = "DMW3-Client Login"
strCaptionButton = "Login"
strClassButton = "Button"
 
 'Get handle to desired form
' if this returns 0 we didn't get it
 hWndForm = FindWindow(vbNullString, strCaptionForm)
 If hWndForm = 0 Then
  MsgBox "Sorry, could not find requested form"
  Exit Sub
 End If
 'Get handle to desired button on form
' if this returns 0 we didn't get it
 hWndButton = FindWindowEx(hWndForm, 0, strClassButton, strCaptionButton)
 If hWndButton = 0 Then
  MsgBox "Sorry, could not find requested button"
 Else
 'Send click message to button
  Call SendMessage(hWndButton, BM_CLICK, 0, 0)
 End If
 
End Sub

-Him

[Balboa.sCo]

I tried this code although i do not know what SPY++ is or how to use it for that matter, If i was to send the the DMW program(only 1mb or 2) could you possibly give me the exact code i will need?

When i try the code i get "sorry, could not find requested form"

I have attached DMW.

please help!!

[moeur]

Sorry,

I can't run your executable code (not wise)
Anyway, SPY++ comes with Visual Studio, see if you have it.

[dglienna]

Google for SPY++, unless you have Enterprise Edition, then you already have it.

[Balboa.sCo]

i have VB 6.0 Proffesional, i cnt find SPY++ anywhere, i read what it does and i was able to play about with the code moeur sent me and managed to find out that the form name for the DMW program was Form1 :P, i cant find out the name of the button tho.

The thing i attached was not my code, it was the DMW program, you can download it at www.dmwworld.com(it may help you understand the question more). I worked out that pressing enter when the program loads does nothing, but pressing space bar logs me in. Therefore i used the following code to try get my program to log me in;

Shell (DMWINSTALL), vbNormalFocus
Sleep 3000
SendKeys " ", True

On screen i can see that my program runs the DMW program and after 3seconds it appears to log me in. My problem is that for some reason it is not loging me in correctly. I know this because when i go to play the game the game crashes for some reason with an OpenGL error. If i manually open DMW log myself in then play the game, the game runs perfect.

The only thing i can think off is to do what i thin moeur was trying, to somehow simulate a mouse click on the button. Iam currently trying to contact the person who made the program to ask what he named it. If anyone could find out the name of this button for me by using SPY++ as i cant find it on google, i would greatly appreciate it

Thanks for all the help so far guys, still needing more tho.

Martyn Rendall

[dglienna]

I can't find Spy++ right now, either. I'll post back if I find it.

[sachin_bhatt]

Why dont you call the sub directly?

Sub Form_Load()
   '
   '
   Call cmdLogin_Click()
End Sub

[moeur]

OK, here is some code to do what SPY++ does, but from VB. It sets a system-wide low level mouse hook so that when you move the mouse over the top of a window or control, it gets you the handle, caption and class name. It's amazing what you can do with the functions provided in the API.

Start a new project with a form and a module, add a command button (cmdStart) and three text boxes (txtHandle, txtCaption and txtClassName) to the form.

Put this code in the module:

Option Explicit
 
'Functions, constants and types for the hook
Private Declare Function SetWindowsHookEx Lib "user32" Alias "SetWindowsHookExA" ( _
    ByVal idHook As Long, _
    ByVal lpfn As Long, _
    ByVal hmod As Long, _
    ByVal dwThreadId As Long _
) As Long
 
Private Declare Function UnhookWindowsHookEx Lib "user32" ( _
    ByVal hHook As Long _
) As Long
 
Private Declare Function CallNextHookEx Lib "user32" ( _
    ByVal hHook As Long, _
    ByVal ncode As Long, _
    ByVal wParam As Long, _
    lParam As Any _
) As Long
 
Public Const WH_MOUSE_LL = 14
 
Public Type POINTAPI
        x As Long
        y As Long
End Type
 
Public Type MSLLHOOKSTRUCT
    pt As POINTAPI
    mouseData As Long
    flags As Long
    time As Long
    dwExtraInfo As Long
End Type
 
Private hHook As Long
Public IsHooked As Boolean
 
'functions for getting windows properties
Private Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" ( _
    ByVal hwnd As Long, _
    ByVal lpString As String, _
    ByVal cch As Long _
) As Long
 
Private Declare Function GetClassName Lib "user32" Alias "GetClassNameA" ( _
    ByVal hwnd As Long, _
    ByVal lpClassName As String, _
    ByVal nMaxCount As Long _
) As Long
 
Private Declare Function WindowFromPoint Lib "user32" ( _
    ByVal xPoint As Long, _
    ByVal yPoint As Long _
) As Long
 
Sub GetWindowData(x As Long, y As Long)
 Dim hWndFrm As Long
 Dim lpClassName As String, lpString As String
 lpClassName = Space(100)
 lpString = Space(100)
 'get handle to window
 hWndFrm = WindowFromPoint(CLng(x), CLng(y))
 If hWndFrm = 0 Then Exit Sub
 'get window text (caption)
 Call GetWindowText(hWndFrm, lpString, Len(lpString))
 'get window class name
 Call GetClassName(hWndFrm, lpClassName, Len(lpClassName))
 
 With Form1
  .txtHandle = Hex(hWndFrm)
  .txtCaption = lpString
  .txtClassName = lpClassName
 End With
End Sub
 
Public Sub SetMouseHook()
    If IsHooked Then
        MsgBox "Don't hook the MOUSE_LL hook twice or you'll be sorry."
    Else
        'This has to be set up as a system-wide hook
        hHook = SetWindowsHookEx(WH_MOUSE_LL, AddressOf MouseProc, App.hInstance, 0)
        IsHooked = True
    End If
End Sub
 
Public Sub RemoveMouseHook()
    Dim temp As Long
    temp = UnhookWindowsHookEx(hHook)
    IsHooked = False
End Sub
 
 
Public Function MouseProc(ByVal uCode As Long, ByVal wParam As Long, lParam As MSLLHOOKSTRUCT) As Long
    If uCode >= 0 Then
        Call GetWindowData(lParam.pt.x, lParam.pt.y)
    End If
            
    MouseProc = CallNextHookEx(hHook, uCode, wParam, lParam)
End Function

This code goes into your form:

Option Explicit
 
'Always on top stuff
Private Const HWND_TOPMOST = -1
Private Const SWP_NOSIZE = &H1
Private Const SWP_NOMOVE = &H2
Private Const SWP_NOACTIVATE = &H10
Private Const SWP_SHOWWINDOW = &H40
 
Private Declare Sub SetWindowPos Lib "user32" ( _
    ByVal hwnd As Long, _
    ByVal hWndInsertAfter As Long, _
    ByVal x As Long, _
    ByVal y As Long, _
    ByVal cx As Long, _
    ByVal cy As Long, _
    ByVal wFlags As Long _
)
 
Private Sub cmdStart_Click()
'make window always on top
 SetWindowPos Me.hwnd, HWND_TOPMOST, 0, 0, 0, 0, SWP_NOACTIVATE Or _
    SWP_SHOWWINDOW Or SWP_NOMOVE Or SWP_NOSIZE
 'set the system-wide low level mouse hook
 Call SetMouseHook
End Sub
 
Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
 Call RemoveMouseHook
End Sub

[dglienna]

sweet!

[Balboa.sCo]

I done as u stated moeur and i have attached teh finding as an image with this post. All i need to know to do now is simulate the user clicking login with the mouse, is this possible? if so could you show me how, i use shell to open the program then i take a sleep for a few seconds so the program loads up then i want to simulate the mouse click.

I was also like to say to moeur that you are a credit to this community mate, you have been patient with me and provided som excellent help so far, hopefully we will get to the end of the problem soon. Is there anyway i can vote for you or somethign moeur?id like to show support for your help if i can in some way?

Thanks

[moeur]

Now you have two of the three values you needed.

strCaptionButton = "Login"
strClassButton = "Button"

To get the third value,

strCaptionForm = ????

It should be something like "DMW3 - Client Login"

Use the above program to get the caption of the main form. Put the mouse over the form area not any of the buttons for this third value.

Understand?

[Balboa.sCo]

ok when i put the cursor over the title bar of the form i get the information attached below.

[moeur]

OK, you have everything you need.
In the first code I gave you, replace the command1_click event code with this
Make sure the caption and class names match exactly what you got from the above SPY-- code.

Private Sub Command1_Click()
 Dim hWndForm As Long ' handle to target window
 Dim hWndButton As Long ' handle to the button
 Dim strCaptionForm As String 'caption of the target form
 Dim strClassButton As String ' Button Class
 Dim strCaptionButton As String ' Button Caption
 Dim strClassForm As String 'Form Class Name
 
strCaptionForm = "DMW3 - Client Login"
strCaptionButton = "Login"
strClassButton = "Button"
strClassForm = "#32770"
 
 'Get handle to desired form
' if this returns 0 we didn't get it
 hWndForm = FindWindow(strClassForm, strCaptionForm)
 If hWndForm = 0 Then
  MsgBox "Sorry, could not find requested form"
  Exit Sub
 End If
 'Get handle to desired button on form
' if this returns 0 we didn't get it
 hWndButton = FindWindowEx(hWndForm, 0, strClassButton, strCaptionButton)
 If hWndButton = 0 Then
  MsgBox "Sorry, could not find requested button"
 Else
 'Send click message to button
  Call SendMessage(hWndButton, BM_CLICK, 0, 0)
 End If
 
End Sub

Does it work?

[Balboa.sCo]

i get the sorry, could not find requesed form error

[moeur]

What are the values of your strClassForm and strCaptionForm variables? Did you cut and paste them from the SPY-- form so that you don't make any errors?

Here is a test you can use to see if this whole thing is going to work anyway.

1. Start your target program
2. Get the handle from the button like you did above with the SPY-- code. (ex: A0128). Note, this value changes everytime you run the target program, so you can't hardwire it into your final program.
3.from a VB project, run the command

Call SendMessage(&HA0128, BM_CLICK, 0, 0)

where A0128 is the new value you get.

If this technique is going to work, then it should click the target button

Try it out.

[Balboa.sCo]

tried(One line of code in entire program):

Call SendMessage(&H401CC, BM_CLICK, 0, 0)

to start with got the error "invalid outside procedure".

then tried

Private Sub Command1_Click()
Call SendMessage(&H401CC, BM_CLICK, 0, 0)
End Sub

and got the error "Sub or Function not defined".

the code above is all i have in the program, for example the first one only has 1 line of code in the entire program, i take it this is incorrect? and that iam missing somehting obvious?

[moeur]

OK,

I was assuming you knew to declare the SendMessage function as

Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" ( _
    ByVal hwnd As Long, _
    ByVal wMsg As Long, _
    ByVal wParam As Long, _
    lParam As Any _
) As Long

[Balboa.sCo]

Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" ( _
ByVal hwnd As Long, _
ByVal wMsg As Long, _
ByVal wParam As Long, _
lParam As Any _
) As Long

Private Sub Command1_click()
Call SendMessage(&HA02B2, BM_CLICK, 0, 0)
End Sub

tried that code, no errors but nothing happens on the target program? that mean im at a lose end?

[penagate]

Why dont you call the sub directly?

Sub Form_Load()
   '
   '
   Call cmdLogin_Click()
End Sub

Can I ask why you want to simulate a mouse click exactly, when the above code should achieve the same result If you are using MouseDown or MouseUp events then no problem, just replace _Click with the appropriate event plus any arguments etc.

[moeur]

Remember you have to do this also

Const BM_CLICK = &HF5

Why dont you call the sub directly?

I'm assuming he doesn't have access to the source code of the other program.

[Balboa.sCo]

the original code, where i send the space bar command to the running program appeared to work, on the screen visually i could see the login button bein pressed, the program therefore appeard to work, however if once i have started DMW i try to play the computer game the game crashes. If i just open the DMW and click login myself then play the game it loads and play fine. I have been asking questions on the DMW forums and the original program was coded in C, does this make a difference?

Basically for some reason pressing spacebar to activate the program appears to work, but for some reason it doesnt, as the computer game has a problem loading once i start the DMW program using my program.

Therefore i decided to try simulate a mouse click to see if this would work, however this is my first time in visual basic and although moeur and other are providing some great help and support im struggling to get this program working as i miss out thinks that should be obvious it seems. Maybe trying to get the mouse click to work is to advanced for me?

I really want this program to work, but im sure you guys must be getting annoyed with my silly mistakes.

[moeur]

Let's try one more time
1. open DMW program, don't close it througout this whole process
2. Get handle to button using SPY+-. Make sure you are looking at button. Classname text box should be Button and caption should be Login.
3. put that number into this code

Option Explicit
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" ( _
  ByVal hwnd As Long, _
  ByVal wMsg As Long, _
  ByVal wParam As Long, _
  lParam As Any _
) As Long
 
Private Sub Command1_click()
  Call SendMessage(&H[I]<Your number>[/I], &HF5, 0, 0)
End Sub

4. Run code
5. If it works then smile, if not then cry.

[Balboa.sCo]

IT WORKS , what i have to do is click the button twice tho, it looks like what the first click does is give the DMW program focus and the second clicks the button. All we need to work on now is to get my program to open the DMW one aswell as login now . MOEUR is my hero :P

[Balboa.sCo]

so what i need now is some way of doing this process without having that unique code. Is that unique code hexadecimal?

Any ideas anyone?, liek to achieve this with as little code as possible so i can understand it

[moeur]

Finally!

To start program use the VB Shell command

[Balboa.sCo]

i can do that, but how do i get it to click the login button each time? cos that code will change each time the DMW program is loaded? how can i get round this?

[moeur]

You've got to get this code working

Option Explicit
 
'Returns handle to target window
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" ( _
    ByVal lpClassName As String, _
    ByVal lpWindowName As String _
) As Long
 
'Returns handle to target control
Private Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" ( _
    ByVal hWnd1 As Long, _
    ByVal hWnd2 As Long, _
    ByVal lpsz1 As String, _
    ByVal lpsz2 As String _
) As Long
 
'Sends a message to our target
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" ( _
    ByVal hwnd As Long, _
    ByVal wMsg As Long, _
    ByVal wParam As Long, _
    lParam As Any _
) As Long
 
'The message we want to send
Const BM_CLICK = &HF5
 
Private Sub Command1_Click()
 Dim hWndForm As Long ' handle to target window
 Dim hWndButton As Long ' handle to the button
 Dim strCaptionForm As String 'caption of the target form
 Dim strClassButton As String ' Button Class
 Dim strCaptionButton As String ' Button Caption
 Dim strClassForm As String 'Form Class Name
 
[B][COLOR=Red]'Get these values right or it will not work!
strCaptionForm = "DMW3 - Client Login"
strCaptionButton = "Login"
strClassButton = "Button"
strClassForm = "#32770"[/COLOR][/B]
 
 'Get handle to desired form
' if this returns 0 we didn't get it
 hWndForm = FindWindow(strClassForm, strCaptionForm)
 If hWndForm = 0 Then
  MsgBox "Sorry, could not find requested form"
  Exit Sub
 End If
 'Get handle to desired button on form
' if this returns 0 we didn't get it
 hWndButton = FindWindowEx(hWndForm, 0, strClassButton, strCaptionButton)
 If hWndButton = 0 Then
  MsgBox "Sorry, could not find requested button"
 Else
 'Send click message to button
  Call SendMessage(hWndButton, BM_CLICK, 0, 0)
 End If
End Sub

I know yo're close, you just have to get the correct values into the caption and class variables. Did you try cutting and pasting from the text boxes?

[Balboa.sCo]

i get the error cannot find the requested form!! , i cnt copy and paste the values because they change be4 i can get to box to copy them. have u got the spy++ program u could send me?

[moeur]

i cnt copy and paste the values because they change be4 i can get to box to copy them

Of course... Duh
Print them out to your immediate window by adding the lines:

Debug.Print "Caption: "; lpString
Debug.Print "Class Name: "; lpClassName

to the end of the GetWindowData subroutine in the SPY-- program. If your immediate window is not visible, the press ctrl-G

[Balboa.sCo]

i now have my program logging me in succesffully IF i open the program first, if i use Shell command to open DMW this causes the error, therefore is there any other way to open up an exe program in VB wihout using the shell command? progressign well

What i done moeur was decided that something was obviously wrong wrong with the DMW3 ...... bit so i added a space at the end and to my surprise it worked .

[moeur]

What i done moeur was decided that something was obviously wrong wrong with the DMW3 .....

Good job!
Maybe the program needs to wait for the login window to open.
After the line in your code

hWndForm = FindWindow(strClassForm, strCaptionForm)

Add the following

While hWndForm = 0
    DoEvents
    hWndForm = FindWindow(strClassForm, strCaptionForm)
Wend

Let's hope that works.

[|2eM!x]

or use runprogram

Option Explicit
Private Const SW_SHOWNORMAL = 1
Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" _
    (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, _
    ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd _
    As Long) As Long
 
Private Sub RunProgram(strProgram As String)
    Dim lRet As Long
    lRet = ShellExecute(vbNull, "", strProgram, "", "", SW_SHOWNORMAL)
End Sub
 
Private Sub Form_Load()
RunProgram ("ya")
End Sub

[Balboa.sCo]

It istn because i need to wait for th program to load, i used 2 buttons, one to openDMW and one to login, i think the porblem is the shell command. Is there any other way to open a program using its path? What is ShellExecute?

[Balboa.sCo]

I dont understand whay this aint working!!!

I can start DMW with my program, login manually then play a game fine.

I can start DMW manually and make my program log me in to DMW, then play the game fine.

However if i try to do these two things it doesnt work!!! i can see my program opening DMW and then clickign the login button, however if i try to play a game this way i get an error with the computer game(Something to do with OpenGL and a file not found).

Needing help!!

Thanks

[moeur]

Try putting a long pause in between opening the program and clicking the button