transferring multiple information from form to form

[redneckrider]

Hello,

So my question is that I have 2 list boxes in two forms aside from the main one. and I am trying to transfer what I choose in the side form to transfer to the list box.

several questions:
Why does the blank list form I have in the main form create a problem when I enter a name for the list box and why does it appear in the box when I put it there? As you can see in my errors. It doesn't seem to recognize the listbox that I wanted to leave empty in the main form.

Second question is how do I get names to add in the main form list box. I believe I have the right code but I seem to be missing something else as well. I want the names to display in the main list box and the integers to add up together so I can separately figure the tax and shipping myself. Thank you

Here are some pictures and codes

Main:

Print:

Audio:

Public Class MainForm

    Dim frmAudioBooks As New AudioBooks
    Dim frmPrintedBooks As New PrintedBooks
    Const decTaxRate As Decimal = 0.06D ' Tax rate for Books
    Const decShipping As Decimal = 2D ' Shipping Rate per Book
    Const decPrintIDidIt As Decimal = 11.95D 'Price of Print Book "I Did It Your Way"
    Const decPrintHistory As Decimal = 14.5D 'Price of Print Book "The History of Scotland"
    Const decPrintCalculus As Decimal = 29.95D 'Price of Print Book "Learn Calculus in One Day"
    Const decPrintStress As Decimal = 18.5D 'Price of Print Book "Feel the Stress"
    Const decAudioCaluclus As Decimal = 29.95D 'Price of Audio Book "Learn Calculus in One Day"
    Const decAudioHistory As Decimal = 14.5D 'Price of Audio Book "The History of Scotland" 
    Const decAudioScience As Decimal = 12.95D 'Price of Audio Book "The Science of Body Language"
    Const decAudioRelax As Decimal = 11.5D 'Price of Audio Book "Relaxation Techniques


    Private Sub mnuFileExit_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles mnuFileExit.Click
        'Close the Form
        Me.Close()
    End Sub

    Private Sub mnuHelpAbout_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles mnuHelpAbout.Click
        'Display a short description of the program
        MessageBox.Show("The program executes a shopping menu for the user to choose from many books both audio and printed and let's them pick from multiple books to check and buy. Designed by Justin Guan")
    End Sub

    Private Sub mnuProductsPrintedBooks_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles mnuProductsPrintedBooks.Click
        frmPrintedBooks.Show()
    End Sub

    Private Sub mnuProductsAudioBooks_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles mnuProductsAudioBooks.Click
        frmAudioBooks.Show()
    End Sub

    Private Sub mnuFileReset_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles mnuFileReset.Click
        lstProducts.Items.Clear()
    End Sub

End Class

Public Class PrintedBooks

    Private Sub btnPrintAddCart_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnPrintAddCart.Click
        Dim intPrintInput As Integer 'Holds the selected Printed Book

        For intPrintInput = 0 To lstPrint.Items.Count = -1
            If lstPrint.SelectedIndex = -1 Then
                'No book is selected
                MessageBox.Show("Select a book.")
            ElseIf lstPrint.GetSelected(intPrintInput) Then
                lstProducts.Items.Add(lstPrint.Items(intPrintInput))
                'Gets the Selected book
            End If
        Next

    End Sub
End Class

Public Class AudioBooks
    Private Sub btnAudioClose_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnAudioClose.Click
        Me.Close()
    End Sub

    Private Sub btnAudioAddCart_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnAudioAddCart.Click
        Dim intAudioInput As Integer 'Holds the selected Printed Book

        For intAudioInput = 0 To lstAudio.Items.Count = -1
            If lstAudio.SelectedIndex = -1 Then
                'No book is selected
                MessageBox.Show("Select a book.")
            ElseIf lstAudio.GetSelected(intAudioInput) Then
                lstProducts().Items.Add(lstAudio.Items(intAudioInput))
                'Gets the Selected book
            End If
        Next
    End Sub

End Class

[.paul.]

using lstProducts outside of mainform:

mainform.lstProducts.Items.Add(lstAudio.Items(intAudioInput))

but you need to be sure mainform is open.

have a look at this thread, for a better method:

http://www.vbforums.com/showthread.p...81#post4087181

[redneckrider]

sweet thanks for that. But my issue now is how come when I select from one of the listbox in the side forms, it doesn't display in the main list box. nothing occurs when I press the add to cart button

[Shaggy Hiker]

What did you expect this to do?

ElseIf lstPrint.GetSelected(intPrintInput) Then

Since it is an If statement, it has to evaluate to True or False. I would expect that to evaluate to True, but it might not.

