multiple mdi childs of the same form question

[markman]

How do you jump between mdi childs? I loaded them with this:

Public Sub CreateNewDocument()
    Static DocCount As Long
    Dim frmDoc As frmDocument
    Set frmDoc = New frmDocument
    DocCount = DocCount + 1
    frmDoc.Caption = "Document " & DocCount
    DoEvents
    frmDoc.Move 0, 0
    frmDoc.Show
End Sub

and now, say when I hit command1, I want the one that says document3 to come to the front. How?

[chrisjk]

just use the SetFocus method to bring the form to the front.

You'd need to loop through the Forms collection to do what you want...paste this into a module

Public Function FrmFocus(frmCaption As String) As Integer
' Inputs: Form caption
' output: 1 form found, 0 form not found
 
Dim frm As Form
 
For Each frm In Forms
    If frm.Caption = frmCaption Then
        'match found, set focus
        frm.SetFocus
        FrmFocus = 1
        Exit Function
    End If
Next frm
 
' not found!
FrmFocus = 0
 
End Function

Usage...

Private Sub Command2_Click()
 
Dim intReturn As Integer
 
intReturn = FrmFocus("Form4")
 
If intReturn = 0 Then MsgBox "Form 4 not found!", vbCritical
 
End Sub

[Michael Woolsey]

You will probably want to use the ActiveForm Property to utilize the form when you have found it.

Just rambling in case you didn't know it existed.

Michael Woolsey