Help Please simple copy files

[Jeremy]

hey im making a program to copy files from point a to point b this will contain a list of jar files i would like to use cmd but control it with my program i have an idea of wat to do but basicly i wanna move directorys and jar files with different names im using this as a back up program its not that many files in cmd it takes like 1 min but i wanna release this to public with out people recoding it and sending viruses to every one if you get my drift thats y i wanna use vb instead of a bat file

[Jeremy]

btw using vb 6.0

[westconn1]

you could use vb filecopy

[Hack]

Keep in mind that if the file is in use when you attempt to copy it the copy will error out so make sure you build in the necessary error trapping.

[Jeremy]

is there another way to copy files if so can you supply code

[Nightwalker83]

As Westconn1 said you can use filecopy for a simple copy method:

Private Sub Command1_Click()
FileCopy "c:\.rnd", "g:\.rnd"
End Sub

or a slightly more advanced method which copies the entire contents of a folder:

Option Explicit
Private source As String, destination As String
Private Sub Command1_Click()
source ="c:\New Folder\"
destination = "d:\New Folder\"
VBCopyFolder(source, destination) 
End Sub

Place this in a module:

Private Type SHFILEOPSTRUCT
    hWnd As Long
    wFunc As Long
    pFrom As String
    pTo As String
    fFlags As Integer
    fAnyOperationsAborted As Long
    hNameMappings As Long
    lpszProgressTitle As Long ' only used if FOF_SIMPLEPROGRESS, sets dialog title
End Type
Private Declare Function SHFileOperation Lib "shell32.dll" Alias "SHFileOperationA" (lpFileOp As SHFILEOPSTRUCT) As Long
' Available Operations
Private Const FO_COPY = &H2 ' Copy File/Folder
Private Const FO_DELETE = &H3  ' Delete File/Folder
Private Const FO_MOVE = &H1  ' Move File/Folder
Private Const FO_RENAME = &H4  ' Rename File/Folder
' Flags
Private Const FOF_ALLOWUNDO = &H40  ' Allow to undo rename, delete ie sends to recycle bin
Private Const FOF_FILESONLY = &H80  ' Only allow files
Private Const FOF_NOCONFIRMATION = &H10  ' No File Delete or Overwrite Confirmation Dialog
Private Const FOF_SILENT = &H4  ' No copy/move dialog
Private Const FOF_SIMPLEPROGRESS = &H100  ' Does not display file names
 
Public Sub VBCopyFolder(ByRef strSource As String, ByRef strTarget As String)
 
    Dim op As SHFILEOPSTRUCT
    With op
        .wFunc = FO_COPY ' Set function
        .pTo = strTarget  ' Set new path
        .pFrom = strSource ' Set current path
        .fFlags = FOF_SIMPLEPROGRESS Or FOF_NOCONFIRMATION And FOF_FILESONLY
    End With
    ' Perform operation
    SHFileOperation op
End Sub

[Jeremy]

night walker you helped me alot ill see wat i can do and see if this does wat i would like it to do until then i will let you know

[Jeremy]

the code is erroring on line 34 in the module can you check over the code and make sure its correct please and thank you im using the vbcopyfolder btw just to let you know

[Nightwalker83]

the code is erroring on line 34 in the module can you check over the code and make sure its correct please and thank you im using the vbcopyfolder btw just to let you know

What is the error you receive on that line?

[Jeremy]

Compile Error:

Varible Required - Can't Assdign to This Expression

its also highlighting op


hopefully this helps

[Nightwalker83]

Can you post the exact code you are using? I created a program using the exact code in post #6 and it works for me.

[westconn1]

have you change the source and destination folders to folders that exist on your computer?
(lines 4 and 5)

[Doogle]

You need to remove the brackets on this line as well

VBCopyFolder(source, destination)

You may also need to remove the trailing "\" on the source folder, or add *.* after it.

EDIT: and the fflags settings should be

        .fFlags = FOF_SIMPLEPROGRESS Or FOF_NOCONFIRMATION Or FOF_FILESONLY

Also you should check the return from the function SHFileoperation ( 0 = success) and also the fAnyOperationsAborted member of the SHFILEOPSTRUCT structure (0 = no operations aborted)

    ' Perform operation
    If SHFileOperation(op) = 0 Then
        If op.fAnyOperationsAborted = 0 Then
            MsgBox "Copy Complete"
        Else
            MsgBox "Copy Incomplete"
        End If
    Else
        MsgBox "Copy Failed"
    End If
End Sub

[Jeremy]

is there a way that i can force a overwrite when im coping the folder :/

[Nightwalker83]

Add this to the flag:

FOF_SILENT

[Jeremy]

ok i get that and everything but how would i enable that in my code i dont really understand

[Nightwalker83]

Dim op As SHFILEOPSTRUCT
    With op
        .wFunc = FO_COPY ' Set function
        .pTo = strTarget  ' Set new path
        .pFrom = strSource ' Set current path
        .fFlags = FOF_SIMPLEPROGRESS Or FOF_NOCONFIRMATION Or FOF_FILESONLY AND FOF_SILENT 
    End With

See the ".fFlags" line.

[Doogle]

I think that Nightwalker meant

        .fFlags = FOF_SIMPLEPROGRESS Or FOF_NOCONFIRMATION Or FOF_FILESONLY Or FOF_SILENT

[Nightwalker83]

I think that Nightwalker meant

        .fFlags = FOF_SIMPLEPROGRESS Or FOF_NOCONFIRMATION Or FOF_FILESONLY Or FOF_SILENT

