Replacing Strings based on Text File

[RickHB]

Hello guys! I USE VISUAL BASIC 2008!

The problem is that I have a plain text file in which TAG's have that the user can customize. So far so good. Everything is saved in text file, like this:
example:

<tag1> = http://www.vbforums.com/
<tag2> = http://www.google.com.br
<tag3> = http://www.youtube.com.br

Anyway, it's a huge list.

There's a RichTextBox in this Form. I want that when user writes some of Tags (for example <tag1>), the same be replaced by what is after the equal sign (in the case, http://www.vbforums.com/).

EXAMPLE:

Hi! I'm fan of <tag1>

BECAME:

Hi! I'm fan of http://www.vbforums.com/

Is it possible?
Grateful, RickHB.

[RickHB]

Does someone can help me?

Please!

[dunfiddlin]

Yes it's possible but with varying degrees of difficulty. Do you want the tags to be replaced instantly or is it enough to do it as a finalising process for the whole text? And now huge is huge?

[RickHB]

Yes it's possible but with varying degrees of difficulty. Do you want the tags to be replaced instantly or is it enough to do it as a finalising process for the whole text? And now huge is huge?

One need not be replaced as text is typed. It is when you press a button to finalize the text.

I hope you understood what I wanted to do.
These tags can be changed as the user wishes.

An yeah, the list is Huge... There're 60 Tag's or more, the user can choose.

[dunfiddlin]

Ok then. First 60+ is not huge. I use a similar list of 19000+ in one of my programs! So, next question, how are you intending to let the user know what tag represents what site? Will there be a permanent visible key of some sort?

[RickHB]

This is not the problem. The user can ADD or REMOVE Tag's acordding his need.

I just need that the richtextbox replace what is before the "=" by the string after "=", but these TAG's can vary, the user can change it. Everything is save in a text file in that structure that I showed.

[ThomasJohnsen]

You can try something like:

'Replaces tags in text and returns the result.
    Private Function replacetags(ByVal text As String, ByVal dict As Dictionary(Of String, String)) As String
 
        Dim parsedtext As New StringBuilder
        Dim indexst, indexgt, curindex As Integer
        Dim tag As String
 
        'Reset current progress and get the location of first "<"c
        curindex = 0
        indexst = text.IndexOf("<"c)
 
        While indexst > 0
 
            'Append the text before the "<"c to the result.
            parsedtext.Append(text.Substring(curindex, indexst - curindex))
 
            'Find the first ">"c after the found "<"c
            indexgt = text.IndexOf(">"c, indexst)
 
            'If no ">"c is found, we're done.
            If indexgt < 0 Then
 
                'Append the rest of the text to the result
                parsedtext.Append(text.Substring(indexst))
 
                Return parsedtext.ToString
 
            End If
 
            'Retrieve the text between "<"c and ">"c
            tag = text.Substring(indexst + 1, indexgt - indexst - 1)
 
            'Is the tag in the dictionary?
            If dict.ContainsKey(tag) Then
 
                'Append the text associated with the tag to the result.
                parsedtext.Append(dict(tag))
 
            Else
 
                'Append <tag> to the result
                parsedtext.Append(text.Substring(indexst, indexgt - indexst + 1))
 
            End If
 
            'Update the current progress within the string
            curindex = indexgt + 1
 
            'Find index of "<"c after the current index
            indexst = text.IndexOf("<"c, curindex)
 
        End While
 
        'Append the last bit of text.
        parsedtext.Append(text.Substring(curindex))
 
        Return parsedtext.ToString
 
    End Function
 
    'Reads tags and descriptions from file and organizes them into a dictionary ordered by the tag.
    Private Function readtags(ByVal filename As String) As Dictionary(Of String, String)
 
        Static parse As Regex = New Regex("^\<(?<tag>[^\>]+)\>\s*=\s*(?<desc>.+)$", RegexOptions.Compiled)
 
        Dim lines() As String = File.ReadAllLines(filename)
        Dim dict As Dictionary(Of String, String) = New Dictionary(Of String, String)
        Dim m As Match
 
        For Each line As String In lines
 
            'Try to validate the line.
            m = parse.Match(line)
 
            'Was line valid?
            If m.Success Then
 
                'Get tag and description
                Dim tag As String = m.Groups(1).Captures(0).Value
                Dim desc As String = m.Groups(2).Captures(0).Value
 
                'Add the entry to the dictionary, unless an entry with tht tag is already present.
                If Not dict.ContainsKey(tag) Then dict.Add(tag, desc)
 
            End If
 
        Next
 
        Return dict
 
    End Function

