Folder Window

[TheSarlacc]

take a look at the screenshot and tell me how what code and/or controls i would use to get this window. thanks

[Matthew Gates]

Private Declare Sub CoTaskMemFree Lib "ole32.dll" _
(ByVal hMem As Long)
 
Private Declare Function lStrCat Lib "kernel32" Alias "lstrcatA" _
(ByVal lpString1 As String, ByVal lpString2 As String) As Long
 
Private Declare Function SHBrowseForFolder Lib "shell32" (lpbi As _
BROWSEINFO) As Long
 
Private Declare Function SHGetPathFromIDList Lib "shell32" _
(ByVal pidList As Long, ByVal lpBuffer As String) As Long
 
Private Type BROWSEINFO
    hwndOwner As Long
    pIDLRoot As Long
    pszDisplayName As Long
    lpszTitle As Long
    ulFlags As Long
    lpfnCallback As Long
    lParam As Long
    iImage As Long
End Type
 
Private Const BIF_RETURNONLYFSDIRS = 1
 
Public Function BrowseForFolder(ByVal lHwnd As Long, ByVal sPrompt As String) As String
    Dim tBI As BROWSEINFO
    Dim lList As Long
    Dim lResult As Long
    Dim sPath As String
    Dim sString As String
    
    sString = Space(260)
    With tBI
        .hwndOwner = lHwnd
        .lpszTitle = lStrCat(sPrompt, Chr(0))
        .pszDisplayName = StrPtr(sString)
        .ulFlags = BIF_RETURNONLYFSDIRS
    End With
    lList = SHBrowseForFolder(tBI)
    sString = StrConv(sString, vbUnicode)
    If lList Then
        sPath = Space(260)
        lResult = SHGetPathFromIDList(lList, sPath)
        Call CoTaskMemFree(lList)
        sPath = Left$(sPath, InStr(sPath, Chr(0)) - 1)
    End If
    BrowseForFolder = sPath
End Function
 
 
 
Private Sub Command1_Click()
    Msgbox BrowseForFolder(hWnd, "Select Directory..")
End Sub