Using a webbrowser control as a file browser

[agent]

Somebody mentioned to me that you could use the webbrowser control to browse for files. Setting the URL parameter to a local folder does this.

Now, does anybody know how to do anything with it, such as get the currently selected file(s)/folder(s), override the default double-click action (like open and save as windows do), and change the view style (details vs. large icon)?

[Deepak Sakpal]

Here is how you change the view style.

Imports System.Runtime.InteropServices
Imports System.Text
 
Public Class Form1
 
    Private Const LV_VIEW_ICON As Integer = &H0
    Private Const LV_VIEW_DETAILS As Integer = &H1
    Private Const LV_VIEW_SMALLICON As Integer = &H2
    Private Const LV_VIEW_LIST As Integer = &H3
    Private Const LV_VIEW_TILE As Integer = &H4
    Private Const EM_HIDEBALLOONTIP As Integer = &H1504
    Private Const LVM_SETVIEW As Integer = &H108E
 
    Private Const ListViewClassName As String = "SysListView32"
    Private Shared ReadOnly NullHandleRef As HandleRef = New HandleRef(Nothing, IntPtr.Zero)
 
    <DllImport("user32.dll", ExactSpelling:=True)> _
    Private Shared Function EnumChildWindows( _
        ByVal hwndParent As HandleRef, _
        ByVal lpEnumFunc As EnumChildrenCallback, _
        ByVal lParam As HandleRef _
    ) As Boolean
    End Function
 
    <DllImport("user32.dll", CharSet:=CharSet.Auto)> _
    Private Shared Function SendMessage( _
        ByVal hWnd As HandleRef, _
        ByVal Msg As UInteger, _
        ByVal wParam As Integer, _
        ByVal lParam As Integer _
    ) As Integer
    End Function
 
    <DllImport("user32.dll", CharSet:=CharSet.Auto)> _
    Private Shared Function RealGetWindowClass( _
        ByVal hwnd As IntPtr, _
        <Out()> ByVal pszType As StringBuilder, _
        ByVal cchType As UInteger _
    ) As UInteger
    End Function
 
    Private Delegate Function EnumChildrenCallback( _
        ByVal hwnd As IntPtr, _
        ByVal lParam As IntPtr _
    ) As Boolean
    Private listViewHandle As HandleRef
 
    Private Sub FindListViewHandle()
        Me.listViewHandle = NullHandleRef
        Dim lpEnumFunc As EnumChildrenCallback = New EnumChildrenCallback(AddressOf EnumChildren)
        EnumChildWindows(New HandleRef(Me.WebBrowser1, Me.WebBrowser1.Handle), lpEnumFunc, NullHandleRef)
    End Sub
 
    Private Function EnumChildren( _
        ByVal hwnd As IntPtr, _
        ByVal lparam As IntPtr _
    ) As Boolean
 
        Dim sb As StringBuilder = New StringBuilder(100)
        RealGetWindowClass(hwnd, sb, 100)
        If sb.ToString() = ListViewClassName Then
            Me.listViewHandle = New HandleRef(Nothing, hwnd)
        End If
        Return True
    End Function
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        WebBrowser1.Navigate("c:\")
    End Sub
 
    Private Sub Button1_Click( _
        ByVal sender As System.Object, _
        ByVal e As System.EventArgs _
    ) Handles Button1.Click
 
        Dim view As Integer
        FindListViewHandle()
        view = LV_VIEW_ICON
        SendMessage(Me.listViewHandle, LVM_SETVIEW, view, 0)
    End Sub
 
End Class

[Nerd44]

Hi!

I've done a complete Filebrowser, based on that.
On ActiveVB-Upload u can search for "filebrowser".

[agent]

Hi!

I've done a complete Filebrowser, based on that.
On ActiveVB-Upload u can search for "filebrowser".

Thank you very much for this, but I have one question first. I'm not at my development machine right now so I can't test this. Are properties provided for changing the view and/or allowing to filter files on a wildcard?

Here is how you change the view style.

Thanks for the code. I'll take a look at this when I can.

I'm still looking to see if there's another way to do this. I've posted a more broad question on this at http://www.vbforums.com/showthread.php?t=526311

[Nerd44]

Are properties provided for changing the view and/or allowing to filter files on a wildcard?

sorry, no.

[jtbjustin]

I am preforming a file copy when my form loads, and then trying to navigate to that local location, and then change my view.. When performing the file copy first, the view change does not sick.. Any ideas?

[Amerigo]

@ Deepak Sakpal... Can you provide similar coding to change sorting and grouping. All the above and sorting and grouping can be done with the context menu, but I want my app to load with directory contents automatically sorted by type.