Usage:

TextBox1.Text = replacetags("I love '<tag1>'.", readtags(mytagfile))

Regards Tom

[dunfiddlin]

Private Sub Submit_Click(sender As System.Object, e As System.EventArgs) Handles Submit.Click
        'read the file
        Dim lines() As String = System.IO.File.ReadAllLines("tagfile.txt")
        'set the text to a single line
        With RichTextBox1
            .WordWrap = False
            .Multiline = False
        End With
        
        For Each line In lines 'check all tags
            Dim s() As String = Split(line, " = ") 's(0) = "<tag>", s(1) = "replacement text"
 
            'replace all instances of current tag
            If RichTextBox1.Text.Contains(s(0)) Then
                RichTextBox1.Text = RichTextBox1.Text.Replace(s(0), s(1))
            End If
        Next
        'reset text box
        With RichTextBox1
            .WordWrap = True
            .Multiline = True
        End With
 
        'whatever else you want to do
    End Sub

[dunfiddlin]

You can try something like:

'Replaces tags in text and returns the result.
    Private Function replacetags(ByVal text As String, ByVal dict As Dictionary(Of String, String)) As String

Not really a big enough collection to justify a dictionary, IMHO.

[ThomasJohnsen]

Not really a big enough collection to justify a dictionary, IMHO.

You're probably right. I opted for readability and speed.
(scanning the entire text for each tag vs. scanning once).

#EDIT: It is worth noting though, that the number of tags isn't the only determining factor. Your algorithm's is basically O(mn) whereas mine is O(m) + O(n) {m being the number of tags and n the length of the input string}.

[RickHB]

You can try something like:

'Replaces tags in text and returns the result.
    Private Function replacetags(ByVal text As String, ByVal dict As Dictionary(Of String, String)) As String
 
        Dim parsedtext As New StringBuilder
        Dim indexst, indexgt, curindex As Integer
        Dim tag As String
 
        'Reset current progress and get the location of first "<"c
        curindex = 0
        indexst = text.IndexOf("<"c)
 
        While indexst > 0
 
            'Append the text before the "<"c to the result.
            parsedtext.Append(text.Substring(curindex, indexst - curindex))
 
            'Find the first ">"c after the found "<"c
            indexgt = text.IndexOf(">"c, indexst)
 
            'If no ">"c is found, we're done.
            If indexgt < 0 Then
 
                'Append the rest of the text to the result
                parsedtext.Append(text.Substring(indexst))
 
                Return parsedtext.ToString
 
            End If
 
            'Retrieve the text between "<"c and ">"c
            tag = text.Substring(indexst + 1, indexgt - indexst - 1)
 
            'Is the tag in the dictionary?
            If dict.ContainsKey(tag) Then
 
                'Append the text associated with the tag to the result.
                parsedtext.Append(dict(tag))
 
            Else
 
                'Append <tag> to the result
                parsedtext.Append(text.Substring(indexst, indexgt - indexst + 1))
 
            End If
 
            'Update the current progress within the string
            curindex = indexgt + 1
 
            'Find index of "<"c after the current index
            indexst = text.IndexOf("<"c, curindex)
 
        End While
 
        'Append the last bit of text.
        parsedtext.Append(text.Substring(curindex))
 
        Return parsedtext.ToString
 
    End Function
 
    'Reads tags and descriptions from file and organizes them into a dictionary ordered by the tag.
    Private Function readtags(ByVal filename As String) As Dictionary(Of String, String)
 
        Static parse As Regex = New Regex("^\<(?<tag>[^\>]+)\>\s*=\s*(?<desc>.+)$", RegexOptions.Compiled)
 
        Dim lines() As String = File.ReadAllLines(filename)
        Dim dict As Dictionary(Of String, String) = New Dictionary(Of String, String)
        Dim m As Match
 
        For Each line As String In lines
 
            'Try to validate the line.
            m = parse.Match(line)
 
            'Was line valid?
            If m.Success Then
 
                'Get tag and description
                Dim tag As String = m.Groups(1).Captures(0).Value
                Dim desc As String = m.Groups(2).Captures(0).Value
 
                'Add the entry to the dictionary, unless an entry with tht tag is already present.
                If Not dict.ContainsKey(tag) Then dict.Add(tag, desc)
 
            End If
 
        Next
 
        Return dict
 
    End Function

Usage:

TextBox1.Text = replacetags("I love '<tag1>'.", readtags(mytagfile))

Regards Tom

IT WORKS PERFECT!!! THANK YOU VERY MUCH!

Thank you all for your patience and great help!

THANK YOU SOOOO MUCH!