I think you want that to just be an Else. After all, the If checks to see whether anything was selected, so to even reach this line, something must be selected. Presumably, you want to move those items across, regardless of which items was selected, though maybe you wanted to check for whether a certain item was selected....

[redneckrider]

I see, but how do I assign values to each book? no matter which one I select and click add to cart, it chooses the first one

[redneckrider]

and how do I assign the price value to that specific book. my textbook confuses me a lot

[.paul.]

and how do I assign the price value to that specific book. my textbook confuses me a lot

what are the directions for your assignment?

[Shaggy Hiker]

Well, you follow that ElseIf with this line:

lstProducts().Items.Add(lstAudio.Items(intAudioInput))

That will add an item, but it will always add whatever item is at intAudioInput. What you want to be doing is adding the selected item, not the one at intAudioInput. However, there are two ways of doing this, depending on whether you have single select or multiselect. If it is singleselect, then you can probably use:

lstProducts().Items.Add(lstAudio.SelectedItem)

For multiselect, you may be able to use AddRange on the SelectedItems collection, but Listbox is a bit archaic, and might not have AddRange. If it doesn't you can iterate through the selected items collection adding each one in turn. It doesn't look like you have multi select on, though.

[.paul.]

Listbox does have multiselect

edit: i mean Listbox does have addrange

[Shaggy Hiker]

Yeah, I know that, but it is optional, and it rather looks like the OP is using single select.

What I don't recall is whether the Items collection has AddRange, or if that was one of the features of an interface it doesn't implement. I remember that the Listbox.Items was a really old collection from the dawn of .NET, and it doesn't implement all the interfaces of later collections, so it can be missing some things. I just never remember what it is missing.

[redneckrider]

The assignment is to design an app that works as a shopping cart system. the person should be able to add any of the following items to his or her shopping cart.

I just added the holding values

Dim decTotalBookPrice As Decimal ' Holds the Total Book Price
    Dim intTotalBooks As Integer ' Holds the Total amount of books
    Dim decTotalPrice As Decimal ' The total price after Tax, Shipping and Book price

problem now is I can get the books to display on the main list box, but I can't seem to figure out how to assign the exact prices to those books. Do the list the code in the separate forms or the main one

[.paul.]

are you using databinding?
the listbox has a selecteditem (which would be the text you see) + a selectedvalue (the price of the item) that you could use if you bind a datasource

@Shaggy. check the edit in post #9

[redneckrider]

not really sure what data binding is. but how would I bind the selected item to the selected value. Do I place that code within the main form where I declared the prices or should I place them in the side form codes to figure it out

what would be the code to bind them

[.paul.]

ok. looks like you aren't using databinding then.
there's a different way you could do this. the listbox items are objects, which means you can add more than just strings.

here's a custom listItem:

Public Class listItem
    Public display As String
    Public value As Decimal
    Public Overrides Function ToString() As String
        Return Me.display
    End Function
End Class

instead of:

lstPrint.items.add("a string")

you'd use:

lstPrint.Items.Add(New listItem With {.display = "Book" & x.ToString, .value = 10})

here's an example project:

[redneckrider]

so if im correct, for the first vB code, I would put Public Class listPrintCalculus??? what is the .value = 10 mean? I don't follow where that is coming from. where am I declaring the price values?

[.paul.]

value = 10 is just an example number.
the value would be the price of the book or item or whatever your list contains

[redneckrider]

Public Class listItem
    Public display As String
    Public value As Decimal
    Public Overrides Function ToString() As String
        Return Me.display
    End Function
End Class

would this be for each individual book?

[redneckrider]

" & x.ToString, .value = 10})

also what is the x. doing?

[redneckrider]

When I do that. the display text has WindowsApplication when it comes right after the text

[redneckrider]

Public Class PrintedBooks

    Public Class PrintIDidIt
        Public display As String
        Public value As Decimal
        Public Overrides Function ToString() As String
            Return Me.display
        End Function
    End Class
    Public Class PrintHistory
        Public display As String
        Public value As Decimal
        Public Overrides Function ToString() As String
            Return Me.display
        End Function
    End Class
    Public Class PrintCalculus
        Public display As String
        Public value As Decimal
        Public Overrides Function ToString() As String
            Return Me.display
        End Function
    End Class
    Public Class PrintStress
        Public display As String
        Public value As Decimal
        Public Overrides Function ToString() As String
            Return Me.display
        End Function
    End Class
    Private Sub btnPrintAddCart_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnPrintAddCart.Click
        Dim intPrintInput As Integer 'Holds the selected Printed Book

        For intPrintInput = 0 To lstPrint.Items.Count = -1
            If lstPrint.SelectedIndex = -1 Then
                'No book is selected
                MessageBox.Show("Select a book.")
            Else : lstPrint.GetSelected(intPrintInput)
                MainForm.lstProducts().Items.Add(New PrintIDidIt With {.display = "I Did It Your Way (Print)" & ToString(), .value = 11.95})
                MainForm.lstProducts().Items.Add(New PrintHistory With {.display = "The History of Scotland" & ToString(), .value = 14.5})
                MainForm.lstProducts().Items.Add(New PrintIDidIt With {.display = "Learn Calculus in One Day" & ToString(), .value = 29.95})
                MainForm.lstProducts().Items.Add(New PrintIDidIt With {.display = "Feel the Stress" & ToString(), .value = 18.5})
                'Gets the Selected book
            End If
        Next

    End Sub

