Run code from textbox

[masterkert3]

So,
I searched, and found a code.
I added scriptcontrol1 component(and also added in references)
I have this code:

scriptcontrol1.executestatement text1.text

when i enter "msgbox "test"" in text1 and press command1 button then it shows a messagebox
however
when i enter "form4.caption = "test"" then it shows error 424: object required form4

[dilettante]

You use the control's AddObject method to add host objects to the script's namespace.

A Google search should produce a number of introduction and tutorial articles.

[jmsrickland]

Do it like this. Instead of adding the script control add a reference to the Microsoft Script Control 1.0 in your project's references.

Option Explicit

Dim script As ScriptControl

Private Sub Command1_Click()
 script.ExecuteStatement Text1.Text
End Sub

Private Sub Form_Load()
 Set script = New ScriptControl
      
 script.Language = "VBScript"
 script.AddObject "Form1", Form1
   
 'Text1.Text = "MsgBox ""Hello"""
 'Text1.Text = "Form1.Command1.Caption = ""Hello"""

 Text1.Text = "Form1.Caption = ""Hello"""
End Sub

[masterkert3]

The above code works fine but how can I like, change variables?

I have

Public Type Player
Attack As Integer
Class As Integer
DeathCount As Integer
Defense As Integer
EXP As Integer
HP As Integer
KillCount As Integer
Level As Integer
MaxHP As Integer
Meteors As Integer
Money As Integer
Name As String
End Type

in a module.

But i can't use

Player.Name = "test"

[jmsrickland]

You will have to call a Sub that loads the fields of the UDT and you also need to dimension the UDT, which you didn't do.

[masterkert3]

how could i do it?

[jmsrickland]

In a Module add the following

  '
  '
Public Type Player
  Attack As Integer
  Class As Integer
  DeathCount As Integer
  Defense As Integer
  EXP As Integer
  HP As Integer
  KillCount As Integer
  Level As Integer
  MaxHP As Integer
  Meteors As Integer
  Money As Integer
  Name As String
End Type
  '
  '

In the Form add the following

  '
  '
Dim script As ScriptControl

Dim Players As Player

Private Sub Command1_Click()
 Text1.Text = "Sub CallLoadPlayers" & vbCrLf & _
              " '" & vbCrLf & _
              " ' This is the internal Sub that the VBScript Calls" & vbCrLf & _
              " '" & vbCrLf & _
              " LoadPlayers" & vbCrLf & _
              "End Sub"

 Set script = New ScriptControl
      
 script.Language = "VBScript"
 script.AddObject "Any text you want", Me, True
 script.AddCode Text1.Text

 '
 ' Run the Sub that is in the VBScript code
 '
 script.Run "CallLoadPlayers"
End Sub

Public Sub LoadPlayers()
 '
 ' This Sub us called by the VBScript in the Text1 Textbox
 '
 Players.Name = "test"
 '
 '
End Sub