[RESOLVED] Custom Collection

[Matchlighter]

I have been researching for a couple of days now and to no avail. Does Anyone know how to make a custom collection that take advantage of the collection editor? Code or an actual file would be greatly appreciated. I would like to be able to have 3 Color Values, 1 Boolean and 1 String. If anyone can help me with this, please do.

E

[cicatrix]

Public Class MyData
    Public C1 As Color
    Public C2 As Color
    Public C3 As Color
    Public Flag As Boolean
    Public Text As String
End Class
 
Public Class SomeClass
    Public col As New List(Of MyData)
End Class

What is collection editor?

[Matchlighter]

Collection Editor is That dialog Box that allows you to define stuff in a drop down menu or such. It opens when you click the ... on any value that says (Collection)

[Matchlighter]

Does Anyone know? I know it is possible because I have seen it used in advanced User Controls. If anyone knows, Please step forward.

E

[i00]

Create a new class as follows:

Imports System.ComponentModel
Imports System.ComponentModel.Design
Imports System.Drawing.Design
 
Public Class Class1
    Inherits Control
    Private mc_asd As New List(Of TestItem)
    <Editor(GetType(CollectionEditor), GetType(UITypeEditor)), _
DesignerSerializationVisibility(DesignerSerializationVisibility.Content), Browsable(True), _
System.ComponentModel.DisplayName("Selector Items")> _
Public Property asd() As List(Of TestItem)
        Get
            Return mc_asd
        End Get
        Set(ByVal value As List(Of TestItem))
            mc_asd = value
        End Set
    End Property
End Class
 
<Serializable()> _
Public Class TestItem
    Dim mc_Text As String
 
    Public Sub New(ByVal theText As String)
        Text = theText
    End Sub
 
    Public Sub New()
        '
    End Sub
 
    <System.ComponentModel.Description("Display Text For the Item"), System.ComponentModel.Category("Item")> _
    Public Property Text() As String
        Get
            Return mc_Text
        End Get
        Set(ByVal value As String)
            mc_Text = value
        End Set
    End Property
 
End Class

check out the asd property in the designer...

(i always call junk asd)

Kris

[i00]

oh and as per usual override the tostring function if you want to change the text of each item...

[Matchlighter]

I am getting a Blue Zig-zag line under CollectionEditor It says 'Type CollectionEditor is not defined' What do I do?

E

[Matchlighter]

Also, If you could make it have the items I defined and then give it to me. I am Afraid I am not a pro a VB.Net.

Thanks for your time and Help!

E

[i00]

add a reference to system.design i think (from memory)

Kris

[Matchlighter]

That Didn't Exist. Here are the current references:
Imports System.ComponentModel
Imports System.ComponentModel.Design
Imports System.Drawing.Design

[i00]

it should exist - just checked it...
here's a sample project:

[Matchlighter]

Great! That Works! Thanks for your time!

E
P.S. Is there a way to make it one of those bottom bar object like timers are?

[Matchlighter]

How would I go about adding The Items I specified I just Cannot figure it out... I appreciate your time and effort, it is just that I am not Extremely Advanced so, if you can find the time could you make It with the Things I specified? I would greatly Appreciate it.

Thanks!
E

[i00]

well add stuff like:

Dim mc_Color As Color = Drawing.Color.Red
    <System.ComponentModel.Description("Sets the color for Item"), System.ComponentModel.Category("Item")> _
    Public Property Color() As Color
        Get
            Return mc_Color
        End Get
        Set(ByVal value As Color)
            mc_Color = value
        End Set
    End Property

bit in the TestItem class...

Kris

[NickThissen]

If you want to customize the CollectionEditor window more, you have to create your own class that derives from CollectionEditor. You can override many methods and properties and customize it the way you like.

Public Class CustomColEditor
   Inherits CollectionEditor
  
   Public Sub New(ByVal type As Type)
      MyBase.New(type)
   End Sub
 
   'override properties/methods
End Class

To use, simply set it as the CollectionEditor instead of the base 'CollectionEditor' as in i00's code:

<Editor(GetType(CustomColEditor), GetType(UITypeEditor))> _
Public Property ...

For a simple example, see my WizardControl (or possibly other controls I created, can't really remember). I needed to use it because I had a collection of Controls, and I needed the editor to create WizardPages, instead of the generic Controls.
There is a method called something like CreateCollectionType (of ItemType, can't remember), which should return the type that the collection editor modifies. If the collection itself is a strongly bound list (List(Of T)) then it should do that automatically, but in my case it was a ControlCollection so it doesn't.
There is also an array variant of that method which allows you to specify multiple types. The 'Add' button then changes into a dropdown button and you can choose one of the types. For an example on that, see my advanced ToolstripContainer control. It can create both ToolStrips and MenuStrips from the same collection editor.

[Matchlighter]

Excellent! That works Fantastically! Thank you for your time!

E