[RESOLVED] Compare string with items in List of String, ignoring case-sensitive ?

[LuckyLuke82]

Hi,

I have a string which user writes in app. Now I want to compare this string with items in List of strings, but without case-sensitive.

This is what I have so far:

  Dim ListToCheck As String() = {"London", "Paris", "Amsterdam"}

  Dim MyString = "John is currently at a meeting in london."

  Dim b As Boolean = ListToCheck.Any(Function(s) MyString.Contains(s))

                If b = True Then

                    MsgBox("string contains an item from List")
                Else

                    MsgBox("string doesn't contain an item from List")

                End If

This returns correct result, but case-sensitive. I know that "StringComparer.CurrentCultureIgnoreCase" does that thing, but can I include It into LINQ, and how ?

[jmcilhinney]

Your issue there is that the String.Contains method does not support case-insensitive comparisons for some reason. What you can do is use String.IndexOf instead, which does have overloads that can be used to ignore case. Note that IndexOf returns an index rather a Boolean, so you must compare that index to -1 to get your Boolean value. -1 means that the original does not contain the substring and anything else means that it does.

[jmcilhinney]

It's actually quite easy to write your own Contains method that does support case-insensitive comparisons. You can add this module to your project to provide such a method that extends the String type:

Imports System.Runtime.CompilerServices
 
Friend Module StringExtensions
 
    <Extension>
    Public Function Contains(source As String,
                             value As String,
                             comparisonType As StringComparison) As Boolean
        Return source.IndexOf(value, comparisonType) <> -1
    End Function
 
End Module

Because it's an extension method, you can call it as you would a conventional module member:

Dim result = Contains(myString, mySubstring, myStringComparison)

or you can call it with two arguments as though it's a member of the what would otherwise be the first argument:

Dim result = myString.Contains(mySubstring, myStringComparison)

That means that you can call that method in place of the String.Contains methodthat you're already calling simply by adding the second argument.

[LuckyLuke82]

Thanks jmcilhinney,

but how would a 1 line code using IndexOf look like, Is It even possible ?

My solution is also this:

 Dim ListToCheck As String() = {"LONDON", "PARIS", "AMSTERDAM"}

Dim MyString = "John is currently at a meeting in london."

  Dim b As Boolean = ListToCheck.Any(Function(s) MyString.ToUpper.Contains(s))

                If b = True Then

                    MsgBox("string contains an item from List")
                Else

                    MsgBox("string doesn't contain an item from List")

                End If

Basically, I wrote all string in a List with upper case, and compare that with MyString.ToUpper. I'm not sure what is better, and most important - faster.

[jmcilhinney]

It's generally not a good idea to try to implement a case-insensitive comparison by comparing all upper-case or all lower-case. It will work sometimes but not others.

As for using IndexOf, I already told you what to do. Instead of calling Contains to get a Boolean value, you call IndexOf and compare the result to -1 to get a Boolean. You just have to read the code in the extension method I provided to see how to implement the equivalent of Contains using IndexOf.

[LuckyLuke82]

Ok,

thanks a lot.

[fenster89411]

I was looking for exactly THIS! Thanks jmcilhinney .... Brilliant!