[RESOLVED] Open two text files at the same time - error

[seanwpb]

i opening two different text files at the same time as different names and i get a error saying the file is already open at the second open statement. whats wrong with what Im doing

Dim strPCNameFromTextFile As String

Dim iFile As Long
Dim FileNumber As Long

Let iFile = FreeFile
Let FileNumber = FreeFile


Open Environ$("Temp") & "\PCList.txt" For Input As #iFile

 While Not EOF(iFile)
      Input #iFile, strPCNameFromTextFile
      
        Open Environ$("Temp") & "\SoftwareInstall.bat" For Output As #FileNumber   ' Open file for output.

          Print #FileNumber, strPCNameFromTextFile
    
       Close #FileNumber
 Wend

Close #iFile

[Doogle]

You need to assign FileNumber after you've opened the first file

Dim strPCNameFromTextFile As String

Dim iFile As Long
Dim FileNumber As Long

Let iFile = FreeFile

Open Environ$("Temp") & "\PCList.txt" For Input As #iFile
Let FileNumber = FreeFile


 While Not EOF(iFile)
      Input #iFile, strPCNameFromTextFile
      
        Open Environ$("Temp") & "\SoftwareInstall.bat" For Output As #FileNumber   ' Open file for output.

          Print #FileNumber, strPCNameFromTextFile
    
       Close #FileNumber
 Wend

Close #iFile

BTW it's a very long time since I've seen 'Let', it's not required.

[jmsrickland]

I don't get it. Isn't opening and closing the output file inside the loop causing the output data to be lost and only the last input record from the input file is actually printed to the output file?

I would think that it should be this way:

  '
  '
Open Environ$("Temp") & "\PCList.txt" For Input As #iFile
Open Environ$("Temp") & "\SoftwareInstall.bat" For Output As #FileNumber   ' Open file for output.
  '
  '
 While Not EOF(iFile)
      Input #iFile, strPCNameFromTextFile
     
       Print #FileNumber, strPCNameFromTextFile
    
 Wend

Close #iFile
Close #FileNumber
  '
  '

[seanwpb]

thanks Doogle, that did the trick. i been using Let for so long i didnt know it wasnt needed. thanks

jmsrickland, i have already expanded this to a couple different while loops where i keep creating bat files that then get ran and over written all while the first PClist.txt file remains open. so the original concept remains and it works great now that i put that second freefile in the right place.