[RESOLVED] Remove temp document

[akhileshbc]

Hi guys

In my desktop, I have folder containing some word document files. I want the filenames of the documents in that folder. So, I used:

 Dim strFiles() As String = IO.Directory.GetFiles("X:\Documents and Settings\XXX\Desktop\vvvvv", "*.doc")

All filenames are stored in that array.

But it would also include the temp document that Word generates. I am somewhat confused on how to remove this from array. I only need full filenames of the actual documents, which excludes the temp document.

Any ideas ?

Thanks in advance

[jmcilhinney]

Don't the temp docs all start with "~$"? A simple LINQ query will give you the items from the list where the file doesn't start with that. You'll obviously have to do that after getting the full list. There's no way to avoid getting the full list in the first place.

[akhileshbc]

Thanks

I have tried doing this query:

        Dim temp() As String = IO.Directory.GetFiles("X:\Documents and Settings\XXX\Desktop\vvvvv", "*.doc")

        Dim allFiles = From str In temp
                        Where Not str.ToString.StartsWith("~$")
                        Select str

But it gives an error:

Error	1	Expression of type '1-dimensional array of String' is not queryable. Make sure you are not missing an assembly reference and/or namespace import for the LINQ provider.

This is the first time I am playing with LINQ.

Edit:
Is LINQ available only in FW3.5+ ?

I am targeting at FW2.0

[.paul.]

worked for me with some modifications:

Dim temp() As String = IO.Directory.GetFiles("X:\Documents and Settings\XXX\Desktop\vvvvv", "*.doc")
 
Dim allFiles() As String = (From str In temp
                Where Not str.ToString.StartsWith("~$")
                Select str).ToArray

[jmcilhinney]

Yes, LINQ is .NET 3.5 and later. Unless you have a requirement for .NET 2.0, I'd suggest upgrading.

If you do then your query will be a little different to that. First, there's not much point calling ToString on an element from a String array. Chances are that it is already a String. Also, the array contains full file paths, while it's the file name that starts with that substring. You can use IO.Path.GetFileName to get just the file name.

Dim wordDocs = IO.Directory.GetFiles("folder path here", "*.doc").Where(Function(s) Not IO.Path.GetFileName(s).StartsWith("~$")).ToArray()

You can drop the ToArray if you only intend to loop through the list. Also, that uses function syntax but query syntax would obviously be just as valid. It just doesn't feel as natural in this particular scenario to me.

If you want to stick with .NET 2.0 then you'll use a loop. Create a new List from the array and then use a For loop to go backwards through the file paths. When you find a temp file path you remove it from the List. At the end, you can convert to an array again if desired.

[.paul.]

Edit:
Is LINQ available only in FW3.5+ ?

I am targeting at FW2.0

yes you're correct. it would've helped to know you're using .net 2.0

Public Class Form1
 
    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
        Dim temp As New List(Of String)(IO.Directory.GetFiles("X:\Documents and Settings\XXX\Desktop\vvvvv", "*.doc"))
        temp.RemoveAll(AddressOf isTemp)
    End Sub
 
    Private Function isTemp(s As String) as Boolean
       Return IO.Path.GetFileName(s).StartsWith("~$")
    End Function
 
End Class

edited

[akhileshbc]

yes you're correct. it would've helped to know you're using .net 2.0

Public Class Form1
 
    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
        Dim temp As New List(Of String)(IO.Directory.GetFiles("X:\Documents and Settings\XXX\Desktop\vvvvv", "*.doc"))
        temp.RemoveAll(AddressOf isTemp)
    End Sub
 
    Private Function isTemp(s As String)
       Return IO.Path.GetFileName(s).StartsWith("~$")
    End Function
 
End Class

Thanks Paul

That worked. I have added to get the FileName as I was trying check whether the FullPath is starting with "~$".

Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Dim temp As New List(Of String)(IO.Directory.GetFiles("X:\Documents and Settings\XXX\Desktop\vvvvv", "*.doc"))
        temp.RemoveAll(AddressOf isTemp)
 
        For i As Integer = 0 To temp.Count - 1
            ListBox1.Items.Add(temp.Item(i))
 
        Next
    End Sub
 
    Private Function isTemp(ByVal s As String)
        Return IO.Path.GetFileName(s).StartsWith("~$")
    End Function

Edit:
I didn't saw that you have edited the code.

[jmcilhinney]

You should be either binding that List to the ListBox or else calling AddRange. Either way, not adding items one by one.

[.paul.]

i edited too (twice ). i didn't test it

[akhileshbc]

Yes, LINQ is .NET 3.5 and later. Unless you have a requirement for .NET 2.0, I'd suggest upgrading.

If you do then your query will be a little different to that. First, there's not much point calling ToString on an element from a String array. Chances are that it is already a String. Also, the array contains full file paths, while it's the file name that starts with that substring. You can use IO.Path.GetFileName to get just the file name.

Dim wordDocs = IO.Directory.GetFiles("folder path here", "*.doc").Where(Function(s) Not IO.Path.GetFileName(s).StartsWith("~$")).ToArray()

You can drop the ToArray if you only intend to loop through the list. Also, that uses function syntax but query syntax would obviously be just as valid. It just doesn't feel as natural in this particular scenario to me.

If you want to stick with .NET 2.0 then you'll use a loop. Create a new List from the array and then use a For loop to go backwards through the file paths. When you find a temp file path you remove it from the List. At the end, you can convert to an array again if desired.

Thanks

Yeah I missed the GetFileName() in my previous code. The reason for using toString() was that it didn't had the StartsWith() method. So, I thought it has to be casted to string.

My target machines contains XP SP2 users. So, I think I can't use FW3.5 as it requires SP3 or high.

[akhileshbc]

You should be either binding that List to the ListBox or else calling AddRange. Either way, not adding items one by one.

Thanks

I was just testing whether it worked or not. This Items will be used one by one for another purpose. So, FOR Loop will be the one that I am going to use for the next operation, that's why I included in displaying also.
I will use the method that you mentioned, in the next time when I need to output to listbox.

Can you guys tell me how the RemoveAll() works with the isTemp() ? A basic idea of how it functions, so that I could understand.

[.paul.]

it's basically a for each loop (behind the scenes).
each element in the list is passed to the isTemp function. if it returns true it removes the element + doesn't if it return false

[akhileshbc]

ok thanks