Tasklist and Termination

[jax]

Hi,

How can i get a list of programs running (those listed on the taskbar) and then choose to terminate some of them? Is there any ways to verify or wait till these programs are successfully terminated before i carry on my execution?

I searched through the general vb questions threads but found myself more confused about processes and those on the taskbar.

I am using vb6 and intended to use the application on Win 9x and Win ME only.

Thanks for any advice.

[Matthew Gates]

To list the running applications:

Private Declare Function CreateToolhelpSnapshot Lib "Kernel32" Alias "CreateToolhelp32Snapshot" _
(ByVal lFlags As Long, ByVal lProcessID As Long) As Long
 
Private Declare Function ProcessFirst Lib "Kernel32" _
Alias "Process32First" (ByVal hSnapShot As Long, uProcess As _
PROCESSENTRY32) As Long
 
Private Declare Function ProcessNext Lib "Kernel32" _
Alias "Process32Next" (ByVal hSnapShot As Long, uProcess As _
PROCESSENTRY32) As Long
 
Private Declare Sub CloseHandle Lib "Kernel32" _
(ByVal hPass As Long)
 
Private Const TH32CS_SNAPPROCESS As Long = 2&
Private Const MAX_PATH As Integer = 260
 
Private Type PROCESSENTRY32
  dwSize As Long
  cntUsage As Long
  th32ProcessID As Long
  th32DefaultHeapID As Long
  th32ModuleID As Long
  cntThreads As Long
  th32ParentProcessID As Long
  pcPriClassBase As Long
  dwFlags As Long
  szExeFile As String * MAX_PATH
End Type
 
 
 
Private Sub Command1_Click()
 
    Dim hSnapShot As Long
    Dim uProcess As PROCESSENTRY32
    Dim r As Long
 
    hSnapShot = CreateToolhelpSnapshot(TH32CS_SNAPPROCESS, 0&)
 
    If hSnapShot = 0 Then
        Exit Sub
    End If
 
    uProcess.dwSize = Len(uProcess)
 
    r = ProcessFirst(hSnapShot, uProcess)
 
    Do While r
        List1.AddItem uProcess.szExeFile
        r = ProcessNext(hSnapShot, uProcess)
    Loop
 
    Call CloseHandle(hSnapShot)
 
End Sub

To close a running application (Note: This does not work on NT (nor do I think the code above does either):

rivate Declare Function ProcessFirst Lib "kernel32" _
Alias "Process32First" (ByVal hSnapshot As Long, uProcess As _
PROCESSENTRY32) As Long
 
Private Declare Function ProcessNext Lib "kernel32" _
Alias "Process32Next" (ByVal hSnapshot As Long, uProcess As _
PROCESSENTRY32) As Long
 
Private Declare Function CreateToolhelpSnapshot Lib "kernel32" _
Alias "CreateToolhelp32Snapshot" (ByVal lFlags As Long, _
lProcessID As Long) As Long
 
Private Declare Function CloseHandle Lib "kernel32" (ByVal _
hObject As Long) As Long
 
Private Declare Function OpenProcess Lib "kernel32" (ByVal _
dwDesiredAccess As Long, ByVal bInheritHandle As Long, _
ByVal dwProcessId As Long) As Long
 
Private Declare Function TerminateProcess Lib "kernel32" (ByVal _
hProcess As Long, ByVal uExitCode As Long) As Long
 
Private Const MAX_PATH = 260
 
Private Type PROCESSENTRY32
    dwSize As Long
    cntUsage As Long
    th32ProcessID As Long
    th32DefaultHeapID As Long
    th32ModuleID As Long
    cntThreads As Long
    th32ParentProcessID As Long
    pcPriClassBase As Long
    dwFlags As Long
    szexeFile As String * MAX_PATH
End Type
 
 
 
Private Function KillApp(myName As String) As Boolean
    Const PROCESS_ALL_ACCESS = 0
    Dim uProcess As PROCESSENTRY32
    Dim rProcessFound As Long
    Dim hSnapshot As Long
    Dim szExename As String
    Dim exitCode As Long
    Dim myProcess As Long
    Dim AppKill As Boolean
    Dim appCount As Integer
    Dim i As Integer
    On Local Error GoTo Finish
    appCount = 0
    
    Const TH32CS_SNAPPROCESS As Long = 2&
    
    uProcess.dwSize = Len(uProcess)
    hSnapshot = CreateToolhelpSnapshot(TH32CS_SNAPPROCESS, 0&)
    rProcessFound = ProcessFirst(hSnapshot, uProcess)
    
    Do While rProcessFound
        i = InStr(1, uProcess.szexeFile, Chr(0))
        szExename = LCase$(Left$(uProcess.szexeFile, i - 1))
        If Right$(szExename, Len(myName)) = LCase$(myName) Then
            KillApp = True
            appCount = appCount + 1
            myProcess = OpenProcess(PROCESS_ALL_ACCESS, False, uProcess.th32ProcessID)
            AppKill = TerminateProcess(myProcess, exitCode)
            Call CloseHandle(myProcess)
        End If
        rProcessFound = ProcessNext(hSnapshot, uProcess)
    Loop
 
    Call CloseHandle(hSnapshot)
Finish:
End Function

[jax]

Thanks a lot Mat, will spend some time reading the codes and understanding them.

[jax]

Hi again,

The code that was adviced by Mat works real good, however, i found out that certain programs could avoid being 'killed' One good example is ICQ 2000b.

There is one situation when ICQ could not detect a connection to the net and output an error message. If this message is not cleared by the user, the system cannot log off or shutdown. Even the app i just compiled using Mat's code does not shut the program down, is there a way to curb this ICQ program?

thanks to any potential advisors