[2008] Detect the insertion of a USB mass storage device (USB stick etc.)

[obi1kenobi]

I'm looking for a way to detect when a new USB mass storage device is inserted in one of the pc's USB ports... I need to get it's drive letter and check for the existence of a particular file. Any ideas?

[Deepak Sakpal]

Here are the results from Google.

[.NetNinja]

Here is a VERY lame way to do it. Just put this in a Timer_Tick function:

           Dim oDrive As DriveInfo
            For Each oDrive In DriveInfo.GetDrives
                If oDrive.DriveType = IO.DriveType.Removable Then
                    MessageBox.Show("Removable USB Drive " & oDrive.Name & " found.", "Warning", MessageBoxButtons.OK, MessageBoxIcon.Error, MessageBoxDefaultButton.Button1, MessageBoxOptions.ServiceNotification, False)
                    Exit Sub
                End If
            Next

You can also use WMI like this (This is the entire form class):

Imports System.Management

Public Class Form1
    Private WithEvents m_MediaConnectWatcher As ManagementEventWatcher
    Public USBDriveName As String
    Public USBDriveLetter As String

    Private Sub Form1_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
        StartDetection()
    End Sub

    Public Sub StartDetection()
        Dim query2 As New WqlEventQuery("SELECT * FROM __InstanceOperationEvent WITHIN 1 " & "WHERE TargetInstance ISA 'Win32_DiskDrive'")

        m_MediaConnectWatcher = New ManagementEventWatcher
        m_MediaConnectWatcher.Query = query2
        m_MediaConnectWatcher.Start()
    End Sub


    Private Sub Arrived(ByVal sender As Object, ByVal e As System.Management.EventArrivedEventArgs) Handles m_MediaConnectWatcher.EventArrived
        Dim mbo As ManagementBaseObject
        Dim obj As ManagementBaseObject

        mbo = CType(e.NewEvent, ManagementBaseObject)
        obj = CType(mbo("TargetInstance"), ManagementBaseObject)

        Select Case mbo.ClassPath.ClassName
            Case "__InstanceCreationEvent"
                If obj("InterfaceType") = "USB" Then
                    MsgBox(obj("Caption") & " (Drive letter " & GetDriveLetterFromDisk(obj("Name")) & ") has been plugged in")
                End If
            Case "__InstanceDeletionEvent"
                If obj("InterfaceType") = "USB" Then
                    MsgBox(GetDriveLetterFromDisk(obj("Name")))
                    If obj("Caption") = USBDriveName Then
                        USBDriveLetter = ""
                        USBDriveName = ""
                    End If
                End If
            Case Else
                MsgBox("nope: " & obj("Caption"))
        End Select
    End Sub

    Private Function GetDriveLetterFromDisk(ByVal Name As String) As String
        Dim oq_part, oq_disk As ObjectQuery
        Dim mos_part, mos_disk As ManagementObjectSearcher
        Dim obj_part, obj_disk As ManagementObject
        Dim ans As String = ""

        Name = Replace(Name, "\", "\\")

        oq_part = New ObjectQuery("ASSOCIATORS OF {Win32_DiskDrive.DeviceID=""" & Name & """} WHERE AssocClass = Win32_DiskDriveToDiskPartition")
        mos_part = New ManagementObjectSearcher(oq_part)
        For Each obj_part In mos_part.Get()

            oq_disk = New ObjectQuery("ASSOCIATORS OF {Win32_DiskPartition.DeviceID=""" & obj_part("DeviceID") & """} WHERE AssocClass = Win32_LogicalDiskToPartition")
            mos_disk = New ManagementObjectSearcher(oq_disk)
            For Each obj_disk In mos_disk.Get()
                ans &= obj_disk("Name") & ","
            Next
        Next

        Return ans.Trim(","c)
    End Function

End Class

[obi1kenobi]

Thanks to both of you. I'll try out the code as soon as I can and post accordingly.

[obi1kenobi]

Ok after adding references to System.Management and System.Management.Instrumentation, I made some changes to the code, in order to fix several errors (concatenation operator cannot be used on Object etc.)

Imports System.Management

Public Class Form3
    Private WithEvents m_MediaConnectWatcher As ManagementEventWatcher
    Public USBDriveName As String
    Public USBDriveLetter As String

    Private Sub Form1_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
        StartDetection()
    End Sub

    Private Sub Form3_FormClosed(ByVal sender As Object, ByVal e As System.Windows.Forms.FormClosedEventArgs) Handles Me.FormClosed
        m_MediaConnectWatcher.Stop()
        m_MediaConnectWatcher.Dispose()
    End Sub

    Public Sub StartDetection()
        Dim query2 As New WqlEventQuery("SELECT * FROM __InstanceOperationEvent WITHIN 1 " & "WHERE TargetInstance ISA 'Win32_DiskDrive'")

        m_MediaConnectWatcher = New ManagementEventWatcher
        m_MediaConnectWatcher.Query = query2
        m_MediaConnectWatcher.Start()
    End Sub

    Private Sub Arrived(ByVal sender As Object, ByVal e As System.Management.EventArrivedEventArgs) Handles m_MediaConnectWatcher.EventArrived
        Dim mbo As ManagementBaseObject
        Dim obj As ManagementBaseObject

        mbo = CType(e.NewEvent, ManagementBaseObject)
        obj = CType(mbo("TargetInstance"), ManagementBaseObject)

        Select Case mbo.ClassPath.ClassName
            Case "__InstanceCreationEvent"
                If obj.Item("InterfaceType").ToString = "USB" Then
                    USBDriveName = obj.Item("Caption").ToString
                    USBDriveLetter = GetDriveLetterFromDisk(obj.Item("Name").ToString)
                    MessageBox.Show(USBDriveName & " (Drive letter " & USBDriveLetter & ") has been plugged in")
                End If
            Case "__InstanceDeletionEvent"
                If obj.Item("InterfaceType").ToString = "USB" Then
                    MessageBox.Show(USBDriveName & " was disconnected. " & USBDriveLetter & " is now inaccessible.") 'GetDriveLetterFromDisk(obj.Item("Name").ToString))
                    If obj.Item("Caption").ToString = USBDriveName Then
                        USBDriveLetter = ""
                        USBDriveName = ""
                    End If
                End If
            Case Else
                MessageBox.Show("nope: " & obj.Item("Caption").ToString)
        End Select
    End Sub

    Private Function GetDriveLetterFromDisk(ByVal Name As String) As String
        Dim oq_part, oq_disk As ObjectQuery
        Dim mos_part, mos_disk As ManagementObjectSearcher
        Dim obj_part, obj_disk As ManagementObject
        Dim ans As String = ""

        Name = Replace(Name, "\", "\\")

        oq_part = New ObjectQuery("ASSOCIATORS OF {Win32_DiskDrive.DeviceID=""" & Name & """} WHERE AssocClass = Win32_DiskDriveToDiskPartition")
        mos_part = New ManagementObjectSearcher(oq_part)
        For Each obj_part In mos_part.Get()

            oq_disk = New ObjectQuery("ASSOCIATORS OF {Win32_DiskPartition.DeviceID=""" & obj_part.Item("DeviceID").ToString & """} WHERE AssocClass = Win32_LogicalDiskToPartition")
            mos_disk = New ManagementObjectSearcher(oq_disk)
            For Each obj_disk In mos_disk.Get()
                ans &= obj_disk.Item("Name").ToString & ","
            Next
        Next

        Return ans.Trim(","c)
    End Function

Please note that the ManagementEventWatcher must be disposed of when the form is closed, otherwise an exception is thrown.

[obi1kenobi]

One more question... Would this same code also detect the insertion of a memory card in a card reader? If not, would it be possible to make some changes so that it does?

[.NetNinja]

I'm not 100% sure if it would. It would probably depend on the reader. I would guess it would if the reader was USB external, but for internal readers maybe/maybe not.

[JuggaloBrotha]

I'm not 100% sure if it would. It would probably depend on the reader. I would guess it would if the reader was USB external, but for internal readers maybe/maybe not.

Just to let you guys know, both internal and external usb readers hook to the system's usb bus, meaning internal readers are hooked to the usb hub built into the motherboard/usb expansion card on the system.

[Jenner]

There are some chip readers that have a permanent "drive assignment" in Windows (just like a CDROM does, whether it has a disk in it or not) and they don't recognize the act of chip insertion or removal. Those may cause problems.

[JuggaloBrotha]

There are some chip readers that have a permanent "drive assignment" in Windows (just like a CDROM does, whether it has a disk in it or not) and they don't recognize the act of chip insertion or removal. Those may cause problems.

Both of my card readers (one internal and one external that plugs into a usb port on the usb hub in my dell monitor) both have an assigned windows drive letter (Once the external one's plugged windows assigns it the drive letters) for each reader (4 each) and when I insert my sd card windows xp some how detects it and pops up the 'What do you want to do with it" window immediately after insertion of the card.

Windows Vista pops up with the same window 5 minutes after the card's inserted. Then again Vista wasn't built to get work done, so 5 minute delays are excusable to the public.

[obi1kenobi]

Well my card reader doesn't have a permanent drive assignment, so is it safe to assume that the code will work as is? I do not own a card so I cannot try it myself... :/

[.NetNinja]

I am not sure I would say it is safe to assume. I am fairly certain that is the case though.

[JuggaloBrotha]

If the above code is working, perhaps a codebank thread would be in order?

[Xancholy]

This is a great thread. Subscribing.

[obi1kenobi]

Sorry for being absent for so long a period, I had no access to the internet for over 10 days :S

The code works like a charm, no issues as of this moment. Since I didn't provide the code in the first place, I only tweaked it to work better, I believe it would be more appropriate if .NetNinja posted this in the CodeBank... After all, I don't want to take credit for something someone else did...

[.NetNinja]

Sorry for being absent for so long a period, I had no access to the internet for over 10 days :S

The code works like a charm, no issues as of this moment. Since I didn't provide the code in the first place, I only tweaked it to work better, I believe it would be more appropriate if .NetNinja posted this in the CodeBank... After all, I don't want to take credit for something someone else did...

I have added this to the code bank: http://www.vbforums.com/showthread.php?t=550730

obi1kenobi: Thanks again for the tweak.

[Biggy-D]

Error	1	Type 'ManagementEventWatcher' is not defined.	
Error	2	Type 'WqlEventQuery' is not defined.	
Error	3	Type 'ManagementEventWatcher' is not defined.	
Error	4	Type 'System.Management.EventArrivedEventArgs' is not defined.	
Error	5	Type 'ManagementBaseObject' is not defined.	
Error	6	Type 'ManagementBaseObject' is not defined.	
Error	7	Type 'ManagementBaseObject' is not defined.	
Error	8	Type 'ManagementBaseObject' is not defined.	
Error	9	Type 'ObjectQuery' is not defined.	
Error	10	Type 'ManagementObjectSearcher' is not defined.	
Error	11	Type 'ManagementObject' is not defined.	
Error	12	Type 'ObjectQuery' is not defined.	
Error	13	Type 'ManagementObjectSearcher' is not defined.

[.NetNinja]

Did you import System.Management?

[Biggy-D]

how to remove msgbox and show result in TextBox ?

[obi1kenobi]

Remove the "MessageBox.Show" part and replace it with "TextBox1.Text =" - no quotation marks.

[Biggy-D]

obi1kenobi thnx for reply

i try but doesn't work, did nothing !!
any idea !

[obi1kenobi]

Perhaps the name of the TextBox you are using is different? I can't think of another reason which would prevent it from working. Post your code and I'll fix it for you.

[Biggy-D]

Imports System.Management
Public Class Form1
    Private WithEvents m_MediaConnectWatcher As ManagementEventWatcher
    Public USBDriveName As String
    Public USBDriveLetter As String

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        StartDetection()
    End Sub
    Public Sub StartDetection()
        Dim query2 As New WqlEventQuery("SELECT * FROM __InstanceOperationEvent WITHIN 1 " & "WHERE TargetInstance ISA 'Win32_DiskDrive'")

        m_MediaConnectWatcher = New ManagementEventWatcher
        m_MediaConnectWatcher.Query = query2
        m_MediaConnectWatcher.Start()
    End Sub
    Private Sub Arrived(ByVal sender As Object, ByVal e As System.Management.EventArrivedEventArgs) Handles m_MediaConnectWatcher.EventArrived
        Dim mbo As ManagementBaseObject
        Dim obj As ManagementBaseObject

        mbo = CType(e.NewEvent, ManagementBaseObject)
        obj = CType(mbo("TargetInstance"), ManagementBaseObject)

        Select mbo.ClassPath.ClassName
            Case "__InstanceCreationEvent"
                If obj.Item("InterfaceType").ToString = "USB" Then
                    USBDriveName = obj.Item("Caption").ToString
                    USBDriveLetter = GetDriveLetterFromDisk(obj.Item("Name").ToString)
                    TextBox1.Text = (USBDriveName & " (Drive letter " & USBDriveLetter & ") has been plugged in")
                End If
            Case "__InstanceDeletionEvent"
                If obj.Item("InterfaceType").ToString = "USB" Then
                    TextBox1.Text = (USBDriveName & " was disconnected. " & USBDriveLetter & " is now inaccessible.") 'GetDriveLetterFromDisk(obj.Item("Name").ToString))
                    If obj.Item("Caption").ToString = USBDriveName Then
                        USBDriveLetter = ""
                        USBDriveName = ""
                    End If
                End If
            Case Else
                TextBox1.Text = ("nope: " & obj.Item("Caption").ToString)
        End Select
    End Sub
    Private Function GetDriveLetterFromDisk(ByVal Name As String) As String
        Dim oq_part, oq_disk As ObjectQuery
        Dim mos_part, mos_disk As ManagementObjectSearcher
        Dim obj_part, obj_disk As ManagementObject
        Dim ans As String = ""

        Name = Replace(Name, "\", "\\")

        oq_part = New ObjectQuery("ASSOCIATORS OF {Win32_DiskDrive.DeviceID=""" & Name & """} WHERE AssocClass = Win32_DiskDriveToDiskPartition")
        mos_part = New ManagementObjectSearcher(oq_part)
        For Each obj_part In mos_part.Get()

            oq_disk = New ObjectQuery("ASSOCIATORS OF {Win32_DiskPartition.DeviceID=""" & obj_part.Item("DeviceID").ToString & """} WHERE AssocClass = Win32_LogicalDiskToPartition")
            mos_disk = New ManagementObjectSearcher(oq_disk)
            For Each obj_disk In mos_disk.Get()
                ans &= obj_disk.Item("Name").ToString & ","
            Next
        Next

        Return ans.Trim(","c)
    End Function
End Class

doesn't work for me !!!!

[.NetNinja]

Why do you have :

Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs)_
 Handles MyBase.Load

[obi1kenobi]

@.NetNinja: That's the correct event signature, check your IDE.

@Biggy-D: The code you are using is ok. Add the reference to System.Management and it'll work fine. Right-click your project in solution explorer, click Properties, select the References tab, then click Add and in the .Net tab scroll to System.Management and select it. The errors will disappear.

[Biggy-D]

@obi1kenobi

the reference :System.Management is already inserted ..
the code doesn't give errors,but doesn't work when i change " messagebox to textbox.text " in the textbox.text i want to display drive info, like messagebox info.

[obi1kenobi]

I tried it in 2005 and it indeed didn't work, I got an InvalidCOMException. I'm puzzled, it should have worked XC

[dee-u]

What did you try that did not work?

[Biggy-D]

i have 2008 !!

[dee-u]

What did you mean by it doesn't work? It doesn't detect or are you encountering some exceptions?

[Biggy-D]

ok. i try to change

MessageBox.Show(USBDriveName & " (Drive letter " & USBDriveLetter & ") has been plugged in")

to

TextBox1.text = (USBDriveName & " (Drive letter " & USBDriveLetter & ") has been plugged in")

in textbox1 doesn't show result..

[dee-u]

When using the MessageBox does it get the correct result?

[Biggy-D]

when using the messagebox i get the correct result..

[dee-u]

That's odd. Care to post the relevant section of the code where you are using a textbox?

[Biggy-D]

textbox1 is in a form1, my code is under form1 class .
here is my code :

Imports System.Management
Public Class Form1
    Private WithEvents m_MediaConnectWatcher As ManagementEventWatcher
    Public USBDriveName As String
    Public USBDriveLetter As String
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        StartDetection()
    End Sub
    Public Sub StartDetection()
        Dim query2 As New WqlEventQuery("SELECT * FROM __InstanceOperationEvent WITHIN 1 " & "WHERE TargetInstance ISA 'Win32_DiskDrive'")
 
        m_MediaConnectWatcher = New ManagementEventWatcher
        m_MediaConnectWatcher.Query = query2
        m_MediaConnectWatcher.Start()
    End Sub
    Private Sub Arrived(ByVal sender As Object, ByVal e As System.Management.EventArrivedEventArgs) Handles m_MediaConnectWatcher.EventArrived
        Dim mbo As ManagementBaseObject
        Dim obj As ManagementBaseObject
 
        mbo = CType(e.NewEvent, ManagementBaseObject)
        obj = CType(mbo("TargetInstance"), ManagementBaseObject)
 
        Select mbo.ClassPath.ClassName
            Case "__InstanceCreationEvent"
                If obj.Item("InterfaceType").ToString = "USB" Then
                    USBDriveName = obj.Item("Caption").ToString
                    USBDriveLetter = GetDriveLetterFromDisk(obj.Item("Name").ToString)
                    TextBox1.Text = (USBDriveName & " (Drive letter " & USBDriveLetter & ") has been plugged in")
                End If
            Case "__InstanceDeletionEvent"
                If obj.Item("InterfaceType").ToString = "USB" Then
                    TextBox1.Text = (USBDriveName & " was disconnected. " & USBDriveLetter & " is now inaccessible.") 'GetDriveLetterFromDisk(obj.Item("Name").ToString))
                    If obj.Item("Caption").ToString = USBDriveName Then
                        USBDriveLetter = ""
                        USBDriveName = ""
                    End If
                End If
            Case Else
                TextBox1.Text = ("nope: " & obj.Item("Caption").ToString)
        End Select
    End Sub
    Private Function GetDriveLetterFromDisk(ByVal Name As String) As String
        Dim oq_part, oq_disk As ObjectQuery
        Dim mos_part, mos_disk As ManagementObjectSearcher
        Dim obj_part, obj_disk As ManagementObject
        Dim ans As String = ""
 
        Name = Replace(Name, "\", "\\")
 
        oq_part = New ObjectQuery("ASSOCIATORS OF {Win32_DiskDrive.DeviceID=""" & Name & """} WHERE AssocClass = Win32_DiskDriveToDiskPartition")
        mos_part = New ManagementObjectSearcher(oq_part)
        For Each obj_part In mos_part.Get()
 
            oq_disk = New ObjectQuery("ASSOCIATORS OF {Win32_DiskPartition.DeviceID=""" & obj_part.Item("DeviceID").ToString & """} WHERE AssocClass = Win32_LogicalDiskToPartition")
            mos_disk = New ManagementObjectSearcher(oq_disk)
            For Each obj_disk In mos_disk.Get()
                ans &= obj_disk.Item("Name").ToString & ","
            Next
        Next
 
        Return ans.Trim(","c)
    End Function
End Class

[.NetNinja]

Could it have something to do with Cross Threading? (I could be way off)

[obi1kenobi]

I tried his code in 2005 and it just ignored the TextBox1.Text line and then threw the exception I described... I can't make heads or tails of this problem...

[dee-u]

It could be a problem with WMI, when I have time I will try to dig furhter into it.

[chris128]

I know I already pointed this out in the codebank entry but it may just be worth mentioning here if you guys are having problems with the WMI version : I made something that does pretty much the exact same thing obi1 described in his original post (ie detect when a new drive is inserted and check for a file on it) using Windows API.
Read all 7 posts in this thread (The 2nd post provides the full code but then I fixed a little problem with the drive letter assignment in the last post) and see if it helps: http://www.vbforums.com/showthread.php?t=534956

Oh and the way I'm searching for the file in that 2nd post isnt great lol I dont know why I was using GetFiles instead of FileExists... it still works but it could be slow if the USB device has a lot of files on it so you might want to change that bit (in the WndProc sub)

[Biggy-D]

chris128

the WMI version work for me !

thnx