How to SET the value of a Listview / Combobox item?

[belinea2003]

I can create a Listview with

Me.ListBox1.Items.Add("Name1")
Me.ListBox1.Items.Add("Name2")
Me.ListBox1.Items.Add("Name3")

But how can I set the values of each item?

When I select a Listview item, I want to read the value of the select item with ListBox1.SelectedValue. But I haven´t found a way to set the value of a item.

[Bulldog]

If it's a Listview;
ListView1.Items(0).Text = "NewString"

If it's a ListBox;
ListBox1.Items(0) = "NewString"

If it's a ComboBox;
ComboBox1.Items(0) = "NewString"

[belinea2003]

If it's a Listview;
ListView1.Items(0).Text = "NewString"

If it's a ListBox;
ListBox1.Items(0) = "NewString"

If it's a ComboBox;
ComboBox1.Items(0) = "NewString"

That changes only the displayed text of an item. But I need to change it´s value.

Or is it not possible to assign a value to a item ?

edit: It´s really impossible. But I think it could be done be a array. But how?

I have a listbox with Names and I must assign a telephonenumber to this entrys. So if I selected the name "Herbert Herbertson" I will get the telephon number of this selected person.

But I don´t know how to assign a telephone number to this ListBox, ComboBox entry.

[jmcilhinney]

The code you have shown in your first post simply adds strings to a ListBox. Strings don't have telephone numbers so in that sense your request doesn't make sense. If you bind a list of objects to the ListBox then you can do the sort of thing you are asking for. For instance, let's say that you have a Person class that has Name and PhoneNumber properties. You could create an array or collection of Person objects and bind them to the ListBox like this:

Dim people As New List(Of Person)
Dim person As New Person
 
person.Name = "John Smith"
person.PhoneNumber = "5551234"
 
people.Add(person)
 
Me.ListBox1.DisplayMember = "Name"
Me.ListBox1.DataSource = people

The list of Person objects is now bound to the ListBox and the Name of each item will be displayed. You can then change the PhoneNumber of the selected Person like so:

DirectCast(Me.ListBox1.SelectedItem, Person).PhoneNumber = "5559876"

[belinea2003]

Does not work for me. I got the error

Type 'Person' ist not defined.
Type 'Person' ist not defined.

[zalez]

The code you have shown in your first post simply adds strings to a ListBox. Strings don't have telephone numbers so in that sense your request doesn't make sense. If you bind a list of objects to the ListBox then you can do the sort of thing you are asking for. For instance, let's say that you have a Person class that has Name and PhoneNumber properties. You could create an array or collection of Person objects and bind them to the ListBox like this:

Dim people As New List(Of Person)
Dim person As New Person
 
person.Name = "John Smith"
person.PhoneNumber = "5551234"
 
people.Add(person)
 
Me.ListBox1.DisplayMember = "Name"
Me.ListBox1.DataSource = people

The list of Person objects is now bound to the ListBox and the Name of each item will be displayed. You can then change the PhoneNumber of the selected Person like so:

DirectCast(Me.ListBox1.SelectedItem, Person).PhoneNumber = "5559876"

jmc has hypothetically stating. You would have to create the "person" class with the two properties.

[bmahler]

Also am I wrong in thinking that you can set the ValueMember = "PhoneNumber" in this case as well. Thus removing the need to use the DirectCast line to get the phone number. like so

Dim people As New List(Of Person)
      Dim person As New Person
 
      person.Name = "John Smith"
      person.PhoneNumber = "5551234"
 
      people.Add(person)
 
      Me.ListBox1.DisplayMember = "Name"
      Me.Listbox1.ValueMember = "PhoneNumber"
      Me.ListBox1.DataSource = people

then you can just get the phone number by calling

Me.ListBox1.SelectedValue

To expand a little on that here is a working example
with this example the person's name will be displayed and the phone number is the value. Double-clicking the listbox will show the selected value.

