[RESOLVED] Help with Code

[Cyb3rH4Xter]

I have got this code from a friend:

Imports System.Text.RegularExpressions

Public Class GameInfo
    Private Const NumberOfFields As Integer = 5

    ' Use properties in real code; I'm using fields for brevity.
    Public IpAddress As String
    Public Port As Integer
    Public Wins As Integer
    Public UserName As String
    Public TimeStamp As Integer
    Public Points As Integer

    Public Shared Function Parse(ByVal logLine As String) As GameInfo
        Dim info As New GameInfo

        Dim pattern As String = "(?<IP>\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3}):(?<port>\d+) (?<wins>\d+) (?<userName>.*) (?<timestamp>\d{10}) (?<points>\d+)"

        Dim lineMatch As Match = Regex.Match(logLine, pattern)

        If Not lineMatch.Success Then
            ' Invalid line, possibly return an error
            Return info
        End If

        ' Group 0 is always the entire capture
        If lineMatch.Groups.Count <> NumberOfFields + 1 Then
            ' Invalid line, possibly return an error
            Return info
        End If

        info.IpAddress = lineMatch.Groups("IP").Value
        info.Port = CInt(lineMatch.Groups("port").Value)
        info.Wins = CInt(lineMatch.Groups("wins").Value)
        info.UserName = lineMatch.Groups("userName").Value
        info.TimeStamp = CInt (lineMatch.Groups("timestamp").Value
        info.Points = CInt(lineMatch.Groups("points").Value)

        Return info
    End Function

    Public Overrides Function ToString() As String
        Return String.Format("{0} ({1}:{2}) had {3} wins and {4} points.", _
                             UserName, IpAddress, Port, Wins, Points)
    End Function
End Class

I will use it for my project. What i want it to do is reading a txt file and read line by line and use this function to separate the lines into specific data. And the it should add a new item to listview detailed view for each line.

The second thing he didn't help me with, but that wouldn't be so hard i think.

Hope someone will look into this.

[.paul.]

can you post your text file, or an example of it?

[Cyb3rH4Xter]

Of course:

ip:port wins username timestamp points
ip:port wins username timestamp points
ip:port wins username timestamp points
ip:port wins username timestamp points
ip:port wins username timestamp points
ip:port wins username timestamp points
ip:port wins username timestamp points

Where the timestamp is always 10 numbers.

[.paul.]

i was thinking more along the lines of an example i could test it with

[Cyb3rH4Xter]

oh, sorry, i'll attach that!

[.paul.]

try this:
(i had to edit your text file slightly. i've reattached it)

Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
    Dim lines() As String = IO.File.ReadAllLines("gungame.txt")
    For x As Integer = 0 To lines.GetUpperBound(0)
        Dim info As New GameInfo
        info = info.Parse(lines(x))
 
        ListView1.Items.Add(New ListViewItem(New String() {info.IpAddress, info.Port.ToString, info.Wins.ToString, info.UserName, info.TimeStamp.ToString, info.Points.ToString}))
    Next
End Sub

Public Class GameInfo
 
    Public IpAddress As String
    Public Port As Integer
    Public Wins As Integer
    Public UserName As String
    Public TimeStamp As Integer
    Public Points As Integer
 
    Public Function Parse(ByVal logLine As String) As GameInfo
        Dim info As New GameInfo
 
        Dim rx As New Regex("(?<IP>(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3}))(\:(?<port>(\d+)))?\t(?<wins>(\d+))\t(?<userName>((.|\s)*))\t(?<timestamp>(\d{10}))\t(?<points>(\d+))")
 
        Dim lineMatch As Match = rx.Match(logLine)
 
        If Not lineMatch.Success Then
            ' Invalid line, possibly return an error
            Return info
        End If
 
        If logLine = "" Then
            ' Invalid line, possibly return an error
            Return info
        End If
 
        info.IpAddress = lineMatch.Groups("IP").Value
        info.Port = CInt(Val(lineMatch.Groups("port").Value))
        info.Wins = CInt(lineMatch.Groups("wins").Value)
        info.UserName = lineMatch.Groups("userName").Value
        info.TimeStamp = CInt(lineMatch.Groups("timestamp").Value)
        info.Points = CInt(lineMatch.Groups("points").Value)
 
        Return info
    End Function
 
End Class

[.paul.]

looking at it again, i'd recommend changing Port + TimeStamp to strings, to avoid zero value Ports or truncated TimeStamps

[Cyb3rH4Xter]

Hmm, i have applied the code, but nothing happens when i click my button. I've attached my .vb file with the code. Have i made anything wrong?

[.paul.]

you didn't use what i posted. gungame.txt needs to be in your bin/debug folder

Imports System.Text.RegularExpressions
 
Public Class Form1
 
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
 
        Dim lines() As String = IO.File.ReadAllLines("gungame.txt")
 
        For x As Integer = 0 To lines.GetUpperBound(0)
 
            Dim info As New GameInfo
 
            info = info.Parse(lines(x))
 
 
 
            ListView1.Items.Add(New ListViewItem(New String() {info.IpAddress, info.Port, info.Wins.ToString, info.UserName, info.TimeStamp, info.Points.ToString}))
 
        Next
 
        MsgBox("Done!")
 
    End Sub
End Class
 
Public Class GameInfo
    Public IpAddress As String
    Public Port As String
    Public Wins As Integer
    Public UserName As String
    Public TimeStamp As String
    Public Points As Integer
    Public Function Parse(ByVal logLine As String) As GameInfo
        Dim info As New GameInfo
        Dim rx As New Regex("(?<IP>(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3}))(\:(?<port>(\d+)))?\t(?<wins>(\d+))\t(?<userName>((.|\s)*))\t(?<timestamp>(\d{10}))\t(?<points>(\d+))")
        Dim lineMatch As Match = rx.Match(logLine)
        If Not lineMatch.Success Then
            ' Invalid line, possibly return an error
            Return info
        End If
        If logLine = "" Then
            ' Invalid line, possibly return an error
            Return info
        End If
        info.IpAddress = lineMatch.Groups("IP").Value
        info.Port = lineMatch.Groups("port").Value
        info.Wins = CInt(lineMatch.Groups("wins").Value)
        info.UserName = lineMatch.Groups("userName").Value
        info.TimeStamp = lineMatch.Groups("timestamp").Value
        info.Points = CInt(lineMatch.Groups("points").Value)
        Return info
    End Function
End Class

[.paul.]

just paste Class GameInfo after the end class in your form1 code.
also as i said you need the text file in the same folder as the executable, which is your projects bin/debug folder. don't forget to set your listview view to details + add 6 columns to it.

[Cyb3rH4Xter]

WAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA!
It works! You're the ****ing man dude! +Reputation!
Thank you SO much!