Detecting titlebar click event

[whitless]

Please could anyone help, Im trying to detect a click event in the title bar, I have looked at a few suguestions but im very confused they dont seem to do what i want. Im not using mdi forms, i just want to detect an click, mouse down etc events.

[Megatron]

You could subclass your window and catch the WM_NCLBUTTONDOWN event.

Add to a Module

Public Declare Function SetWindowLong& Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long)
Public Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hwnd As Long, ByVal msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Public Const GWL_WNDPROC = (-4)
Public WinProcOld As Long
Private Const WM_NCLBUTTONDOWN = &HA1
 
Public Function WinProc(ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
    If wMsg = WM_NCLBUTTONDOWN Then
        '< -- Add code here
    End If
    
    WinProc = CallWindowProc(WinProcOld&, hwnd&, wMsg&, wParam&, lParam&)
End Function
 
Sub SubClassWnd(hwnd As Long)
    WinProcOld& = SetWindowLong(hwnd, GWL_WNDPROC, AddressOf WinProc)
End Sub
 
Sub UnSubclassWnd(hwnd As Long)
    SetWindowLong hwnd, GWL_WNDPROC, WinProcOld&
    WinProcOld& = 0
End Sub

Add to a Form.

Private Sub Form_Load()
    SubClassWnd hwnd
End Sub
    
Private Sub Form_Unload(Cancel As Integer)
    UnSubclassWnd hwnd
End Sub