Working with Windows Registry using Visual Basic 6 - A complete Tutorial

[Siddharth Rout]

Now that we have the MyApp's startup form's .Top value saved in the Windows Registry, we need to access the value whenever our program starts up. We'll use the Visual Basic GetSetting function to read this value from the Windows Registry, and a good place to execute that function is in the Load Event Procedure of the form. Before I show you that code, let me show you the format for the GetSetting function.

Syntax

GetSetting(appname, section, key[, default])

The GetSetting function syntax has thesenamed arguments:

Part Description
appname Required String expression containing the name of the application or project whose key setting is requested.
section Required String expression containing the name of the section where the key setting is found.
key Required String expression containing the name of the key setting to return.
default Optional Expression containing the value to return if no value is set in the key setting. If omitted, default is assumed to be a zero-length string ("").

As you can see, the first three arguments of the GetSetting function are identical to the SaveSetting statement. The difference lies in the fourth argument. With the SaveSetting Statement, the fourth argument was the value to be written to the Registry. For the GetSetting function, the fourth argument is an optional argument used to specify a default value to be returned in the event that the entry specified cannot be located in the Windows Registry.

Here's the code to place in the Load Event Procedure of the Startup Form. I have inserted 2 message box in the code below so that you can understand how it works...

Private Sub Form_Load()
    '~~> Check what is the current top value
    MsgBox Form1.Top
    '~~> Get value from registry
    Form1.Top = GetSetting("MyApp", "Startup", "Top", 25)
    '~~> Check the new top value
    MsgBox Form1.Top
End Sub

[Siddharth Rout]

To delete the entry that you made in the registry, you need to use DeleteSetting statement

Syntax

DeleteSetting appname, section[, key]

The DeleteSetting statement syntax has these named arguments:

Part Description
appname Required String expression containing the name of the application or project to which the section or key setting applies.
section Required String expression containing the name of the section where the key setting is being deleted. If only appname and section are provided, the specified section is deleted along with all related key settings.
key Optional String expression containing the name of the key setting being deleted.

You can use it to delete the appname, section and key entry, similar to the way you created the entry to begin with. For example

DeleteSetting "MyApp", "Startup", "Top

After deleting the key, try searching the registry again and you will see that the key has been deleted.

[Siddharth Rout]

Visual Basic provides us a function called GetAllSettings which can be used to return the Registry entries for a particular Appname and Setting. Here's the format for the GetAllSettings function. This is used for example in case we loose track of the entries we have made in the windows registry.

Syntax

GetAllSettings(appname, section)

The GetAllSettings function syntax has these named arguments:

Part Description
appname Required String expression containing the name of the application orproject whose key settings are requested.
section Required String expression containing the name of the section whose key settings are requested. GetAllSettings returns aVariant whose contents is a two-dimensional array of strings containing all the key settings in the specified section and their corresponding values.

Once GetAllSettings executes and returns a two dimensional array, we can use the Lbound and Ubound functions, in conjunction with a For-Next Loop to move through the elements of the Array and display them as shown in the code below

Private Sub Command2_Click()
    Dim MyAppSettings As Variant, i As Long
    
    MyAppSettings = GetAllSettings("MyApp", "Startup")
    
    '~~> Loop through the array
    For i = LBound(MyAppSettings, 1) To UBound(MyAppSettings, 1)
        '~~> Display the values in the array
        MsgBox MyAppSettings(i, 0), MyAppSettings(i, 1)
    Next i
End Sub

[Siddharth Rout]

Assuming that you haven't deleted the key that we created above, lets now try to find the key we created.

Like I mentioned above, Visual Basic, by default using GetSetting and SaveSetting allows reading and writing only to the VB and VBA Programs key under HKEY_Current_User\Software.

Create a form and place a Text Box and a Command Button in it. Place the code in the general declaration of the form.

