[RESOLVED] System Tray Menu

[03myersd]

Well here is my third and hopefully last thread of the night.

I have searched for the last hour or so on google and here on the forum for a way to add an icon to the system tray that works as a menu. I have been unsuccessful. I'm looking for a nice easy way to do this. If anyone can help me it would be great. Thanks!!

[RhinoBull]

Would this for you?

[Static]

http://www.vbforums.com/showthread.p...tray+icon+menu

[03myersd]

I'm using the code that static suggested. But how do I give it a menu now. I know how to have a drop down menu at the top of the form. How do I do it for the tray icon though? Thanks.

[Static]

do you know how to make a popup menu?
basically create a menu with the top level visible = false
then call popupmenu "MenuName" from the mousedown event of the form (I think it was the form)

do a search here.. many examples are kickin around. Systray Popup menu

[03myersd]

Yeah I can do a popup menu.

[RobDog888]

In the Form_Mousedown event you would detect if the Button = 2 (right click) and if so then just popup your menu.

[03myersd]

How do I get it to pop up if I right click on the icon on the tray though?

[RobDog888]

As mentioned...

Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
    If Button = 2 Then
        Me.PopupMenu "MyMenu"
    End If
End Sub

[Joacim Andersson]

Which event you should write the code that shows the popup menu depends on what you've set the hWnd and uCallbackMessage members of the NOTIFYICONDATA structure to. For example, if you've set the hWnd member to the hWnd of your main Form and the uCallbackMessage to WM_MOUSEMOVE (which is the message I would recommend you to use). In that case the Form_MouseMove event will be fired everytime an event has happened on the icon. Which event that is (WM_MOUSEMOVE, WM_LBUTTONDOWN, WM_RBUTTONDOWN and so on) will then be stored in the X parameter of the event. If the ScaleMode of your Form is set to Twips you need to divide X with Screen.TwipsPerPixelX to get the correct value. So the code should look simular to this:

Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
    Dim nMsg As Long
    
    nMsg = X \ Screen.TwipsPerPixelX
    Select Case nMsg
        Case WM_RBUTTONDOWN
            'the right mouse button was pressed show the popup menu
            Me.PopupMenu mnuPop
    End Select
End Sub

[03myersd]

As mentioned...

Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
    If Button = 2 Then
        Me.PopupMenu "MyMenu"
    End If
End Sub

That only works if I right click on the form? It does nothing at all if I right click on the icon.

[RobDog888]

Like Joacim posted, it depends on what you set the callback.

[03myersd]

Callback?

Yeah i'm still a beginner at all this... Could you explain in more detail what i have to do please? This is the code that I am using:

Option Explicit

    Private Declare Function Shell_NotifyIcon Lib "shell32" Alias "Shell_NotifyIconA" (ByVal dwMessage As Long, pnid As NOTIFYICONDATA) As Long
    
    Private Type NOTIFYICONDATA
        cbSize As Long
        hWnd As Long
        uId As Long
        uFlags As Long
        ucallbackMessage As Long
        hIcon As Long
        szTip As String * 64
    End Type
    
    Private Const NIM_ADD = &H0
    Private Const NIM_MODIFY = &H1
    Private Const NIM_DELETE = &H2
    Private Const NIF_MESSAGE = &H1
    Private Const NIF_ICON = &H2
    Private Const NIF_TIP = &H4
    
    Private Const WM_LBUTTONDBLCLK = &H203
    Private Const WM_LBUTTONDOWN = &H201
    Private Const WM_RBUTTONUP = &H205
    
    Dim NID As NOTIFYICONDATA


Private Sub Form_Load()
Dim str As String

        With NID
            .cbSize = Len(NID)
            .hIcon = Me.Icon
            .hWnd = Me.hWnd
            .szTip = "Hello" & vbNullChar
            .ucallbackMessage = WM_LBUTTONDBLCLK
            .uFlags = NIF_MESSAGE Or NIF_ICON Or NIF_TIP
            .uId = 1&
        End With
        
        Shell_NotifyIcon NIM_ADD, NID
End Sub

Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
If Button = 2 Then
Form1.PopupMenu menumain
End If
End Sub

Thanks in advance.

[RobDog888]

Change the .ucallbackMessage from ".ucallbackMessage = WM_LBUTTONDBLCLK" to ".ucallbackMessage = WM_MOUSEMOVE".
Then use the code Joacim posted.

[03myersd]

It works!!! Thanks so much to both of you!!!!