[RESOLVED] List or Array?

[thijsd]

Hello,

I am working on a Card game, and i have a little question. I want to put all the cards in a array or list. The problem is that the list need to be shuffled/randomised. But it should also be able to shrink. Witch of those 2 is better to use? And how can i shuffle them?

Please tell me,

ThijsD

[.paul.]

the list has better, easier to use, functionality than the array

[Shaggy Hiker]

If you need to change the size at any time, then a list is definitely going to be easier.

[thijsd]

Ok so list it is

But how can u shuffle one? (I thought that removing an item was .removeat(), is that true?)

[cicatrix]

Public Function Shuffle(Of T)(ByVal source As IEnumerable(Of T)) As IEnumerable(Of T)
        Dim rng As New Random
        Dim elements() As T = source.ToArray
        Dim i, SwapIndex As Integer
        Dim tmp As T
        For i = elements.Length - 1 To 1 Step -1
            SwapIndex = rng.Next(i + 1)
            tmp = elements(i)
            elements(i) = elements(SwapIndex)
            elements(SwapIndex) = tmp
        Next
        Return elements
End Function
 
Sub Test()
        Dim ordered() As Integer = {1, 2, 3, 4, 5}
        Dim shuffled = Shuffle(ordered)
        For Each el In shuffled
            Debug.Write(el.ToString + ";")
        Next
End Sub

[.paul.]

try this:

Public Class Form1
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Dim cards As New List(Of Integer)
        For x As Integer = 1 To 52
            cards.Add(x)
        Next
        cards = shuffleDeck(cards)
    End Sub
 
    Private Function shuffleDeck(ByVal deck As List(Of Integer)) As List(Of Integer)
        Dim randomNumber As New Random
        Dim used As New List(Of Integer)
        For x As Integer = 0 To deck.Count - 1
            Dim number As Integer = randomNumber.Next(0, deck.Count)
            If Not used.Contains(number) Then
                used.Add(number)
            Else
                x -= 1
            End If
        Next
        Dim newList(deck.Count - 1) As Integer
        For x As Integer = 0 To used.Count - 1
            newList(used(x)) = deck(x)
        Next
        deck.Clear()
        deck.AddRange(newList)
        Return deck
    End Function
    
End Class

with a list you can use .removeat

[thijsd]

Yes Both of these codes work! Thank you for helping me out

[NickThissen]

jmcilhinney has a very nice 'Randomize list' codebank submission which shuffles a list randomly with much less code using LINQ. The query is something simple as this:

From item As Integer In yourList _
Order By rnd.NextDouble() _
Select item

where 'rnd' is a Random object.