Private Declare Function RegOpenKeyEx Lib "advapi32.dll" Alias "RegOpenKeyExA" _
(ByVal hKey As Long, ByVal lpSubKey As String, ByVal ulOptions As Long, _
ByVal samDesired As Long, phkResult As Long) As Long
 
Private Declare Function RegCloseKey Lib "advapi32.dll" (ByVal hKey As Long) As _
Long
 
Const KEY_READ = &H20019
Const HKEY_CURRENT_USER = &H80000001
 
'~~> Return True if a Registry key exists
Function CheckRegistryKey(ByVal hKey As Long, ByVal KeyName As String) As Boolean
    Dim handle As Long
    '~~> Try to open the key
    If RegOpenKeyEx(hKey, KeyName, 0, KEY_READ, handle) = 0 Then
        '~~> The key exists
        CheckRegistryKey = True
        '~~> Close it before exiting
        RegCloseKey handle
    End If
End Function
 
Private Sub Command1_Click()
'~~> Visual Basic, by default using GetSetting and SaveSetting allows reading and
'~~> writing only to the VB and VBA Programs key under HKEY_Current_User\Software.
    Dim strSubKey As String
    strSubKey = Trim(Text1.Text)
    '~~> will return True if it exists
    MsgBox CheckRegistryKey(HKEY_CURRENT_USER, strSubKey)
End Sub

Run the Form and type "Software\VB and VBA Program Settings\MyApp" in the Text Box. Once done, click the Command Button. you will get the message "True" if the key exists or "False" if it doesn't.

[Siddharth Rout]

I have mentioned the constants for the hives in the Windows Registry so that you can experiment if you want to...

'~~> Constants for the Registry Hive in case you want to experiment
Const HKEY_CLASSES_ROOT = &H80000000
Const HKEY_CURRENT_USER = &H80000001
Const HKEY_LOCAL_MACHINE = &H80000002
Const HKEY_USERS = &H80000003
 
'~~> Other Constants for RegCreateKeyEx
Const REG_OPTION_BACKUP_RESTORE = 4   '<~~ open for backup or restore
Const REG_OPTION_VOLATILE = 1         '<~~ Key isn't preserved if system is rebooted
Const REG_OPTION_NON_VOLATILE = 0     '<~~ Key is preserved if system is rebooted
Const STANDARD_RIGHTS_ALL = &H1F0000
Const SYNCHRONIZE = &H100000
Const READ_CONTROL = &H20000
Const STANDARD_RIGHTS_READ = (READ_CONTROL)
Const STANDARD_RIGHTS_WRITE = (READ_CONTROL)
Const KEY_CREATE_LINK = &H20
Const KEY_CREATE_SUB_KEY = &H4
Const KEY_ENUMERATE_SUB_KEYS = &H8
Const KEY_NOTIFY = &H10
Const KEY_QUERY_VALUE = &H1
Const KEY_SET_VALUE = &H2
Const KEY_READ = ((STANDARD_RIGHTS_READ Or KEY_QUERY_VALUE Or _
KEY_ENUMERATE_SUB_KEYS Or KEY_NOTIFY) And (Not SYNCHRONIZE))
Const KEY_WRITE = ((STANDARD_RIGHTS_WRITE Or KEY_SET_VALUE Or _
KEY_CREATE_SUB_KEY) And (Not SYNCHRONIZE))
Const KEY_EXECUTE = (KEY_READ)
Const KEY_ALL_ACCESS = ((STANDARD_RIGHTS_ALL Or KEY_QUERY_VALUE Or _
KEY_SET_VALUE Or KEY_CREATE_SUB_KEY Or KEY_ENUMERATE_SUB_KEYS Or _
KEY_NOTIFY Or KEY_CREATE_LINK) And (Not SYNCHRONIZE))
 
'~~> The RegCloseKey function releases the handle of the specified key.
Private Declare Function RegCloseKey Lib "advapi32.dll" (ByVal hKey As Long) As Long
 
