Indexing a NTFS volume on the network

[dirty_howi]

I have a small problem, i finally got the search routine for a specific file worked out, but it is ooooooooooooooold dog slow. i was wondering if there is a way to index all files of a certain type prior to the main program running so that all file locations are known and can be gotten to through a binary search??? would i just load the directory locations of all files into a array, sort and then search?? if i can do this it would be much quicker than what i have currently, which works but will put you to sleep.

o yea, running NT4.0 with NTFS on the volume in question.

[rudvs2]

what was the method you used to search the for the files???

[dirty_howi]

this

Public Function GetList(ByVal DirPath As String, ByVal FileName As String) _
As String
Dim aa As Long
Dim a As Long
Dim Cp As Long

' Exit if you Forgot to pass a Start Directory.

GetList = ""
If Len(DirPath) = 0 Then Exit Function

' Keep Count of Total Calls of this
' Function so we can unload all the Flist and tempdir Later

dcount = dcount + 1

' Current Index
Cp = dcount

'Load and Set the Path on the control

Load frmBOMExtraction.Flist(Cp)
frmBOMExtraction.Flist(Cp).path = DirPath
DoEvents

' Search For the File

For a = 0 To frmBOMExtraction.Flist(Cp).ListCount - 1
If LCase(frmBOMExtraction.Flist(Cp).List(a)) = LCase(FileName) Then
' File Found Return Path

GetList = DirPath & "\" & frmBOMExtraction.Flist(Cp).List(a)
Exit Function
End If
DoEvents
Next a

' File Not Found

Load frmBOMExtraction.TempDir(Cp)

' If there are sub directories. Search them.

frmBOMExtraction.TempDir(Cp).path = DirPath
If frmBOMExtraction.TempDir(Cp).ListCount > 0 Then
For aa = 0 To frmBOMExtraction.TempDir(Cp).ListCount - 1
GetList = GetList(frmBOMExtraction.TempDir(Cp).List(aa), FileName)
If Len(GetList) <> 0 Then Exit For
Next aa
DoEvents
End If
End Function

[rudvs2]

how about using the findFirstFile and findNextFile API??

its much faster

heres an example of what i have done in the past

Option Explicit
Dim FindData As WIN32_FIND_DATA
Dim FindHandle As Long
Dim FindNextHandle As Long
Dim filestring As String
 
Sub findfilesapi(DirPath As String, FileSpec As String)
Dim txtCheck2() As String
Dim txtCheck1 As String
Dim isSame As Boolean
Dim isThere As Boolean
Dim isAdded As Boolean
Dim x As Integer
Dim strProgram() As String
Dim strExe As String
Dim strPath As String
Dim strName As String
 
DirPath = Trim$(DirPath)
 
If Right(DirPath, 1) <> "\" Then
  DirPath = DirPath & "\"
End If
 
' Find the first file in the selected directory
 
