HOW To Make METHOD in a Class?

[QuestionPlease]

I want to make an accelerate method that adds 5 to the speed field each time it is called?

Public Class CarClass
    Private yearModel As Integer
    Private make As String
    Private speed As Integer

    Public Sub New(ByVal yearM As Integer, ByVal make As String, ByVal speed As Integer)
        yearModel = yearM
        make = make
        speed = 0
    End Sub
    Public Sub SetYearModel(ByVal yearM As Integer)
        yearM = yearModel
    End Sub
    Public Sub SetMake(ByVal make As String)
        make = make
    End Sub
    Public Sub SetSpeed(ByVal speed As Integer)
        speed = speed
    End Sub
    Public Function GetyearModel() As Integer
        Return yearModel
    End Function
    Public Function Getmake() As String
        Return make
    End Function
    Public Function Getspeed() As Integer
        Return speed
    End Function

End Class

[.paul.]

Public Sub Accelerate
    speed += 5
End Sub

[4x2y]

You must declare yearModel, speed and make as properties not as subs and functions

Public Class CarClass
 
    Public Sub New(ByVal yearM As Integer, ByVal make As String, ByVal speed As Integer)
        mintYearModel = yearM
        mintSpeed = speed
        mstrMake = make
    End Sub
 
    Private mintYearModel As Integer
    Public Property YearModel() As Integer
        Get
            Return mintYearModel
        End Get
        Set(ByVal value As Integer)
            mintYearModel = value
        End Set
    End Property
 
    Private mintSpeed As Integer
    Public Property Speed() As Integer
        Get
            Return mintSpeed
        End Get
        Set(ByVal value As Integer)
            mintSpeed = value
        End Set
    End Property
 
    Private mstrMake As String
    Public Property Make() As String
        Get
            Return mstrMake
        End Get
        Set(ByVal value As String)
            mstrMake = value
        End Set
    End Property
 
    Public Sub Accelerate()
        mintSpeed += 5
    End Sub
 
End Class

[.paul.]

@4x2y. the OP's code would work, but your properties method is more efficient

[4x2y]

the OP's code would work,

Actually, it will not work at all because there are many mistakes, e.g. the speed sub will never change the speed because the procedure speed variable shadows the module level speed

Public Sub SetSpeed(ByVal speed As Integer)
        speed = speed
    End Sub

Therefore, i think he must learn more about properties, methods and variable's scoop

[Niya]

@Op: generally speaking you should implement things that describe the object as properties and things that take action as methods.

[QuestionPlease]

My next task is to create a program that makes a car object and then calls the accelerate method five times after each call the accelerate method gets the cars speed and displays it how do i go about doing this? This is how far i gotten?

Public Class CarClass
    Private yearModel As Integer
    Private make As String
    Private speed As Integer

    Public Sub New(ByVal yearM As Integer, ByVal make As String, ByVal speed As Integer)
        yearModel = yearM
        make = make
        speed = 0
    End Sub

    Sub New()
        ' TODO: Complete member initialization 
    End Sub

    Public Sub SetYearModel(ByVal yearM As Integer)
        yearM = yearModel
    End Sub
    Public Sub SetMake(ByVal make As String)
        make = make
    End Sub
    Public Sub SetSpeed(ByVal speed As Integer)
        speed = 0
    End Sub
    Public Function GetyearModel() As Integer
        Return yearModel
    End Function
    Public Function Getmake() As String
        Return make
    End Function
    Public Function Getspeed() As Integer
        Return speed
    End Function
    Public Sub accelerate()
        speed += 5
    End Sub
    Public Sub brake()
        speed -= 5
    End Sub
End Class

Module Module2
    Sub Main()
        Dim mycar As CarClass
        Dim index As Integer
        mycar = New CarClass
        For index = 0 To 5
            mycar.accelerate()
            Console.WriteLine("the speed is " & mycar.Getspeed())
        Next

    End Sub

    End Module

[4x2y]

@QuestionPlease
Please take my code in post #3 to start with because your class is full of mistakes and will never work as you expect (read my post #5)

[QuestionPlease]

@4x2y
if I were to use your code as a start My next task is to create a program that makes a car object and then calls the accelerate method five times after each call the accelerate method gets the cars speed and displays it how do i go about doing this? This is how far i gotten?

Module Module1
    Sub Main()
        Dim mycar As CarClass
        Dim index As Integer
        mycar = New CarClass()
        For index = 0 To 4
            Console.WriteLine("the speed is " & mycar.Accelerate())
        Next

    End Sub

End Module

[.paul.]

Module Module1
    Sub Main()
        Dim mycar As New CarClass()
         
        For index As Integer = 0 To 4
            mycar.Accelerate
            Console.WriteLine("the speed is " & mycar.speed)
        Next
 
    End Sub
 
End Module

[QuestionPlease]

am guessing with my class the problem is in the speed? because i am told to use subs and functions for this console application? can any one tell me what specifically is wrong with my code??

Public Class CarClass
    Private yearModel As Integer
    Private make As String
    Private speed As Integer

    Public Sub New(ByVal yearM As Integer, ByVal make As String, ByVal speed As Integer)
        yearModel = yearM
        make = make
        speed = 0
    End Sub

    Sub New()
        ' TODO: Complete member initialization 
    End Sub

    Public Sub SetYearModel(ByVal yearM As Integer)
        yearM = yearModel
    End Sub
    Public Sub SetMake(ByVal make As String)
        make = make
    End Sub
    Public Sub SetSpeed(ByVal speed As Integer)
        speed = speed
    End Sub
    Public Function GetyearModel() As Integer
        Return yearModel
    End Function
    Public Function Getmake() As String
        Return make
    End Function
    Public Function Getspeed() As Integer
        Return speed
    End Function
    Public Sub accelerate()
        speed += 5
    End Sub
    Public Sub brake()
        speed -= 5
    End Sub
End Class

[.paul.]

this is the problem:

Public Sub SetSpeed(ByVal speed As Integer)
    speed = speed
End Sub

to fix it:

Public Sub SetSpeed(ByVal speed As Integer)
    me.speed = speed
End Sub

[.paul.]

there were other problems too. try this:

Public Class CarClass
    Private yearModel As Integer
    Private make As String
    Private speed As Integer
 
    Public Sub New(ByVal yearM As Integer, ByVal make As String, ByVal speed As Integer)
        Me.yearModel = yearM
        Me.make = make
        Me.speed = 0
    End Sub
 
    Sub New()
    End Sub
 
    Public Sub SetYearModel(ByVal yearM As Integer)
        Me.yearModel = yearM
    End Sub
 
    Public Sub SetMake(ByVal make As String)
        Me.make = make
    End Sub
 
    Public Sub SetSpeed(ByVal speed As Integer)
        Me.speed = speed
    End Sub
 
    Public Function GetyearModel() As Integer
        Return Me.yearModel
    End Function
 
    Public Function Getmake() As String
        Return Me.make
    End Function
 
    Public Function Getspeed() As Integer
        Return Me.speed
    End Function
 
    Public Sub accelerate()
        Me.speed += 5
    End Sub
 
    Public Sub brake()
        Me.speed -= 5
    End Sub
 
End Class

[4x2y]

@QuestionPlease

.paul.'s latest code is OK, but in sub New you should replace

Me.speed = 0

with

Me.speed = speed