[RESOLVED] How can I add a link (like TreeView control has) into a usercontrol?

[Simonetos The Greek]

I am working on a UserControl and I want to place something like this link label (?) which we can see under TreeView control in Properties Window.

I don't want it to open an editor window, like in TreeView control does. I want to add my own action. The question is, how can I place a link like this on my UserControl? Is it possible?

Thank you in advance!!!

[techgnome]

It's not clear if you want it at design time in the properties window, or on the user control itself. If you want it on the user control itself then a LinkLabel is the way to go. If you mean at design time in the properties window.... I'm not sure.

-tg

[Simonetos The Greek]

It's not clear if you want it at design time in the properties window, or on the user control itself. If you want it on the user control itself then a LinkLabel is the way to go. If you mean at design time in the properties window.... I'm not sure.

-tg

Yes, sorry I didn't mention it, I want it at design time in the properties window!!!

[jmcilhinney]

I've done very little when it comes to custom controls so I don't know a lot on this subject but I think that this might be a good place to start:

https://www.codeproject.com/articles...rtygrid-comman

[Sitten Spynne]

JMC's link is a good reference, these are called "Designer Verbs" in UI designer parlance and it takes a bit of dancing to set them up, but once you've done it the first time it's easier the next.

[Simonetos The Greek]

I've done very little when it comes to custom controls so I don't know a lot on this subject but I think that this might be a good place to start...

Thanks for the link!!! Of course I have to study it first and manage to understand what is happening "in there" lol.

JMC's link is a good reference, these are called "Designer Verbs" in UI designer parlance and it takes a bit of dancing to set them up, but once you've done it the first time it's easier the next.

"Designer Verbs"... Nice, now I know how to search for more informations about it!!! Thank you very much!!!

[jmcilhinney]

For the record, the way I found that link was to read the documentation for the PropertyGrid control, which is the same control that is used in the Properties window of the WinForms designer, to see what it said about that area. From that I got the term "command pane" and then I just did a web search for "propertygrid command pane".

[Simonetos The Greek]

For the record, the way I found that link was to read the documentation for the PropertyGrid control, which is the same control that is used in the Properties window of the WinForms designer, to see what it said about area. From that I got the term "command pane" and then I just did a web search for "propertygrid command pane".

Very useful note, mostly for people like me, who sometimes don't know how to search things because of poor terminology knowledge...

[Simonetos The Greek]

Well, here is a simple example...

1. If we haven't done already, we should first add a reference to System.Design. Goto Reference Manager > Assemblies > Framework and find System.Design. Check it and click OK.

2. Into our UserControl code, we make sure that we already have Imports System.ComponentModel and Imports System.ComponentModel.Design references.

3. Over our UserControl class, we add a Designer attribute, to specify our ControlDesigner for this UserControl.

Imports System.ComponentModel 
Imports System.ComponentModel.Design

<Designer(GetType(MyControlDesigner))>
Public Class UserControl1
    'Our UserControl code in here...
End Class

4. Under our UserControl class, we create a new class by the name "MyControlDesigner" which will be our ControlDesigner.

Public Class MyControlDesigner 

End Class

5. Now, for example, lets create a Verb which will Dock and Undock our UserControl in ParentForm.

Public Class MyControlDesigner
     Inherits System.Windows.Forms.Design.ControlDesigner 'Inherit from ControlDesigner class.

    Private MyVerbs As DesignerVerbCollection

    Public Sub New()

    End Sub

    Public Overrides ReadOnly Property Verbs() As DesignerVerbCollection
        Get
            If MyVerbs Is Nothing Then
                MyVerbs = New DesignerVerbCollection 'A new DesignerVerbCollection to use for our DesignerVerbs.
                MyVerbs.Add(New DesignerVerb("Dock In ParentForm", New  EventHandler(AddressOf OnMyCommandLinkClicked))) 'An Event Handler for  Docking our UserControl.
                MyVerbs.Add(New DesignerVerb("Undock in ParentForm", New  EventHandler(AddressOf OnMyCommandLinkClicked))) 'An Event Handler for  Undocking our UserControl.
                MyVerbs(1).Visible = False 'We hide second Verd by default.
            End If
            Return MyVerbs
        End Get
    End Property

    Private Sub OnMyCommandLinkClicked(ByVal sender As Object, ByVal args As EventArgs)
        Dim _UserControl As UserControl1 = CType(Me.Control,  UserControl1) 'Reference to our UserControl1 Class, so we can access  it's Properties and Methods.
        If _UserControl.Dock = DockStyle.None Then 'If UserControl is Undocked then...
            _UserControl.Dock = DockStyle.Fill 'Dock UserControl in ParentForm.
            MyVerbs(0).Visible = False 'Hide "Dock In ParentForm" DesignerVerb.
            MyVerbs(1).Visible = True 'Show "Undock in ParentForm" DesignerVerb.
        Else
            _UserControl.Dock = DockStyle.None 'Undock UserControl.
            MyVerbs(1).Visible = False 'Hide "Undock in ParentForm" DesignerVerb.
            MyVerbs(0).Visible = True 'Show "Dock in ParentForm" DesignerVerb.
        End If
    End Sub
End Class

6. Then we Build our project and we add our UserControl into our test Form.