FindHandle = FindFirstFile(DirPath & FileSpec, FindData)
If FindHandle <> 0 Then
  If FindData.dwFileAttributes And FILE_ATTRIBUTE_DIRECTORY Then
    ' It's a directory
    If Left$(FindData.cFileName, 1) <> "." And Left$(FindData.cFileName, 2) <> ".." Then
      filestring = DirPath & Trim$(FindData.cFileName) & "\"
      lstsearch.AddItem filestring, 1
    End If
  Else
    filestring = DirPath & Trim$(FindData.cFileName)
    txtCheck2 = Split(filestring, "\", , 0)
    x = UBound(txtCheck2)
    txtCheck1 = txtCheck2(x)
    txtCheck1 = LTrim$(txtCheck1)
    isSame = LCase(txtCheck1) Like "*.exe*"
    
    If isSame = True Then
        
        strProgram = Split(txtCheck1, ".", , 0)
        strName = strProgram(0)
        strPath = LTrim(filestring)
        strExe = txtCheck1
        isThere = objData.CheckProgram(strExe)
        
        If isThere = False Then
            isAdded = objData.AddProgramItem(strName, strPath, strExe)
        End If
    End If
  
  End If
End If
 
' Now loop and find the rest of the files
If FindHandle <> 0 Then
  Do
  
    DoEvents
    
    FindNextHandle = FindNextFile(FindHandle, FindData)
    If FindNextHandle <> 0 Then
      If FindData.dwFileAttributes And FILE_ATTRIBUTE_DIRECTORY Then
        ' It's a directory
        If Left$(FindData.cFileName, 1) <> "." And Left$(FindData.cFileName, 2) <> ".." Then
          filestring = DirPath & Trim$(FindData.cFileName) & "\"
          lstsearch.AddItem filestring, 1
        End If
      Else
        filestring = DirPath & Trim$(StripNulls(FindData.cFileName))
        txtCheck2 = Split(filestring, "\", , 0)
        x = UBound(txtCheck2)
        txtCheck1 = txtCheck2(x)
        txtCheck1 = LTrim$(txtCheck1)
        isSame = LCase(txtCheck1) Like "*.exe*"
    
    If isSame = True Then
        
        strProgram = Split(txtCheck1, ".", , 0)
        strName = strProgram(0)
        strPath = LTrim(filestring)
        strExe = txtCheck1
        isThere = objData.CheckProgram(strExe)
        
        If isThere = False Then
            isAdded = objData.AddProgramItem(strName, strPath, strExe)
        End If
        
    End If
      
      End If
    Else
      Exit Do
    End If
  Loop
End If
 
' It is important that you close the handle for FindFirstFile
Call FindClose(FindHandle)
End Sub
 
Private Sub cmdDone_Click()
Dim intCount As Integer
Dim lngNum As Long
Dim arrProgs() As String
 
 
lngNum = objData.enumPrograms(arrProgs)
 
If lngNum > 0 Then
    frmremovecom.List1.Clear
    lngNum = lngNum - 1
    
    For intCount = 0 To lngNum
        If arrProgs(intCount) > "" Then
            frmremovecom.List1.AddItem (arrProgs(intCount))
        End If
    Next intCount
 
End If
 
Unload Me
frmremovecom.SetFocus
End Sub
 
Private Sub Form_Activate()
Dim SearchPath As String, FindStr As String
Dim intCount As Integer
 
Screen.MousePointer = vbHourglass
SearchPath = "c:\Program Files\"
FindStr = "*.*"
lstsearch.List(0) = SearchPath
ProgressBar1.Min = 0
ProgressBar1.Max = 5000
intCount = 1
 
Do
  ProgressBar1.Value = intCount
  findfilesapi lstsearch.List(0), FindStr
  lstsearch.RemoveItem 0
  intCount = intCount + 1
Loop Until lstsearch.ListCount = 0
 
Screen.MousePointer = vbDefault
Picture3.Visible = True
cmdDone.Visible = True
ProgressBar1.Value = 5000
 
 
End Sub
 
Private Sub Form_Load()
Picture3.Visible = False
cmdDone.Visible = False
ProgressBar1.Visible = True
End Sub

this was just a little autosearch form I used in one of my apps
you can should be able to grab the code you need for the search from the function

in a module

Option Explicit
 
Declare Function FindFirstFile Lib "kernel32" Alias _
"FindFirstFileA" (ByVal lpFileName As String, lpFindFileData _
As WIN32_FIND_DATA) As Long
Declare Function FindNextFile Lib "kernel32" Alias _
"FindNextFileA" (ByVal hFindFile As Long, _
lpFindFileData As WIN32_FIND_DATA) As Long
Declare Function GetFileAttributes Lib "kernel32" Alias _
"GetFileAttributesA" (ByVal lpFileName As String) As Long
Declare Function FindClose Lib "kernel32" (ByVal hFindFile _
As Long) As Long
Public Const MAX_PATH = 260
Public Const MAXDWORD = &HFFFF
Public Const INVALID_HANDLE_VALUE = -1
Public Const FILE_ATTRIBUTE_ARCHIVE = &H20
Public Const FILE_ATTRIBUTE_DIRECTORY = &H10
Public Const FILE_ATTRIBUTE_HIDDEN = &H2
Public Const FILE_ATTRIBUTE_NORMAL = &H80
Public Const FILE_ATTRIBUTE_READONLY = &H1
Public Const FILE_ATTRIBUTE_SYSTEM = &H4
Public Const FILE_ATTRIBUTE_TEMPORARY = &H100
Public Type FILETIME
    dwLowDateTime As Long
    dwHighDateTime As Long
End Type
Public Type WIN32_FIND_DATA
    dwFileAttributes As Long
    ftCreationTime As FILETIME
    ftLastAccessTime As FILETIME
    ftLastWriteTime As FILETIME
    nFileSizeHigh As Long
    nFileSizeLow As Long
    dwReserved0 As Long
    dwReserved1 As Long
    cFileName As String * MAX_PATH
    cAlternate As String * 14
End Type
 
Public Function StripNulls(OriginalStr As String) As String
If (InStr(OriginalStr, Chr(0)) > 0) Then
    OriginalStr = Left(OriginalStr, _
    InStr(OriginalStr, Chr(0)) - 1)
End If
StripNulls = OriginalStr
End Function