[RESOLVED] Get length of string minus the line feeds

[Edgemeal]

Need to get length of a string minus the line feed chars and came up with this. Is there a better/more efficient way?

Function GetLenMinus_LF(s As String) As Integer
    s = s.Replace(ControlChars.Lf, String.Empty)
    Return s.Length
End Function

[EricPeterson87]

what about cr and crlf?

[kareninstructor]

Perhaps the following (tweak [\n\r] as needed)

Dim TestString As String = _
"One" & Environment.NewLine & _
"Second Line" & Environment.NewLine & _
"Third and last"

Console.WriteLine("[{0}]", TestString.Length)
Console.WriteLine("[{0}]", TestString.CleanLength)

Place in code modules

<System.Runtime.CompilerServices.Extension()> _
Public Function CleanLength(ByVal sender As String) As Integer
    Return System.Text.RegularExpressions.Regex.Replace(sender, "[\n\r]", "").Length
End Function

[.paul.]

this works, but only ignores vblf + not vbcr:

Dim TestString As String = _
    "One" & Environment.NewLine & _
    "Second Line" & Environment.NewLine & _
    "Third and last"
 
MsgBox(TestString.Count(Function(c) c.ToString <> vbLf))

[jmcilhinney]

Here's another alternative, not necessarily better or worse:

Private Function GetStringLengthWithoutLineBreaks(text As String) As Integer
    Return text.Split(New String() {ControlChars.NewLine,
                                    ControlChars.Cr,
                                    ControlChars.Lf},
                      StringSplitOptions.None).Sum(Function(s) s.Length)
End Function

[Edgemeal]

Thanks for the suggestions,
I did some quick tests and using .Replace(Lf, "") was actually the fastest for my use, I wasn't expecting that,... i just remember Replace being sort of slow in VB6.