[2005] How to set applications opacity to 75% after application is inactive for 30sec

[Lerroy_Jenkins]

I want to set the application to gradually fade to 75% opacity - This I can do.

But, I want this event to happen only when the application has been inactive for 30 seconds.

So, I have 2 timers, 1 to count down from 30, when hits 0, second timer counts until opacity = 75%, this, I can do.

But, I want the 1st timer to be reset if the application is being used. Say, pressing a button, or the user is typing.

Any ideas guys?

L.Jenkins

[penagate]

You could use an event handler and attach it to a few relevant events.


edit: whoops, wrong language.

Me.KeyPreview = True
AddHandler Me.KeyDown, AddressOf doThings
AddHandler Me.Click, AddressOf doThings

For Each c As Control In Me.Controls
  AddHandler c.Click, AddressOf doThings
Next

[Lerroy_Jenkins]

Can you please expand on that code a little penagate? I dont understand what is happening.

[NPassero]

would you create your sub routine

doThings()
reset timer
set opacity

[zalez]

You could declare two variables. One as integer and one as boolean. See below, not the prettiest but it works.

 Dim isActive As Boolean = True
 Dim tick As Integer = 0

Private Sub TextBox1_TextChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles TextBox1.TextChanged 
        If isActive = False Then
            ChangeStatus()
        End If
        tick = 0
    End Sub

    Private Sub Timer1_Tick(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Timer1.Tick
        If tick = 30 Then
            ChangeStatus()
        Else
            tick = tick + 1
        End If
    End Sub

    Private Sub ChangeStatus()

        If isActive = False Then
            isActive = True
            Timer1.Enabled = True
            Me.Opacity = 1
            tick = 0
        Else
            Timer1.Enabled = False
            isActive = False

            Me.Opacity = 0.25

        End If
    End Sub

    Private Sub Form1_MouseDown(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles Me.MouseDown
        If isActive = False Then
            ChangeStatus()
        End If
    End Sub

[NPassero]

The only thing is that it won't handle all the controls on the form, only if the text is changed.. But you have the right idea with the CheckStatus() sub routine.

[penagate]

Can you please expand on that code a little penagate? I dont understand what is happening.

The KeyPreview property of the form allows it to receive keyboard events before its controls do.
AddHandler is a VB.NET statement used to attach an event handler to a particular event.

[zalez]

Dim isActive As Boolean = True
Dim tick As Integer = 0

Private Sub Timer1_Tick(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Timer1.Tick
        If tick = 30 Then
            ChangeStatus()
        Else
            tick = tick + 1
        End If
    End Sub

    Private Sub ChangeStatus()

        If isActive = False Then
            isActive = True
            Timer1.Enabled = True
            Me.Opacity = 1
            tick = 0
        Else
            Timer1.Enabled = False
            isActive = False

            Me.Opacity = 0.25

        End If
    End Sub

'Two resetTicks sub for different control signatures
    Private Sub ResetTick(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyPressEventArgs)
        tick = 0
        If isActive = False Then
            ChangeStatus()
        End If
    End Sub

    Private Sub ResetTick(ByVal sender As System.Object, ByVal e As System.EventArgs)
        tick = 0
        If isActive = False Then
            ChangeStatus()
        End If
    End Sub

    Private Sub Form1_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
        Me.KeyPreview = True
        AddHandler Me.KeyPress, AddressOf ResetTick
        AddHandler Me.Click, AddressOf ResetTick

        For Each c As Control In Me.Controls
            AddHandler c.Click, AddressOf ResetTick
        Next
    End Sub

Thank you Penagate for teaching me something