Read web page dynamically (Solved)

[nasreen]

Hi

I want to read some texts from a web page dynamially using VB6. This text is not same string every time, it is like a secret code subjected to change on each visit to this page.

I was reading by tagname like:

Dim MySecretCode as String
MySecretCode  = WebBrowser1.Document.getElementsByTagName("td").Item(4).innerText

But whenever any modification occures in the webpage the item number 18 is changed so I want to findout the correct number and change this in my code or in database for every modification in the webpage

So is there any trick to read the required text dynamically.

In the web page there is a constant text in a cell before the cell of the secret code that I need to read.

If it is possible to find out the item number of a cell based on the text in it, I think I can solve my problem, but I don't know how to find the item number dynamically

I hope anybody can help me

With regards,
Nasreen

[dee-u]

How about INSTR? Is the table containing that item is dynamically being changed also? If not perhaps you could instead retrieve it and then just retrieve on what column the data you want is located.

[nasreen]

Hi dee-u
In my case the INSTR is not applicable because the data is changed and once every two month some columns and rows in the tables also either added or removed due to modifications in the page. So that I cannot depend a constact item number of the cell.
As I think the possible way is what did you say:

If not perhaps you could instead retrieve it and then just retrieve on what column the data you want is located.

Because there is another cell with a static data in it and this cell is adjacent for the cell I want read it. We can read this static data with INSTR and if possible we can find out the item number of this cell

But I don't know how to retrieve a column or cell item number based on the data in it.

Can anybody forward me a solution ?

With regards,
Nasreen

[westconn1]

it is probably quite easy to do, but i would need to look at the web page
can you post a link to it, or pm it to me

[nasreen]

Hi westconn1

Here I attached the saved page of my webpage (confirm.zip). The value I want to read formt this page is (585564559854564), and it is not constant but is changed upon every visit to this page. The text(U Code: ) is constant.

With regards,
Nasreen

[Jim Davis]

Can't you just simply modify the code that generates the html output, to add id= property to each td element? Just like

<td id="td:12_3">value here</td><td id="td:12_4">value here</td>.. etc The 12 can be a row, and 4 can be a column identifier.

So you can get these element by their id anytime you are looking for its value.

document.getElementById('td:12_3').innerText
document.getElementById('td:12_4').innerText

Its just a tip, havent tested, but you might want to.

[nasreen]

Hi Jim Davis
Thanks for your replay.
Please be informed that I have no any control on the web page since it is for a third party in a western country. Our company uses the services of this website and I am assigned to develop a project to store the data of the page in the local server of our company.
The web page is subjected to modification oftenly that changes positions of rows and columns of the tables in it. So I cannot depend a constant item number of the cell.
What I expect is an idea to find out the item number of a cell holds a constant value. In my attached page it is U Code:. So this item number + 1 will be the accurate item number of the cell that I want to read exactly. We can find out this constant value using INSTR, but how we can find out the item number of that cell or any other solution to get the exact value

With regards,
Nasreen

[Jim Davis]

Since the ucode is encapusalted between <span> tags,

WebBrowser1.Document.getElementsByTagName("span").innerText

or

WebBrowser1.Document.getElementsByTagName("span").Item(0 /or 1/).innerText

should work.

[MarkT]

This will parse out the td tag after the tag containing U Case as it's text

Private Sub Command1_Click()
Dim strURL As String
Dim objHTML
Dim intPos As Integer
Dim strHTML As String


    strURL = "C:\Documents and Settings\Mark\Desktop\Confirm\Confirm.htm"
    Set objHTML = CreateObject("Microsoft.XMLHTTP")
    objHTML.open "GET", strURL, False
    objHTML.send
    
    strHTML = objHTML.responseText
    Set objHTML = Nothing
    
    
    'Find the U Code text and remove everything before it
    intPos = InStr(strHTML, "U Code")
    strHTML = Mid(strHTML, intPos)
    
    'Find the next td tag. This will hold the data you are after
    intPos = InStr(strHTML, "<td")
    strHTML = Mid(strHTML, intPos)
    
    'Find the closing td tag and remove everything after it
    intPos = InStr(strHTML, "</td>") + 4
    strHTML = Left(strHTML, intPos)
    
    'strip off everything after the value
    intPos = InStr(strHTML, "</") - 1
    strHTML = Left(strHTML, intPos)
    
    'remove everything before your value
    intPos = InStrRev(strHTML, ">") + 1
    strHTML = Mid(strHTML, intPos)
    
    'this should be the value you are looking for
    Text1.Text = strHTML
    
End Sub

EDIT: Finished the example

[westconn1]

you can try this,
MsgBox web1.document.All("ms__id6").innerText

[nasreen]

Thanks Mr. MarkT

Your idea is almost OK and is a solution for an extend.

For this web page it is good and working fine. My company is dealing with a number of services like this using different online money transfer web services. I don't know how far I can apply this idea for each web pages..

If I get an idea to find out the item number of the cell it will be the best solution for my problem

MsgBox web1.document.All("ms__id6").innerText

This code is not working with me. Can I know what is this ("ms__id6") ??

With regards
Nasreen

[westconn1]

unique id for that element, it returned the correct value for me

it should remain constant unless the page is redesigned

you can try like this

For Each ele In ie.Document.getelementsbytagname("Span")
 MsgBox ele.innertext
 Next

[nasreen]

Hi all,
Finally I got the idea that I look for. I would like to share with all

Private Sub Form_Load()
WebBrowser1.Navigate2 App.Path & "\Confirm.htm"
End Sub

Private Sub Command1_Click()
Dim ii As Integer
Dim docEl
Dim Ucode As String

 For Each docEl In WebBrowser1.Document.documentElement.All
        If docEl.tagName = "TR" Then
            For ii = 0 To docEl.Cells.Length - 1
                    If UCase(Trim(docEl.Cells(ii).innerText)) = UCase("Ucode:") Then
                        Ucode= Trim(docEl.Cells(ii + 1).innerText)
                    End If
            Next
        End If
    Next
    Text1.Text = Ucode
End Sub

With regards,
Nasreen