I currently have this, and it still doesn't specific which one i pick. It just simply displays all of them and WindowsApplication text right after it.

[.paul.]

i uploaded an example project. it's a working example that should help you understand how the custom listItem works + how to transfer selected items between forms.

i could finish your project for you, but what will you learn? nothing.

[redneckrider]

Sorry Didn't mean you to help me complete it. Mere misunderstanding

Now that I have this

Public Class listItem
    Public display As String
    Public value As Decimal
    Public Overrides Function ToString() As String
        Return Me.display
    End Function
End Class

Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        With lstPrint
            lstPrint.Items.Add(New listItem With {.display = "I Did It Your Way (Print)" & ToString(), .value = 11.95})
            lstPrint.Items.Add(New listItem With {.display = "The History of Scotland (Print)" & ToString(), .value = 14.5})
            lstPrint.Items.Add(New listItem With {.display = "Learn Calculus in One Day (Print)" & ToString(), .value = 29.95})
            lstPrint.Items.Add(New listItem With {.display = "Feel the Stress (Audio)" & ToString(), .value = 18.5})
            MainForm.Show()
        End With
    End Sub


    Private Sub lstPrint_SelectedIndexChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles lstPrint.SelectedIndexChanged
        Dim ItemSelected As Decimal
        ItemSelected = CType(lstPrint.SelectedItem,  _
            listItem).value
    End Sub

How can I compile the values that were added to the main listbox by adding them all together. I'm used to adding them as separate values not all of them stored in one.

Also is there a way to count the amount of books in the main listbox?

Thank you for everything so far. It's been so helpful

[.paul.]

ok try this. the listItem class should be a separate class (Project-->Add Class. + name it listItem, then paste code into class):

Public Class listItem
    Public display As String
    Public value As Decimal
    Public Overrides Function ToString() As String
        Return Me.display
    End Function
End Class

Public Class AudioBooks
 
    Private Sub btnAudioClose_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnAudioClose.Click
        Me.Close()
    End Sub
 
    Private Sub btnAudioAddCart_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnAudioAddCart.Click
        MainForm.lstProducts.Items.AddRange(lstAudio.SelectedItems.Cast(Of listItem).ToArray)
        MainForm.lblSubtotal.Text = MainForm.lstProducts.Items.Cast(Of listItem).Sum(Function(li) li.value).ToString("c2")
    End Sub
 
    Private Sub AudioBooks_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        'prices are just used for illustration purposes. change to actual prices if necessary
        lstAudio.Items.Add(New listItem With {.display = "Learn Calculus in One Day (Audio)", .value = 10.99})
        lstAudio.Items.Add(New listItem With {.display = "Relaxation Techniques(Audio)", .value = 7.99})
        lstAudio.Items.Add(New listItem With {.display = "The History of Scotland (Audio)", .value = 9.99})
        lstAudio.Items.Add(New listItem With {.display = "The Science of Body Language (Audio)", .value = 8.99})
    End Sub
 
End Class

Public Class PrintedBooks
 
    Private Sub btnPrintAddCart_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnPrintAddCart.Click
        MainForm.lstProducts.Items.AddRange(lstPrint.SelectedItems.Cast(Of listItem).ToArray)
        MainForm.lblSubtotal.Text = MainForm.lstProducts.Items.Cast(Of listItem).Sum(Function(li) li.value).ToString("c2")
    End Sub
 
    Private Sub btnPrintClose_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnPrintClose.Click
        Me.Close()
    End Sub
 
    Private Sub PrintedBooks_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        'prices are just used for illustration purposes. change to actual prices if necessary
        lstPrint.Items.Add(New listItem With {.display = "I Did It Your Way (Print)", .value = 10.99})
        lstPrint.Items.Add(New listItem With {.display = "The History of Scotland (Print)", .value = 7.99})
        lstPrint.Items.Add(New listItem With {.display = "Learn Calculus in One Day (Print)", .value = 9.99})
        lstPrint.Items.Add(New listItem With {.display = "Feel the Stress (Print)", .value = 8.99})
    End Sub
 
