renaming file names

[markirving]

hi can someone help me with the code for renaming existing files? thanks alot!

this is what ive wrote.. and it fails to rename existing files

             For Each file As String In listbox1.Items
                    IO.File.Copy(file, IO.Path.Combine(fbCopyto.SelectedPath, IO.Path.GetFileName(file)))
                    While IO.File.Exists(fbCopyto.SelectedPath & file)
                        file=  file & x & ".wav"
                        x += 1


                    End While
                Next

[J-Deezy]

             For Each file As String In listbox1.Items
                    IO.File.Copy(file, IO.Path.Combine(fbCopyto.SelectedPath, IO.Path.GetFileName(file)))
                    While IO.File.Exists(fbCopyto.SelectedPath & file)
                        IO.File.Rename(file, "new name.wav")
                        x += 1
                    End While
                Next

I'm not quite sure why you have a while statement in there for, but I wasn't sure of your context so I left it

[jmcilhinney]

Presumably you are trying to copy a file and, if a file with that name exists, you change the name numerically. E.g. if Test.txt exists then you try Test1.txt, and if that exists you try Test2.txt, etc. Here's some code that will do that:

Dim destinationFolderPath As String = fbCopyTo.SelectedPath
 
For Each sourceFilePath As String In Me.ListBox1.Items
    Dim destinationFilePath As String = IO.Path.Combine(destinationFolderPath, IO.Path.GetFileName(sourceFilePath))
 
    If IO.File.Exists(destinationFilePath) Then
        Dim fileName As String = IO.Path.GetFileNameWithoutExtension(sourceFilePath)
        Dim fileNumber As Integer = 1
        Dim extension As String = IO.Path.GetExtension(sourceFilePath)
 
        destinationFolderPath = IO.Path.Combine(destinationFolderPath, _
                                                String.Format("{0}{1}.{2}", _
                                                              fileName, _
                                                              fileNumber, _
                                                              extension))
 
        While IO.File.Exists(destinationFolderPath)
            fileNumber += 1
            destinationFolderPath = IO.Path.Combine(destinationFolderPath, _
                                                    String.Format("{0}{1}.{2}", _
                                                                  fileName, _
                                                                  fileNumber, _
                                                                  extension))
        End While
    End If
 
    IO.File.Copy(sourceFilePath, destinationFilePath)
Next

[markirving]

hi jmcilhinney, thanks for the reply!

ive tried your code, unfortunately, i still cannot rename the file that has existing copy of it.

[jmcilhinney]

There was an error in my code. I used 'destinationFolderPath' in a few places where I should have used 'destinationFilePath'. Here's the corrected version:

Dim destinationFolderPath As String = fbCopyTo.SelectedPath

For Each sourceFilePath As String In Me.ListBox1.Items
    Dim destinationFilePath As String = IO.Path.Combine(destinationFolderPath, IO.Path.GetFileName(sourceFilePath))

    If IO.File.Exists(destinationFilePath) Then
        Dim fileName As String = IO.Path.GetFileNameWithoutExtension(sourceFilePath)
        Dim fileNumber As Integer = 1
        Dim extension As String = IO.Path.GetExtension(sourceFilePath)

        destinationFilePath = IO.Path.Combine(destinationFolderPath, _
                                              String.Format("{0}{1}.{2}", _
                                                            fileName, _
                                                            fileNumber, _
                                                            extension))

        While IO.File.Exists(destinationFilePath)
            fileNumber += 1
            destinationFilePath = IO.Path.Combine(destinationFolderPath, _
                                                  String.Format("{0}{1}.{2}", _
                                                                fileName, _
                                                                fileNumber, _
                                                                extension))
        End While
    End If

    IO.File.Copy(sourceFilePath, destinationFilePath)
Next

You probably could have worked that out for yourself with a bit of an examination of the code and some debugging.

Here's a slightly more succinct version:

Dim destinationFolderPath As String = fbCopyTo.SelectedPath
 
For Each sourceFilePath As String In Me.ListBox1.Items
    Dim destinationFilePath As String = IO.Path.Combine(destinationFolderPath, IO.Path.GetFileName(sourceFilePath))
 
    If IO.File.Exists(destinationFilePath) Then
        Dim fileName As String = IO.Path.GetFileNameWithoutExtension(sourceFilePath)
        Dim fileNumber As Integer = 0
        Dim extension As String = IO.Path.GetExtension(sourceFilePath)
 
        Do
            fileNumber += 1
            destinationFilePath = IO.Path.Combine(destinationFolderPath, _
                                                  String.Format("{0}{1}.{2}", _
                                                                fileName, _
                                                                fileNumber, _
                                                                extension))
        Loop While IO.File.Exists(destinationFilePath)
    End If
 
    IO.File.Copy(sourceFilePath, destinationFilePath)
Next