Get the message

[abhid]

hi everybody
i am using following piece of code to catch the messages. Now
MSDN says that you can only use the low word of the message
parameter of the MSG structure. I know this is very much possible
by using LOWORD in windows programming with C, but how can i read the low word of message from VB?

Private Sub getMessage()
Dim MS As MSG
Do While 1
    DoEvents
    PeekMessage MS, Me.hWnd, WM_MOUSEFIRST, WM_MOUSELAST, PM_REMOVE
    Select Case MS.message
        
        'This is where i need help
 
    End Select
Loop
End Sub

Please help me.
Thanks in advance.

[abhid]

Nobody?

[TiPeRa]

Try:

Private Function HiWord(lParam As Long) As Long
    HiWord = lParam \ &H10000 And &HFFFF&
End Function
Private Function LoWord(lParam As Long) As Long
    LoWord = lParam And &HFFFF&
End Function

[Shawn N]

I think that you're going to find that this method very unreliable. Your program might process the message before your routine has a chance to handle it.

[abhid]

This means even if i create a callback function for my app., i cannot gurantee its performance. I cant assure that it will
process each and every message it is supposed to handle. Isn't
it?
Any suggestions?

[Shawn N]

Originally posted by abhid
This means even if i create a callback function for my app., i cannot gurantee its performance. I cant assure that it will
process each and every message it is supposed to handle. Isn't
it?

Pretty Much

Any suggestions?

Subclass your form.

[abhid]

Originally posted by Shawn N
[B Subclass your form. [/B]

hmm...
I have used subclassing technique only once in VB. can you show
me?
Any links or tutorials?

[Megatron]

Here's a basic skeleton:

Add to a Module

Public Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hwnd As Long, ByVal msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Public Declare Function SetWindowLong& Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long)
Public Const GWL_WNDPROC = (-4)
Public WinProcOld As Long
 
Public Function WinProc(ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
    
    If wMsg = WM_MYMESSAGE Then
 
    End If
    
    WinProc = CallWindowProc(WinProcOld&, hwnd&, wMsg&, wParam&, lParam&)
End Function
 
Sub SubClassWnd(hwnd As Long)
    WinProcOld& = SetWindowLong(hwnd, GWL_WNDPROC, AddressOf WinProc)
End Sub
 
Sub UnSubclassWnd(hwnd As Long)
    SetWindowLong hwnd, GWL_WNDPROC, WinProcOld&
    WinProcOld& = 0
End Sub

Add to your Form

Private Sub Form_Load()
    SubClassWnd Me.hwnd
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
    UnSubclassWnd Me.hwnd
End Sub