Well, if it can't handle two or more things at once then yes, that is correct.

[Doogle]

I was referring to the use of 'Or' rather than 'And' to include a flag.

[Nightwalker83]

I was referring to the use of 'Or' rather than 'And' to include a flag.

Yeah, I know but it would depend on what the user wants 'and' would be inclusive while 'or' one or the other.

[Doogle]

Yeah, I know but it would depend on what the user wants 'and' would be inclusive while 'or' one or the other.

Not quite.

FOF_SIMPLEPROGRESS Or FOF_NOCONFIRMATION Or FOF_FILESONLY And FOF_SILENT

equates to
&H100 Or &H80 Or &H10 And &H4 = &H190 ie the &H4 bit is off

whereas

FOF_SIMPLEPROGRESS Or FOF_NOCONFIRMATION Or FOF_FILESONLY Or FOF_SILENT

equates to
&h100 Or &H80 Or &H10 Or &H4 = &H194 ie the &H4 bit is on.

Remember we're dealing with logical operators, to 'add' to the flags value you have to use 'Or' not 'And'.

[Jeremy]

k now im confused what part of the module would i edit i am using the code that doogle gave me i just dont understand where to put the silent thing

[Nightwalker83]

k now im confused what part of the module would i edit i am using the code that doogle gave me i just dont understand where to put the silent thing

Exactly where it is in post #6 except where it says 'And' in post #6 put 'Or' like:

FOF_SIMPLEPROGRESS Or FOF_NOCONFIRMATION Or FOF_FILESONLY Or FOF_SILENT

[Jeremy]

alright heres another question how would i access the appdata

blah = appdata\test

thats wat i wanna do but i really dont know how can any one help me please

[Nightwalker83]

You can use this code to retrieve the location of the appdata folder as well as others.

[jstinnett]

First not trying to highjack the thread but I have a problem with this code and I cant figure out why its doing it. For some reason when I use the code it copies the files/Folders "C:\test\whatever" to "F:\test\whatever" fine but then tries to copy and overwrite them again. I have tried everything I can think of to make this not happen anyone know why its happening?

[Nightwalker83]

First not trying to highjack the thread but I have a problem with this code and I cant figure out why its doing it. For some reason when I use the code it copies the files/Folders "C:\test\whatever" to "F:\test\whatever" fine but then tries to copy and overwrite them again. I have tried everything I can think of to make this not happen anyone know why its happening?

Could please post the exact could you are using so we can see if there anything that needs changing in you code. Thanks!

[jstinnett]

form

    Option Explicit
    Private source As String, destination As String
Private Sub Command1_Click()

    source = "C:\squad"
    destination = Text1.Text
    VBCopyFolder source, destination

End Sub


Private Sub Command2_Click()
    source = Text1.Text
    destination = "C:\"
    VBCopyFolder source, destination
End Sub


Private Sub Command3_Click()
Timer2.Enabled = True
Timer2.Enabled = False

End Sub

Private Sub Command4_Click()

'Text3.Text = FileDateTime("C:\test.txt")
End Sub

Private Sub Form_Load()

End Sub

Private Sub Timer1_Timer()
Text1.Text = Drive1.Drive + Text2.Text

End Sub

Private Sub Timer2_Timer()
Drive1.Refresh
End Sub

Modules

    Private Type SHFILEOPSTRUCT
        hWnd As Long
        wFunc As Long
        pFrom As String
        pTo As String
        fFlags As Integer
        fAnyOperationsAborted As Long
        hNameMappings As Long
        lpszProgressTitle As Long ' only used if FOF_SIMPLEPROGRESS, sets dialog title
    End Type
    Private Declare Function SHFileOperation Lib "shell32.dll" Alias "SHFileOperationA" (lpFileOp As SHFILEOPSTRUCT) As Long
    ' Available Operations
    Private Const FO_COPY = &H2 ' Copy File/Folder
    Private Const FO_DELETE = &H3  ' Delete File/Folder
    Private Const FO_MOVE = &H1  ' Move File/Folder
    Private Const FO_RENAME = &H4  ' Rename File/Folder
    ' Flags
    Private Const FOF_ALLOWUNDO = &H40  ' Allow to undo rename, delete ie sends to recycle bin
    Private Const FOF_FILESONLY = &H80  ' Only allow files
    Private Const FOF_NOCONFIRMATION = &H10  ' No File Delete or Overwrite Confirmation Dialog
    Private Const FOF_SILENT = &H4  ' No copy/move dialog
    Private Const FOF_SIMPLEPROGRESS = &H100  ' Does not display file names
    
     
    Public Sub VBCopyFolder(ByRef strSource As String, ByRef strTarget As String)
     
        Dim op As SHFILEOPSTRUCT
        With op
            .wFunc = FO_COPY ' Set function
            .pTo = strTarget  ' Set new path
            .pFrom = strSource ' Set current path
            .fFlags = FOF_SIMPLEPROGRESS Or FOF_NOCONFIRMATION Or FOF_FILESONLY
        End With
        ' Perform operation
        SHFileOperation op
                If SHFileOperation(op) = 0 Then
        If op.fAnyOperationsAborted = 0 Then
            MsgBox "Copy Complete"
        Else
            MsgBox "Copy Incomplete"
        End If
    Else
        MsgBox "Copy Failed"
    End If
    End Sub

[Doogle]

You're performing the copy twice

        SHFileOperation op
                If SHFileOperation(op) = 0 Then

You just need

                If SHFileOperation(op) = 0 Then