Automation questions

[Ellis Dee]

Three questions that should be simple, though I don't know the proper way to do it:

1) Given an hwnd of a window, how can I get the titlebar caption?

2) Given an hwnd of a button, how can I get the button's caption?

3) Given an hwnd of a control, how can I tell what type of control it is?

EDIT: Nevermind, I think I figured everything out thanks to this MSDN article.

[Siddharth Rout]

1)

Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" _
(ByVal lpClassName As String, ByVal lpWindowName As String) As Long

Private Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" _
(ByVal hwnd As Long, ByVal lpString As String, ByVal cch As Long) As Long

Private Sub Command1_Click()
    Dim lngHwndOne As Long, lngHwndTwo As Long
    Dim WindTitle As String * 256
    
    '~~> Sample Internet Explorer. You already have a hwnd so
    '~~> you may comment it
    lngHwndOne = FindWindow("IEFrame", vbNullString)
    
    '~~> Get the title bar text
    lngHwndTwo = GetWindowText(lngHwndOne, WindTitle, 255)
    
    '~~> Display it
    MsgBox Left$(WindTitle, lngHwndTwo)
End Sub

2)

'~~> Create a form1 and place a command button on. Set it's caption to anything
'~~> that you like
Private Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" _
(ByVal hwnd As Long, ByVal lpString As String, ByVal cch As Long) As Long

Private Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" _
(ByVal hWnd1 As Long, ByVal hWnd2 As Long, ByVal lpsz1 As String, ByVal lpsz2 As String) As Long


Private Sub Command1_Click()
    Dim lngHwndOne As Long, lngHwndTwo As Long
    Dim WindTitle As String * 256
    
    lngHwndOne = FindWindowEx(Me.hwnd, 0, "ThunderCommandButton", vbNullString)
    
    lngHwndTwo = GetWindowText(lngHwndOne, WindTitle, 255)
    
    '~~> Display it
    MsgBox Left$(WindTitle, lngHwndTwo)
End Sub

3)

'~~> Create a form1 and place a command button

Private Declare Function GetClassName Lib "user32" Alias "GetClassNameA" _
(ByVal hwnd As Long, ByVal lpClassName As String, ByVal nMaxCount As Long) As Long

Private Sub Command1_Click()
    Dim lngHwndOne As Long, WindTitle As String * 256
    
    lngHwndOne = GetClassName(Command1.hwnd, WindTitle, 255)
    
    '~~> Displays the class of the control
    '~~> For example "ThunderCommandButton" for the command button
    MsgBox Left$(WindTitle, lngHwndOne)
End Sub

[Ellis Dee]

Sweet, perfect. I'm trying to compile a comprehensive automation library to post in the CodeBank, so any tips, tricks or ideas are welcome.

(And doh! Can't give you rep again so soon.)

[Siddharth Rout]

Updated the code for point 2 and Working on point 3

(And doh! Can't give you rep again so soon.)

I know

[Siddharth Rout]

All updated

[Ellis Dee]

You're the man.

I may have followup questions as I put together the library module over the next few days, so keep an eye out for this thread getting bumped. Once I finish and post to the codebank I'll mark the thread resolved.

Thanks much.