End Class

[.paul.]

another suggestion:

change lstAudio + lstPrint selectionmode property to multisimple + you can then add more than 1 book at a time

[redneckrider]

another suggestion:

change lstAudio + lstPrint selectionmode property to multisimple + you can then add more than 1 book at a time

I'm not quite sure how to really do that. Is that done in the design window?


Also another big question is how do I do a count on the amount of books that will be in the main listbox? I need it to calculate another formula for my project.



Edit: Also why does it add two books instead of one?

[.paul.]

I'm not quite sure how to really do that. Is that done in the design window?


Also another big question is how do I do a count on the amount of books that will be in the main listbox? I need it to calculate another formula for my project.



Edit: Also why does it add two books instead of one?

in design view select the listbox. to the right of your screen is your properties window. change the selectionmode property there.


2 books instead of 1??? i downloaded your project from a previous post + with my changes it adds the correct amount of books.


to calculate the number of books in lstProducts:

lstProducts.Items.count

if you need to differentiate between audio + printed books in your calculations, we can add a type property to the listItem

[redneckrider]

I found the double problem. I had for my error message of not selecting a book.

Else : lstAudio.GetSelected(intAudioInput)
                MainForm.lstProducts().Items.Add(lstAudio.SelectedItem)

[.paul.]

2 books instead of 1???

my mistake. i forgot to tell you i removed the items you'd added at design time, so i could add them as listItems instead of strings

[redneckrider]

For the item count, when I put it in a formula, would it be something like

lstProducts.Items.count * decShipping = intTotalShipping

Edit: How Do I calculate what is in the label for Subtotal in another equation?

Would it be

lblSubtotal.Text * decTaxRate = lblTax

[redneckrider]

lblTax.Text = decTaxCost.ToString("c2")

    Function TaxCost() As Decimal
        Dim decTaxCost As Decimal = 0
        Const decTaxRate As Decimal = 0.06D ' Tax rate for Books


        decTaxCost = CDec(lblSubtotal.Text) * decTaxRate

        Return decTaxCost


    End Function

Why does my label text require a declaration expected?

[Shaggy Hiker]

If you mean this line:

lblTax.Text = decTaxCost.ToString("c2")


that appears to be outside of any method. You won't be able to do that. The line has to be inside a method.

[redneckrider]

If you mean this line:

lblTax.Text = decTaxCost.ToString("c2")


that appears to be outside of any method. You won't be able to do that. The line has to be inside a method.

So I have this in the function and I can't get it to execute into the label

Function TaxCost() As Decimal
        Dim decTaxCost As Decimal = 0
        Const decTaxRate As Decimal = 0.06D ' Tax rate for Books

        decTaxCost = CDec(lblSubtotal.Text) * decTaxRate

        Return decTaxCost

        decTotalTax = TaxCost()

        lblTax.Text = decTotalTax.ToString("c2")

    End Function

[Shaggy Hiker]

Once execution hits that Return statement, that's the end of the function. Any lines after that, such as the line that puts the information into the label, won't get executed. You have to move the return to the end of the function.

[redneckrider]

Ok so far I have this, my tax label still doesn't return a value back to the label

and for the other labels to display, you said they have to be within a method. where would they go?

I attached my program. Where did I go wrong?

