[RESOLVED] Check network path exists

[sgrya1]

Hi all,

I have searched but can't find an answer to this.

If I have a string containing a file path. eg "R:\Administration\Timekeeping\test.xls" How do I check that the path exists?

If the computer running the app is not connected to the network, and hence the path doesn't exist, then using this code

Public Function FileExists(strFilePath As String) As Boolean
    FileExists = False 'Assume the worst!
    'Make sure a filename was passed!
    If Len(strFilePath) > 0 Then
              'Check to see if the file exists!
              If Len(Dir$(strFilePath)) > 0 Then
                  'The file exists!
                  FileExists = True
              End If
    End If
End Function

If Len(Dir$(strFilePath)) > 0 Then

still creates an error "bad file name or number"

Can someone suggest a way of finding out whether or not a path exists?

[Hack]

You are correct, and there is no code in the world that will tell you the path exists if it doesn't. And, it doesn't exist for a particular machine if said machine is not connected to the network with the drive mapped and/or available to it.

[sgrya1]

I've just modified the FileExists Function slightly and it now appears to work.
Out of interest. Can this snippet of code now be significantly reduced? Got the feeling it can but I'm no expert and it might take some one a second to say it can while I'd spend a lot of time in trial and error to say it can't.

Public Function FileExists(strFilePath As String) As Boolean
   On Error GoTo FileExists_Error
    FileExists = False 'Assume the worst!
    'Make sure a filename was passed!
    If Len(strFilePath) > 0 Then
        'Check to see if the file exists!
        If Len(Dir$(strFilePath)) > 0 Then
            'The file exists!
            FileExists = True
        End If
    End If
   On Error GoTo 0
   Exit Function
FileExists_Error:
    If Err.Number = 52 Then
        FileExists = False
    Else
        MsgBox "Error " & Err.Number & " (" & Err.Description & ") on line " & Erl & " in FileExists of Module1"
    End If
End Function

[Hack]

Providing you have a network connection, that should work just fine.

[Edgemeal]

Wouldn't these work?

' file check

Public Function bFileExists(sFile As String) As Boolean
    On Error Resume Next
    bFileExists = ((GetAttr(sFile) And vbDirectory) = 0)
End Function

' folder check

Public Function bDirExists(sDir As String) As Boolean
    On Error Resume Next
    bDirExists = ((GetAttr(sDir) And vbDirectory) <> 0)
End Function

[lannyboy]

this is my clsFileFolder class

Option Explicit

Private Declare Function OpenFile Lib "kernel32" (ByVal lpFileName As String, lpReOpenBuff As OFSTRUCT, ByVal wStyle As Long) As Long

Private Const OFS_MAXPATHNAME = 128
Private Const OF_EXIST = &H4000

Private Type OFSTRUCT
    cBytes As Byte
    fFixedDisk As Byte
    nErrCode As Integer
    Reserved1 As Integer
    Reserved2 As Integer
    szPathName(OFS_MAXPATHNAME) As Byte
End Type

Public Function CheckNetworkExist(strFullPath As String) As Boolean

    Dim strResult
    Dim strucFname As OFSTRUCT
    
    If Left(strFullPath, 2) = "\\" Then
        strResult = OpenFile(strFullPath, strucFname, OF_EXIST)
        If strResult <> -1 Then
            CheckNetworkExist = True
        Else
            CheckNetworkExist = False
        End If
    End If
    
End Function

[fafalone]

You are correct, and there is no code in the world that will tell you the path exists if it doesn't. [...]

Sorry, can't resist

Public Function PathExists(path As String) As Boolean
    PathExists = True
End Function