Newtonsoft help - declaring a JObject

[nbrege]

I want to use Newtonsoft JSON.Net to save & load program settings in a file.

I want the structure of the file to be like:

Settings
    Setting1:value
    Setting2:value
    Setting3:value

I can create a JObject as follows, but it doesn't have the top level node:

    Dim settings As JObject = New JObject From {
    {"Setting1", 5},
    {"Setting2", 10},
    {"Setting3", 15}
}

I can't for the life of me figure out how to add the top level "Settings" node in the JObject declaration.

In tried:

    Dim setting As JObject = New JObject From {
    {"Settings",
    {"Setting1", 5},
    {"Setting2", 10},
    {"Setting3", 15}
}}

Basically I want the various settings to be under a Settings node. I could not find any examples in the documentation that shows how to do this. Hoping someone can help me out. Thanks...

[kebo]

Put all of the settings in a class and de/serialize the class to/from json as needed and you can avoid woring with jObjects completely. It won't give you control over the file structure, but does that really matter?

Imports Newtonsoft.Json
Imports System.IO
 
...
 
    Public Class mySettings
 
        Public Property Setting1() As String = "1"
        Public Property Setting2() As String = "2"
        Public Property Setting3() As String = "3"
    End Class
 
...
 
Dim settings As New mySettings
Dim filePath As String = "some path"
 
'serialize/save it
Dim json As String = JsonConvert.SerializeObject(settings)
File.WriteAllText(filePath, json)
 
'read/deserialize it
json = File.ReadAllText(filePath)
settings = JsonConvert.DeserializeObject(Of mySettings)(json)

Kevin

[nbrege]

Put all of the settings in a class and de/serialize the class to/from json as needed and you can avoid woring with jObjects completely. It won't give you control over the file structure, but does that really matter?

Kebo ... thank you for the reply. The code you posted works great. The reason I want a top level node is because there is more to my settings than what I posted. Here is what I really want:

Settings
    Setting1:value
    Setting2:value
    Setting3:value
History
    Item
        Param1:someValue
        Param2:someValue
        Param3:someValue
    Item
        Param1:someValue
        Param2:someValue
        Param3:someValue
    Item
        Param1:someValue
        Param2:someValue
        Param3:someValue

I want to have a "History" section that is dynamic, where Items are added when a process completes. I then want to read in the History items at program startup & display them in a DataGridView control. The Settings will also be read in to set the state of controls on a form. I would like settings & history to be in the same json file. I am currently using a SQLite database to save these things, but I feel like that is overkill for the few things I need to save.

I am basically trying to duplicate this structure:



Any idea how I would implement a mechanism like this?

[kebo]

You would need to create a dictionary(of string, object) and put your settings and history it, then serialize...
Note that on the deserialize, your settings in the dictionary will be a jObject and would need to be deserialized agin. Same with the history.

Dim settings As New mySettings
        Dim history As New List(Of String)
        history.Add("this")
        history.Add("that")
        history.Add("the other")
 
        Dim d As New Dictionary(Of String, Object)
        d.Add("Settings", settings)
        d.Add("History", history)
 
        Dim json As String = JsonConvert.SerializeObject(d)
 
        Dim filePath As String = "c:\test.json"
        File.WriteAllText(filePath, json)
 
 
        json = File.ReadAllText(filePath)
        d = JsonConvert.DeserializeObject(Of Dictionary(Of String, Object))(json)
 
        settings = JsonConvert.DeserializeObject(Of mySettings)(d("Settings").ToString())
        history = JsonConvert.DeserializeObject(Of List(Of String))(d("History").ToString())

The resulting Json looks like this,

{
  "Settings": {
    "Setting1": "1",
    "Setting2": "2",
    "Setting3": "3"
  },
  "History": [
    "this",
    "that",
    "the other"
  ]
}

[dday9]

Here is how you can use the Newtonsoft JObject and JArray classes:

Private Function BuildObjectFromTokens(values As Dictionary(Of String, JToken)) As JObject
	Dim container = New JObject()
	For Each value In values
		container.Add(value.Key, value.Value)
	Next
	Return container
End Function

Private Function BuildArrayFromObjects(values As IEnumerable(Of JObject)) As JArray
	Dim collection = New JArray()
	For Each value In values
		collection.Add(value)
	Next
	Return collection
End Function

Private Function BuildObjectFromDictionary(values As Dictionary(Of String, String)) As JObject
	Dim container = New JObject()
	For Each value In values
		container.Add(value.Key, value.Value)
	Next
	Return container
End Function

And here is an example of how to use it: https://dotnetfiddle.net/nQ8UtA

[nbrege]

Thanks for the help guys. I'm starting to figure this out, but I'm still stuck on one part. How do I add in a history item to an existing file?
This is what I tried:

        Dim json As String = IO.File.ReadAllText(File)
        Dim jsonObject As JObject = JObject.Parse(json)

        Dim histToken As JToken = jsonObject.SelectToken("history")
        Dim histItems As JArray = CType(histToken, JArray)

        Dim history As New JObject
        history.Add("Param1", "SomeValue")
        history.Add("Param2", "SomeValue")
        history.Add("Param3", "SomeValue")

        Dim d As New Dictionary(Of String, Object)
        d.Add("History", history)

        histItems.Add(d)

        IO.File.WriteAllText(file, JsonConvert.SerializeObject(jsonObject, Formatting.Indented))

[dday9]

If you take the approach I gave you, then it'd be:

Dim historyArray = DirectCast(rootObject.Item("History"), JArray)
Dim historyItem = BuildObjectFromDictionary(New Dictionary(Of String, String) From { { "Param1", "SomeValue" },  { "Param2", "SomeValue" },  { "Param3", "SomeValue" } })
historyArray.Add(historyItem)