[RESOLVED] Shortcut keys do not work

[gate7cy]

I have formA.vb and I added some shortcut keys using the key_up event handler. Before coding the handler I change the keypreview property of the form to true. I added this code :

    Private Sub IntRMA_KeyUp(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyUp
        If e.KeyCode = Keys.ControlKey And e.KeyCode = Keys.C Then
            modcustomer.Show()
        ElseIf e.KeyCode = Keys.ControlKey And e.KeyCode = Keys.T Then
            Me.Button6.PerformClick()
        ElseIf e.KeyCode = Keys.ControlKey And e.KeyCode = Keys.I Then
            Me.Button5.PerformClick()
        ElseIf e.KeyCode = Keys.ControlKey And e.KeyCode = Keys.S Then
            Me.Button1.PerformClick()
        ElseIf e.KeyCode = Keys.ControlKey And e.KeyCode = Keys.P Then
            Me.Button9.PerformClick()
        ElseIf e.KeyCode = Keys.ControlKey And e.KeyCode = Keys.X Then
            Me.Close()
        ElseIf e.KeyCode = Keys.Escape Then
            Me.Close()
        End If
    End Sub

..... Only the last option of the Escape works. Thanks for the time and replies. Waiting for the sun between the rain

[keystone_paul]

Try this :

    Private Sub IntRMA_KeyUp(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyUp
        If e.Control = True And e.KeyCode = Keys.C Then
            modcustomer.Show()
        ElseIf e.Control = True And e.KeyCode = Keys.T Then
            Me.Button6.PerformClick()
        ElseIf e.Control = True And e.KeyCode = Keys.I Then
            Me.Button5.PerformClick()
        ElseIf e.Control = True And e.KeyCode = Keys.S Then
            Me.Button1.PerformClick()
        ElseIf e.Control = True And e.KeyCode = Keys.P Then
            Me.Button9.PerformClick()
        ElseIf e.Control = True And e.KeyCode = Keys.X Then
            Me.Close()
        ElseIf e.KeyCode = Keys.Escape Then
            Me.Close()
        End If
    End Sub

[jmcilhinney]

That's because you're testing whether e.KeyCode is two different values at the same time, which it can't possibly be. If you don't care about modifier keys then just test e.KeyCode for a single key. If you do care about modifier keys then test e.KeyData for a key combination. Your code should be:

Private Sub IntRMA_KeyUp(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyUp
    Select Case e.KeyData
        Case Keys.Control Or Keys.C
            modcustomer.Show()
        Case Keys.Control Or Keys.T
            Me.Button6.PerformClick()
        Case Keys.Control Or Keys.I
            Me.Button5.PerformClick()
        Case Keys.Control Or Keys.S
            Me.Button1.PerformClick()
        Case Keys.Control Or Keys.P
            Me.Button9.PerformClick()
        Case Keys.Control Or Keys.X
            Me.Close()
        Case Keys.Escape
            Me.Close()
    End Select
End Sub

[gate7cy]

thanks jmcilhinney. that did the work. great

[gautamshaw]

I am a beginner of .net framework and the visual basic language
I added the following code:

Private Sub Form1_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyDown
If e.Control = True And e.KeyCode = Keys.P Then
Me.Button1.PerformClick()
End If
End Sub
Private Sub Button1_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles Button1.Click
MessageBox.Show("This is a message box")
End Sub

but this is not working for me.....
can you tell me why its not working?

[gate7cy]

What exactly are trying to do? Get the button1 to perform click? What keys you want to use to enable this shortcut? the control button and P? If, yes the try this:

Private Sub Form1_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyDown
If e.KeyData = Keys.Control And e.KeyData = Keys.P Then
Me.Button1.PerformClick()
End If
End Sub

[jmcilhinney]

What exactly are trying to do? Get the button1 to perform click? What keys you want to use to enable this shortcut? the control button and P? If, yes the try this:

Private Sub Form1_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyDown
If e.KeyData = Keys.Control And e.KeyData = Keys.P Then
Me.Button1.PerformClick()
End If
End Sub

How can e.KeyData be equal to Keys.Control and equal to Keys.P at the same time? As has been established by post #3, you have to compare e.KeyData to (Keys.Control Or Keys.P), but this has already been explained to gautamshaw in their own thread on this topic, where they asked this exact same question.

[gate7cy]

my bad

drop the 'and' and replace it with an 'or'.
how on earth would I know of the anwer he got on his own thread.

[jmcilhinney]

drop the 'and' and replace it with an 'or'.

That still won't work because you're then testing for one value or the other, not both at the same time. You have to compare e.KeyData to a single value and that value has to be a combination of Keys.Control and Keys.P, which you create with a bitwise OR operation.

how on earth would I know of the anwer he got on his own thread.

You wouldn't, which is exactly why people shouldn't be posting the same question in mutliple threads. That was directed at gautamshaw, not you.