Public Class Form1
 
    Private Class Person
        Private _Name As String
        Private _PhoneNumber As String
 
        Public Property Name() As String
            Get
                Return _Name
            End Get
            Set(ByVal value As String)
                _Name = value
            End Set
        End Property
 
        Public Property PhoneNumber() As String
            Get
                Return _PhoneNumber
            End Get
            Set(ByVal value As String)
                _PhoneNumber = value
            End Set
        End Property
    End Class
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Dim people As New List(Of Person)
        Dim person As New Person
        person.Name = "John Smith"
        person.PhoneNumber = "555-125-4456"
 
        people.Add(person)
 
        Me.ListBox1.DisplayMember = "Name"
        Me.ListBox1.ValueMember = "PhoneNumber"
        Me.ListBox1.DataSource = people
 
 
    End Sub
 
    Private Sub ListBox1_MouseDoubleClick(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles ListBox1.MouseDoubleClick
        MessageBox.Show(Me.ListBox1.SelectedValue)
    End Sub
 
End Class

[belinea2003]

Thanks bmahler. It´s working

So many code for such a easy thing.

[belinea2003]

A last question: How can I add more persons?

person.Name = "John Smith"
person.PhoneNumber = "555-125-4456
people.Add(person)
person.Name = "John Sinclair"
person.PhoneNumber = "777-125-4456
people.Add(person)
person.Name = "John Johnsen"
person.PhoneNumber = "999-125-4456
people.Add(person)

... doesn´t work.

[bmahler]

If you change the person class to accept the values in the new constructor it makes it quite easy. something like so

    Private Class Person

        Private _Name As String
        Private _PhoneNumber As String

        Public Sub New(ByVal Name As String, ByVal PhoneNumber As String)
            _Name = Name
            _PhoneNumber = PhoneNumber
        End Sub

        Public Sub New()

        End Sub

        Public Property Name() As String
            Get
                Return _Name
            End Get
            Set(ByVal value As String)
                _Name = value
            End Set
        End Property

        Public Property PhoneNumber() As String
            Get
                Return _PhoneNumber
            End Get
            Set(ByVal value As String)
                _PhoneNumber = value
            End Set
        End Property

    End Class

You can then easily add new ones like this

        Dim people As New List(Of Person)

        people.Add(New Person("John Smith", "555-125-4456"))
        people.Add(New Person("Joe Jones", "555-125-4587"))

        Me.ListBox1.DisplayMember = "Name"
        Me.ListBox1.ValueMember = "PhoneNumber"
        Me.ListBox1.DataSource = people

Also notice that I overloaded the New Constructor with one that accepts nothing as parameters. This is so that you can create an instance of the class without initially speciifying the name and phone number if desired.

[belinea2003]

PERFECT !!!!

Many, many, many, many thanks.

[belinea2003]

I need help again.

With

Me.ListBox1.SelectedValue

i can get the Phone number of the selected person in the ListBox. But how can I get the Name of the person of the current selected Person?

[bmahler]

use

Me.ListBox1.SelectedItem.ToString()

but you will need to override the ToString method of your class like so

    Private Class Person

        Private _Name As String
        Private _PhoneNumber As String

        Public Sub New(ByVal Name As String, ByVal PhoneNumber As String)
            _Name = Name
            _PhoneNumber = PhoneNumber
        End Sub

        Public Sub New()

        End Sub

        Public Property Name() As String
            Get
                Return _Name
            End Get
            Set(ByVal value As String)
                _Name = value
            End Set
        End Property

        Public Property PhoneNumber() As String
            Get
                Return _PhoneNumber
            End Get
            Set(ByVal value As String)
                _PhoneNumber = value
            End Set
        End Property

        Public Overrides Function ToString() As String
            Return _Name
        End Function

    End Class

[belinea2003]

Thanks.

[belinea2003]

Can I sort the people array list by name?

people.sort()

doesn´t work. It stops with error "InvalidOperationException"

[belinea2003]

No idea?

[belinea2003]

Really no way to sort the people alphabetically ?

[belinea2003]

I have another problem.

I can select a contact in the dropdown by it it´s telephone number

Me.listbox1.SelectedValue = "555-125-4587"

But I cannot select a contact in the dropdown by it´s name.

Me.listbox1.SelectedItem = "John Doe"

When I try this, the dropdown stays at the current selected entry.

Can you help me again bmahler? Thank you...

[techgnome]

That's because SelectedItem is expecting an object.... If you want to select by the name, then you need to do one of two things. 1) Set the text property of the listbox to the name you want to select (ah... it might be TextDisplayed, or something along those lines).... but I'm not 100% sure that works... the other thing to do is to loop through your collection to find the item, then set the SelectedItem to THAT....

As for sorting..... try just sorting the listbox... not the collection itself. Your people.sort isn't working because your collection doesn't know how to sort the objects because they are just that, objects. In order to sort your collection, you have to provide a way to sort it yourself. If what you are after is just getting the listbox to sort, just set the .Sorted property to true.

-tg

[belinea2003]

1) Set the text property of the listbox to the name you want to select (ah... it might be TextDisplayed, or something along those lines).... but I'm not 100% sure that works...

IT WORKS IT WORKS IT WORKS !!!! YEEEEEEEEEEEEEEEEEEEEAAAAAAH

The 50$ are yours!

If what you are after is just getting the listbox to sort, just set the .Sorted property to true.

The ComboDropdown hasn´t a .Sorted Property.

[techgnome]

Oh.. a combobox..... not a listbox.... I'll have to get back to you on that one.

-tg

[belinea2003]

1) Set the text property of the listbox to the name you want to select (ah... it might be TextDisplayed, or something along those lines).... -tg

This method doesn´t work when you try to select a contact that doesn´t exist in the dropdown.

If you try to select a contact with

Me.ComboDropdown.Text = "John Doe"

Visual Basic enters this name in the current selected position in the dropdown when the name is not found in the dropdown.

I think the only way to select a name is your second soluution (switch to all contacts in a loop).

[techgnome]

It should... depending on the ComboBox style.... if you change it from a dropdowncombo to a dropdownlist... it should work.... but it also depends on if you want the user to be able to type into it....

-tg