[RESOLVED] VB.NET Combine .txt files without header

[GideonE]

Hi all

I have the following code to combine all .txt files in a folder into a single .txt file :

Dim path As String = "D:\Wingerdbou\Lutzville2\InvoerDataFiles\Ander Organisasies\Wesbank\HistorieseFiles\"
        Dim topath As String = "D:\Wingerdbou\Lutzville2\InvoerDataFiles\Ander Organisasies\Wesbank\HistorieseFiles\"
        Dim files As String = "*.txt"
        Dim txtFiles() As String
        txtFiles = Directory.GetFiles(path, files)
        Using writer As New StreamWriter(topath & "\Combined.txt")
            For i As Integer = 0 To txtFiles.Length - 1
                Using reader As StreamReader = File.OpenText(txtFiles(i))
                    writer.Write(reader.ReadToEnd())

                End Using
            Next i

        End Using

However in the process I also combine all the headers in the first line of all the files into the new .txt file.
I just cannot figure out how to use only one column header. The data structure of the files are identical.


Any help would be appreciated.

Regards

[jmcilhinney]

Dim sourceFolderPath = "source folder path here"
Dim outputFilPath = "output file path here"
 
Dim sourceFilePaths = Directory.GetFiles(sourceFolderPath, "*.txt")
 
Using writer As New StreamWriter(outputFilPath)
    For i = 0 To sourceFilePaths.GetUpperBound(0)
        Dim lines = File.ReadLines(sourceFilePaths(i))
 
        'Skip the first line if this is not the first file.
        If i > 0 Then
            lines = lines.Skip(1)
        End If
 
        For Each line In lines
            writer.WriteLine(line)
        Next
    Next
End Using

[GideonE]

Thank you jmcilhinney.

Works like a charm.
However the new file in in Windows(CRLF) UTF8 format. The original files are in Unix(LF) UTF8 format.
For importing it into MYSQL, I changed the carriage return to \r\n instead of \n (which works Unix(LF) files).
I have tried both \r\n and \n , but it does not import with no error messages.
Any Ideas?

[jmcilhinney]

You could change this:

writer.WriteLine(line)

to this:

writer.Write(line & ControlChars.Lf)

[GideonE]

Thank you very much.