[RESOLVED] [NOT - RESOLVED] View images in the debugger

[kebo]

Hey all,

Does anyone know if there is a way to view images directly from the debugger in VS2013 while stopped at a break point? I am looking for something that would be analogous to the DataSet Visualizer for viewing a data table except for an image. If not could this be created as an add on?

Thanks kevin

[topshot]

You can likely get something to work by adapting one of these:
https://bitmapsourcevisualizer.codeplex.com/
https://marketplace.visualstudio.com...ggerVisualizer
https://marketplace.visualstudio.com...ualizerPreview

[boops boops]

Besides topshot's recommendations, it's not hard to code your own DebuggerVisualizer for images. This has the advantage that you can customize it however you like. Here's a VB.Net version based on the CodeProject article by Tomer Noy. It dates from VS2005 but it works fine in VS2013 and I'm sure it still will in VS2015/7.

To make and install it:
1. Start a ClassLibary project.
2. Add the following project references:

Microsoft.VisualStudio.DebuggerVisualizers
System.Drawing
System.Windows.Forms

3. Code a Class as follows:

Imports Microsoft.VisualStudio.DebuggerVisualizers
Imports System.Windows.Forms
Imports System.Drawing
 
<Assembly: System.Diagnostics.DebuggerVisualizer(GetType(ImageVisualizer.DebuggerSide), GetType(VisualizerObjectSource), Target:=GetType(System.Drawing.Image), Description:="Image Visualizer")> 
Namespace ImageVisualizer
   Public Class DebuggerSide
      Inherits DialogDebuggerVisualizer
      Protected Overrides Sub Show(windowService As IDialogVisualizerService, objectProvider As IVisualizerObjectProvider)
         Dim image As Image = DirectCast(objectProvider.GetObject(), Image)
         Dim form As New Form With {.Text = image.Size.ToString, .AutoSize = True, .FormBorderStyle = FormBorderStyle.FixedToolWindow}
         Dim pictureBox As New PictureBox With {.Image = image, .Parent = form, .Dock = DockStyle.Fill}
         windowService.ShowDialog(form)
      End Sub
   End Class
End Namespace

4. Build the solution.

5. In File Explorer, find the compiled ImageVisualizer.dll in the project's bin\Debug folder and copy it into the installed Visual Studio Common7/Packages/Debugger/Visualizers folder.

Restart Visual Studio and, hey presto, you have a debugger visualizer for images!

BB

[kebo]

hey presto, you have a debugger visualizer for images!

Now that what I'm talking about. I should have made this post years ago. Thanks a ton BB.

BTW, the dll can also be put in the My Documents\ VisualStudioVersion \Visualizers folder as well.

[kebo]

I've rolled up to VS2017, and my visualizer broke with the following message,
.
It was working, and still does work in VS2013.

I've tried rebuilding the visualizer in VS2017, but to no avail. This is the code, which as you can see inherits from DialogDebuggerVisualizer.

Imports Microsoft.VisualStudio.DebuggerVisualizers ' < -- import the namespace
Imports System.Windows.Forms
Imports System.Drawing
 
<Assembly: System.Diagnostics.DebuggerVisualizer(GetType(ImageVisualizer.DebuggerSide), GetType(VisualizerObjectSource), Target:=GetType(System.Drawing.Image), Description:="Image Visualizer")> 
Namespace ImageVisualizer
    Public Class DebuggerSide
        Inherits DialogDebuggerVisualizer ' < - inherit the Visualizer
        Protected Overrides Sub Show(windowService As IDialogVisualizerService, objectProvider As IVisualizerObjectProvider)
            Dim image As Image = DirectCast(objectProvider.GetObject(), Image)
            Dim form As New Form With {.Text = image.Size.ToString, .AutoSize = True}
            Dim pictureBox As New PictureBox With {.BackgroundImage = image, .Parent = form, .BackgroundImageLayout = ImageLayout.Zoom, .Dock = DockStyle.Fill}
 
            Try
                windowService.ShowDialog(form)
            Catch ex As Exception
                MessageBox.Show(String.Format("{0}{1}{1}{2}", ex.Message, Environment.NewLine, ex.ToString))
            End Try
 
        End Sub
    End Class
End Namespace

Not sure whats going on here.Has anyone seen this with their visualizers, or is there something special I need to do for VS2017

[boops boops]

That's strange because the class clearly does inherit from the correctly named class. I don't have VS2017 installed to try it out, but I wonder if you are referencing an outdated version of Microsoft.VisualStudio.DebuggerVisualizer? I notice that there's a version 12 as well as a version 10.

BB

[kebo]

Well you were certainly on the right track. To get it to work in VS2017, I had to build the visualizer in VS2017 with DebuggerVisualizer version 15.

Thanks for the input. My world is right once again.