Click a flexgrid row, get value of cell in column 0 ?

[TheBionicOrange]

I have a flexgrid with 6 columns and various amounts of rows.

If I click anywhere in the flexgrid I want to move the value of the cell in column 0 for that row in to a textbox.

Is there a quick way to do this ?

Last time I trapped values in cells I had to declare 2 variables called X and Y and plot where I was, but I'm not sure if this is the best way to go.

Any takers ?

[darre1]

this help?

Private Sub MSFlexGrid1_Click()
    MSFlexGrid1.Col = 0
    MsgBox MSFlexGrid1.Text
End Sub

dont like the flexgrid, funny to work with

[wayneh]

Try this:

Text1.Text = MSFlexGrid1.TextMatrix(MSFlexGrid1.Row, 0)

[TheBionicOrange]

Cheers Guys.

Amazingly simple really, I just need to invest in a brain first

[darre1]

nah, i dont like the flexgrid, too brain-needy

[TheBionicOrange]

I'll admit they can be fiddly to work with.

I presume you use DataGrids instead then do you ?

[darre1]

i've just started fiddling with my first ListView control, very useful

[TheBionicOrange]

I like the way you can click a listview header and have it sort on that column. Very handy.

[darre1]

ive just posted a problem with that

[Slaine]

I like the way you can click a listview header and have it sort on that column. Very handy.

That can be done with a flex grid too, just add the following code

Option Explicit
 
' variables for enabling column sort
Private m_iSortCol As Integer
Private m_iSortType As Integer
 
Private Sub MSHFlexGrid1_DblClick()
'-------------------------------------------------------------------------------------------
' code in grid's DblClick event enables column sorting
'-------------------------------------------------------------------------------------------
 
    Dim i As Integer
 
    ' sort only when a fixed row is clicked
    If MSHFlexGrid1.MouseRow >= MSHFlexGrid1.FixedRows Then Exit Sub
 
    i = m_iSortCol                  ' save old column
    m_iSortCol = MSHFlexGrid1.Col   ' set new column
 
    ' increment sort type
    If i <> m_iSortCol Then
        ' if clicking on a new column, start with ascending sort
        m_iSortType = 1
    Else
        ' if clicking on the same column, toggle between ascending and descending sort
        m_iSortType = m_iSortType + 1
    If m_iSortType = 3 Then m_iSortType = 1
    End If
 
    DoColumnSort
 
End Sub
 
Sub DoColumnSort()
'-------------------------------------------------------------------------------------------
' does Exchange-type sort on column m_iSortCol
'-------------------------------------------------------------------------------------------
 
    With MSHFlexGrid1
        .Redraw = False
        .Row = 1
        .RowSel = .Rows - 1
        .Col = m_iSortCol
        .Sort = m_iSortType
        .Redraw = True
    End With
 
End Sub

[TheBionicOrange]

Cheers Slaine. I might find a use for that