'~~> The RegDeleteKey function deletes the specified key
Private Declare Function RegDeleteKey Lib "advapi32.dll" Alias "RegDeleteKeyA" _
(ByVal hKey As Long, ByVal lpSubKey As String) As Long
 
'~~> The RegCreateKeyEx function creates the specified key. If the key already exists
'in the registry, the function opens it.
Private Declare Function RegCreateKeyEx Lib "advapi32.dll" Alias "RegCreateKeyExA" _
(ByVal hKey As Long, ByVal lpSubKey As String, ByVal Reserved As Long, ByVal _
lpClass As String, ByVal dwOptions As Long, ByVal samDesired As Long, _
lpSecurityAttributes As Any, phkResult As Long, lpdwDisposition As Long) As Long
 
'~~> The RegOpenKeyEx function opens the specified key.
Private Declare Function RegOpenKeyEx Lib "advapi32.dll" Alias "RegOpenKeyExA" _
(ByVal hKey As Long, ByVal lpSubKey As String, ByVal Reserved As Long, ByVal _
samDesired As Long, phkResult As Long) As Long
 
Private Sub Command1_Click()
    '~~> Code adapted from APIGuide <~~'
    Dim Result As Long
    
    '~~> Check if the specified key "koolsid" exists under HKEY_CLASSES_ROOT
    RegOpenKeyEx HKEY_CLASSES_ROOT, "koolsid", 0, KEY_ALL_ACCESS, Result
    
    '~~> If the key doesn't exist, we create it
    If Result = 0 Then
        '~~> Create a new key under HKEY_CLASSES_ROOT
        RegCreateKeyEx HKEY_CLASSES_ROOT, "koolsid", 0, "REG_DWORD", _
        REG_OPTION_NON_VOLATILE, KEY_ALL_ACCESS, ByVal 0&, Result, ret
        
        If Result = 0 Then
            MsgBox "Error while creating the Key!!"
            Exit Sub
        End If
        '~~> Inform user that the key has been created
        MsgBox "Key Created..."
    End If
    
    '~~> Inform user before deleting the key
    MsgBox "Deleting the Key..."
    
    '~~> Delete the key
    RegDeleteKey Result, ""
    
    '~~> Close the handle
    RegCloseKey Result
End Sub

[Siddharth Rout]

Based on Article by Microsoft.Com....

Using API functions to programmatically find keys in the system registry. The sample demonstrates searches of root subkeys for specified text strings. An option to perform case-sensitive text search is also available.

The example uses the RegEnumKeyEx API function to enumerate subkeys of a specified open registry key. The function retrieves information about one subkey each time it is called.

[Siddharth Rout]

Please note that all these API's have been extensively covered in http://allapi.mentalis.org/agnet/apiguide.shtml and hence I will not cover them here. However if you have any questions then refer to Summary in the next post...

RegCloseKey
The RegCloseKey function releases the handle of the specified key.

RegCreateKey
The RegCreateKey function creates the specified key. If the key already exists in the registry, the function opens it. This function is provided for compatibility with Windows version 3.1. Win32-based applications should use the RegCreateKeyEx function.

RegCreateKeyEx
The RegCreateKeyEx function creates the specified key. If the key already exists in the registry, the function opens it.

RegDeleteKey
Windows 95: The RegDeleteKey function deletes a key and all its descendents.
Windows NT: The RegDeleteKey function deletes the specified key. This function cannot delete a key that has subkeys.

RegDeleteValue
The RegDeleteValue function removes a named value from the specified registry key.

RegEnumKeyEx
The RegEnumKeyEx function enumerates subkeys of the specified open registry key. The function retrieves information about one subkey each time it is called.

RegEnumValue
The RegEnumValue function enumerates the values for the specified open registry key. The function copies one indexed value name and data block for the key each time it is called.

Edit: 18/06/2010

RegCreateKey, RegCloseKey and RegDeleteKey covered in this thread...

http://www.vbforums.com/showthread.php?t=618594