Public Class MainForm

    Dim frmAudioBooks As New AudioBooks
    Dim frmPrintedBooks As New PrintedBooks

    Const decShipping As Decimal = 2D ' Shipping Rate per Book
    Const decPrintIDidIt As Decimal = 11.95D 'Price of Print Book "I Did It Your Way"
    Const decPrintHistory As Decimal = 14.5D 'Price of Print Book "The History of Scotland"
    Const decPrintCalculus As Decimal = 29.95D 'Price of Print Book "Learn Calculus in One Day"
    Const decPrintStress As Decimal = 18.5D 'Price of Print Book "Feel the Stress"
    Const decAudioCaluclus As Decimal = 29.95D 'Price of Audio Book "Learn Calculus in One Day"
    Const decAudioHistory As Decimal = 14.5D 'Price of Audio Book "The History of Scotland" 
    Const decAudioScience As Decimal = 12.95D 'Price of Audio Book "The Science of Body Language"
    Const decAudioRelax As Decimal = 11.5D 'Price of Audio Book "Relaxation Techniques

    Dim decTotalBookCount As Decimal ' Holds Total Book Count
    Dim decTotalBookPrice As Decimal ' Holds Total Book Price
    Dim decTotalTax As Decimal ' Holds the Total Tax Price
    Dim decTotalShipping As Decimal ' Holds the Total shipping amount of books
    Dim decTotalPrice As Decimal ' The total price after Tax, Shipping and Book price

    'Display Labels (Tax, Shipping Rate, Total)


    lblShipping.Text = decTotalShipping.ToString("c2")
    lblTotal.Text = decTotalPrice.ToString("c2")    


    'Holds the Functions

        decTotalShipping = decShipping * CDbl(lstProducts.Items.count)
        decTotalPrice = decTax + decTotalShipping + CDec(lblSubtotal.Text)


    Function TaxCost() As Decimal
        Dim decTaxCost As Decimal = 0
        Const decTaxRate As Decimal = 0.06D ' Tax rate for Books

        decTaxCost = CDec(lblSubtotal.Text) * decTaxRate



        decTotalTax = TaxCost()

        lblTax.Text = decTotalTax.ToString("c2")
        Return decTaxCost

    End Function





    Private Sub mnuFileExit_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles mnuFileExit.Click
        'Close the Form
        Me.Close()
    End Sub

    Private Sub mnuHelpAbout_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles mnuHelpAbout.Click
        'Display a short description of the program
        MessageBox.Show("The program executes a shopping menu for the user to choose from many books both audio and printed and let's them pick from multiple books to check and buy. Designed by Justin G.")
    End Sub

    Private Sub mnuProductsPrintedBooks_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles mnuProductsPrintedBooks.Click
        frmPrintedBooks.Show()
    End Sub

    Private Sub mnuProductsAudioBooks_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles mnuProductsAudioBooks.Click
        frmAudioBooks.Show()
    End Sub

    Private Sub mnuFileReset_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles mnuFileReset.Click
        lstProducts.Items.Clear()
    End Sub

    Private Sub lstProducts_SelectedIndexChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles lstProducts.SelectedIndexChanged
        MsgBox(DirectCast(lstProducts.SelectedItem, listItem).value)




    End Sub
End Class

[.paul.]

try this:

[redneckrider]

Ok for this part, I am confused to what to put into there, would I put in the Audio or the Print listbox?

If I put lstAudio in it, it will do what it did before and double to amount of books when I click once

How would I declare it for the listbox for Print if it allows to choose one source listbox

  Public Shared Sub updateMainformLB(ByVal sourceListbox As ListBox, ByVal lstProducts As ListBox, ByVal lblSubtotal As Label, ByVal lblTax As Label, ByVal lblShipping As Label, ByVal lblTotal As Label)
        lstProducts.Items.AddRange(sourceListbox.SelectedItems.Cast(Of listItem).ToArray)
        updateMainformLbls(lstProducts, lblSubtotal, lblTax, lblShipping, lblTotal)
    End Sub

[.paul.]

did you read the rest of the project?
that sub procedure has that parameter so it works with either listbox.

with parameters you pass values: i.e

private sub showAMsgbox(byval msg as string)
    msgbox(msg)
end sub

then you'd use it like this:

showAMsgbox("this is the value you passed")

+ it will show a msgbox with "this is the value you passed" as it's text.

[redneckrider]

Yes it finally works!!! thank you soo much

one quick question though

When I click print or audio to have another form popup and i close it, and when I try to open it again
it says it cannot access a disposed object

[.paul.]

at the top of mainForm code, change:

Dim frmAudioBooks As New AudioBooks
Dim frmPrintedBooks As New PrintedBooks

to:

Dim frmAudioBooks As AudioBooks
Dim frmPrintedBooks As PrintedBooks

then change:

Private Sub mnuProductsPrintedBooks_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles mnuProductsPrintedBooks.Click
    frmPrintedBooks.Show()
End Sub
 
Private Sub mnuProductsAudioBooks_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles mnuProductsAudioBooks.Click
    frmAudioBooks.Show()
End Sub

to:

Private Sub mnuProductsPrintedBooks_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles mnuProductsPrintedBooks.Click
    frmPrintedBooks = New PrintedBooks
    frmPrintedBooks.Show()
End Sub
 
Private Sub mnuProductsAudioBooks_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles mnuProductsAudioBooks.Click
    frmAudioBooks = New AudioBooks
    frmAudioBooks.Show()
End Sub

[.paul.]

one last recommendation.
i'd show frmPrintedBooks + frmAudioBooks as dialogs (Form.ShowDialog Method) as i tried to tell you in post #2