How to improve this

[jmsrickland]

Private Sub Timer1_Timer()
 On Error Resume Next
 Static HH As Single
 Static MM As Single
 Static SS As Single
 Static TS As Single
 Static TSS As Single

 TS = TS + 1
 
 TSS = TS / 10
 
 If TSS = ".9" Then
   TS = 0
   SS = SS + 1
   
   If SS = "59" Then
     SS = 0
     MM = MM + 1
     
     If MM = "59" Then
       MM = 0
       HH = HH + 1
     End If
   End If
 End If
 
 Label5.Caption = Right("00" & HH, 2) & ":" & _
                  Right("00" & MM, 2) & ":" & _
                  Right("00" & SS, 2) & ":" & _
                  Right("00" & TS, 2)
 
End Sub

[4x2y]

Try this

Private Sub Timer1_Timer()

    Static HH As Long
    Static MM As Long
    Static SS As Long
    Static TS As Long
    
    TS = (TS + 1) Mod 100
    
    If TS = 0 Then
        SS = (SS + 1) Mod 60
        If SS = 0 Then
            MM = (MM + 1) Mod 60
            If MM = 0 Then
                HH = (HH + 1) Mod 24
            End If
        End If
    End If

 
 Label5.Caption = Right("00" & HH, 2) & ":" & _
                  Right("00" & MM, 2) & ":" & _
                  Right("00" & SS, 2) & ":" & _
                  Right("00" & TS, 2)
 
End Sub

[Jacob Roman]

And if you really really want to improve it, and have more peformance, remove On Error Resume Next, add CSng() on the lines using Mod wrapping parenthesis around the code. This is on 4x2ys code of course. Also never treat singles as strings. I see you wrapped quotes around the numbers.

[jmsrickland]

@4x2y

Thanks but I changed TS = (TS + 1) Mod 100 to Mod 10. The last two numbers are in 10th of a second

[4x2y]

I forgot to change variables declaration to Long instead of Single, it is better for speed and also there is no need for single type. There isn't any error can occur from that code, so no need for On Error Resume Next as Jacob Roman said.

The last two numbers are in 10th of a second

In this case replace the last line with

 Label5.Caption = Right("00" & HH, 2) & ":" & _
                  Right("00" & MM, 2) & ":" & _
                  Right("00" & SS, 2) & ":" & _
                  TS

[Bonnie West]

Since the Mod operator involves division (even with Integer operands), I therefore believe it is slower than the + operator.

[4x2y]

The code without using Mod

Private Sub Timer1_Timer()

    Static HH As Long
    Static MM As Long
    Static SS As Long
    Static TS As Long
    
    TS = TS + 1
    
    If TS = 10 Then
        TS = 0
        SS = SS + 1
        If SS = 60 Then
            SS = 0
            MM = MM + 1
            If MM = 60 Then
                MM = 0
                HH = HH + 1
                If HH = 24 Then
                    HH = 0
                End If
            End If
        End If
    End If

 
 Label5.Caption = Right("00" & HH, 2) & ":" & _
                  Right("00" & MM, 2) & ":" & _
                  Right("00" & SS, 2) & ":" & _
                  TS
 
End Sub

[4x2y]

Double post...

[Bonnie West]

The code without using Mod

Merri once stated that fast code is typically lengthy and I mostly agree with him.