Getting list of all running programs...

[AlbafaN]

I'm making a program that will scan threw all the programs the computer is running. Like all of the programs in the "Close Program" dialog (ctrl+alt+del). Once I get the list, I need to get the path of all the exe's for each program, so I can scan threw the file, kind of like a virus scanner does. How would I go about getting the file path's of all the running programs?

[chrisjk]

I've been told this doesn't work on NT, but it does work on 95/98. You'll need a listbox on a form

Paste this into a module

Public Const TH32CS_SNAPPROCESS As Long = 2&
Public Const MAX_PATH As Integer = 260
 
Public Type PROCESSENTRY32
    dwSize As Long
    cntUsage As Long
    th32ProcessID As Long
    th32DefaultHeapID As Long
    th32ModuleID As Long
    cntThreads As Long
    th32ParentProcessID As Long
    pcPriClassBase As Long
    dwFlags As Long
    szExeFile As String * MAX_PATH
End Type
 
Public Declare Function CreateToolhelpSnapshot Lib "Kernel32" Alias "CreateToolhelp32Snapshot" (ByVal lFlags As Long, ByVal lProcessID As Long) As Long
Public Declare Function ProcessFirst Lib "Kernel32" Alias "Process32First" (ByVal hSnapShot As Long, uProcess As PROCESSENTRY32) As Long
Public Declare Function ProcessNext Lib "Kernel32" Alias "Process32Next" (ByVal hSnapShot As Long, uProcess As PROCESSENTRY32) As Long
Public Declare Sub CloseHandle Lib "Kernel32" (ByVal hPass As Long)

Usage

Dim hSnapShot As Long
Dim uProcess As PROCESSENTRY32
Dim r As Long
 
hSnapShot = CreateToolhelpSnapshot(TH32CS_SNAPPROCESS, 0&)
 
If hSnapShot = 0 Then
    Exit Sub
End If
 
uProcess.dwSize = Len(uProcess)
r = ProcessFirst(hSnapShot, uProcess)
 
Do While r
    List1.AddItem uProcess.szExeFile
    r = ProcessNext(hSnapShot, uProcess)
Loop
 
Call CloseHandle(hSnapShot)

[AlbafaN]

OMG, ty so much! thats exactly what i wanted! yAy!