Adding an item to the list - VBScript

**lateefm** · Aug 11th, 2000, 09:24 AM

How do I add items to a list box present on htlm page using vbscript at click of a button at run time.
thnaks

**Serge** · Aug 11th, 2000, 02:41 PM

Here you go:

Code:

<HTML>
<HEAD>

<SCRIPT Language=vbscript>

Sub LoadListItems
	Dim colOptions
	Dim objOption
	Dim i
	
	Set colOptions = lstItems.options
	
	For i = 1 To 10
		Set objOption = document.createElement("OPTION")
		
		colOptions.add(objOption)
		objOption.innerText = "Item: " & CStr(i)
	Next
End Sub

Sub DeleteItems
	Dim i
	Dim colOptions
	
	Set colOptions = lstItems.options
	
	For i = colOptions.length - 1 To 0 Step - 1
		colOptions.remove i
	Next	
End Sub	

</SCRIPT>

</HEAD>
<BODY>

<P> </P>


<SELECT Id=lstItems size=10 Style="Width=150">

</SELECT>

 
<INPUT Type=Button OnClick=LoadListItems Id=cmdButton Value="Add Items"> 
<INPUT Type=Button OnClick=DeleteItems Id=cmdButton Value="Delete Items">

</BODY>
</HTML>

Thread: Adding an item to the list - VBScript

Thread Tools

Display

Posting Permissions