Customising Common Dialogues

[jmcilhinney]

C# version here.

Someone posted a question recently asking how to set the initial location of a ColorDialog. I originally posted that it wasn't possible and you'd have to use the Windows API to get the window's handle and move it yourself. I recently discovered that that's not strictly true. You do have to work with unmanaged code but you can do it within a class derived from your common dialogue of choice. Here's an example that answers the aforementioned question:

Imports System.Runtime.InteropServices
 
''' <summary>
''' Extends the ColorDialog class and allows the initial location of the window to be specified.
''' </summary>
Public Class ColorDialogEx
    Inherits ColorDialog
 
#Region " Types "
 
    ''' <summary>
    ''' Defines values that can be assigned to the Flags field of a WindowPos object.
    ''' </summary>
    <Flags()> _
    Private Enum WindowPosFlags As UInteger
        NoResize = &H1
        NoMove = &H2
        NoZOrder = &H4
        NoRedraw = &H8
        NoActivate = &H10
        FrameChanged = &H20
        ShowWindow = &H40
        HideWindow = &H80
        NoCopyBits = &H100
        NoOwnerZOrder = &H200
        NoSendChanging = &H400
        DeferErase = &H2000
        AsyncWindowPos = &H4000
    End Enum
 
    ''' <summary>
    ''' Received as the lParam value when a WM_WINDOWPOSCHANGING message is received.
    ''' </summary>
    Private Structure WindowPos
        Public HWnd As IntPtr
        Public HWndInsertAfter As IntPtr
        Public X As Integer
        Public Y As Integer
        Public Cx As Integer
        Public Cy As Integer
        Public Flags As WindowPosFlags
    End Structure
 
#End Region 'Types
 
#Region " Constants "
 
    ''' <summary>
    ''' The message received when the window position is changing.
    ''' </summary>
    Private Const WM_WINDOWPOSCHANGING As Integer = &H46
 
#End Region 'Constants
 
#Region " Variables "
 
    ''' <summary>
    ''' The location at which the window will be initially displayed.
    ''' </summary>
    ''' <remarks>
    ''' If no value is assigned the window is displayed at the default location.
    ''' </remarks>
    Private initialLocation As Nullable(Of Point) = Nothing
 
#End Region 'Variables
 
#Region " Constructors "
 
    ''' <summary>
    ''' Creates a new instance of the ColorDialogEx class.
    ''' </summary>
    Public Sub New()
        MyBase.New()
    End Sub
 
    ''' <summary>
    ''' Creates a new instance of the ColorDialogEx class.
    ''' </summary>
    ''' <param name="initialLocation">
    ''' The location at which the window will be initially dispalyed.
    ''' </param>
    Public Sub New(ByVal initialLocation As Point)
        Me.New()
        Me.initialLocation = initialLocation
    End Sub
 
#End Region 'Constructors
 
#Region " Methods "
 
    ''' <summary>
    ''' Hooks into the common dialog's message queue.
    ''' </summary>
    ''' <param name="hWnd">
    ''' The handle to the native window.
    ''' </param>
    ''' <param name="msg">
    ''' The message received from the operating system.
    ''' </param>
    ''' <param name="wparam">
    ''' Message-specific data.
    ''' </param>
    ''' <param name="lparam">
    ''' Message-specific data.
    ''' </param>
    ''' <returns>
    ''' A zero value if the default dialog box procedure processes the message; a nonzero value if the default dialog box procedure ignores the message.
    ''' </returns>
    Protected Overrides Function HookProc(ByVal hWnd As System.IntPtr, _
                                          ByVal msg As Integer, _
                                          ByVal wparam As System.IntPtr, _
                                          ByVal lparam As System.IntPtr) As System.IntPtr
        'Trap the WM_WINDOWPOSCHANGING message if an initial location has been specified.
        If msg = WM_WINDOWPOSCHANGING AndAlso Me.initialLocation.HasValue Then
            'Get the data provided by the OS.
            Dim pos As WindowPos = DirectCast(Marshal.PtrToStructure(lparam, _
                                                                     GetType(WindowPos)),  _
                                              WindowPos)
 
            'Look for the specific combination of flags that indicates that
            'this is the appropriate message on which to set the location.
            If pos.Flags = (WindowPosFlags.NoResize Or _
                            WindowPosFlags.NoZOrder Or _
                            WindowPosFlags.NoActivate) Then
                With Me.initialLocation.Value
                    pos.X = .X
                    pos.Y = .Y
                End With
 
                'Make the new data available to unmanaged code.
                Marshal.StructureToPtr(pos, lparam, True)
            End If
        End If
 
        'Pass on the message.
        Return MyBase.HookProc(hWnd, msg, wparam, lparam)
    End Function
 
#End Region 'Methods
 
End Class

Note that there were six WM_WINDOWPOSCHANGING messages received before the window was fully loaded and I found the correct combination of flags by trial and error. That combination is received on the second of those six messages. If you try to set the location on any of the others it doesn't work. Note that this will also not prevent you moving the dialogue by dragging the title bar.

Adapting this idea you can trap any Windows message you want and then use the window's handle to manipulate it using unmanaged code. The HookProc method is a member of the CommonDialog class, so all classes derived from CommonDialog provide this functionality.

One final point to note here is that i've used a Nullable(Of Point) to store the initial location. If it has no value then the default location is used. In .NET 1.x you don't have Nullable types so you'd have to use two variables: one Point and one Boolean.

[jmcilhinney]

I should also point out, for those who don't realise, that you don't ever explicitly call the HookProc method. It will get invoked implicitly each time the common dialogue receives a message from the OS. All you have to do is create the object and specify the location, e.g.

Using dialogue As New ColorDialogEx(New Point(10, 20))
    If dialogue.ShowDialog() = Windows.Forms.DialogResult.OK Then
        Dim selectedColour As Color = dialogue.Color
 
        'Use selectedColour here.
    End If
End Using

[ljohnway]

Excellent sample.
Is there any way to apply this technique to OpenFileDialog, which is non-inheritable, or must I revert to Win32?

[jmcilhinney]

Excellent sample.
Is there any way to apply this technique to OpenFileDialog, which is non-inheritable, or must I revert to Win32?

Hmmm... I didn't realise that OpenFileDialog was NotInheritable. The only thing that comes to mind is inheriting the FileDialog class and reproducing the functionality of the OpenFileDialog yourself. I'm not sure how easy or practical that is though.