Timer issue on VB6

[kusky]

I need to place some kind of timer on a form so that it closes if left open for 30 minutes. Ive checked the timer out and can see that this can only be configured for 65 seconds.

Can someone help with how i go about keeping a form open for up to 30 minutes after it Loads?

[opus]

Welcome to the forum
Save the time when opening the form (timeformopened) and use the timer to check if the (actualtime-timeformopened) is more than 30 minutes. You could do this check every minute or so!

[krtxmrtz]

...and after every elapsed minute you can add 1 to a variable that keeps track of the accumulated minutes and check if it is more than 30.

[Ellis Dee]

Use the way opus described; it is better than counting.

[krtxmrtz]

Then you need the Timer function (or GetTickCount) to check the elapsed time every minute or whatever the timer (control) interval has been set to.

[Ellis Dee]

I was thinking of DateDiff, actually:

Option Explicit

Private mdtmLastActivity As Date

Private Sub Form_Load()
    mdtmLastActivity = Now()
End Sub

Private Sub Timer1_Timer()
    If DateDiff("n", mdtmLastActivity, Now()) >= 30 Then Unload Me
End Sub

Set the timer interval for anything between 10-60 seconds and you're good to go.

[Ellis Dee]

I notice the OP qualifies it with "if left open", meaning you don't want to close unless the user stopped responding. In that case, set the form's KeyPreview property to true, and add this:

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
    mdtmLastActivity = Now()
End Sub

Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
    mdtmLastActivity = Now()
End Sub

[kusky]

Thanks for all your help so far. I have tried the following...

I was thinking of DateDiff, actually:

Option Explicit

Private mdtmLastActivity As Date

Private Sub Form_Load()
    mdtmLastActivity = Now()
End Sub

Private Sub Timer1_Timer()
    If DateDiff("n", mdtmLastActivity, Now()) >= 30 Then Unload Me
End Sub

Set the timer interval for anything between 10-60 seconds and you're good to go.

...However the window closes after about 10 seconds.

Any Ideas?

[Ellis Dee]

That's odd; the code should work. Try changing the timer code to this and see what the msgbox says:

Private Sub Timer1_Timer()
    If DateDiff("n", mdtmLastActivity, Now()) >= 30 Then
        MsgBox DateDiff("n", mdtmLastActivity, Now()) & " minutes elapsed"
        Unload Me
    End If
End Sub

[kusky]

Wierdly it says

56554272 minutes have elapsed

[randem]

Not weird just incorrect coding, you were actually checking for minutes with the "n" parameter. What you want is this:

Option Explicit

Private mdtmLastActivity As Date

Private Sub Form_Load()
    mdtmLastActivity = Now()
    Timer1.Interval = 1000
    Timer1.Enabled = True
End Sub

Private Sub Timer1_Timer()
Dim Seconds As Long

    Seconds = DateDiff("s", mdtmLastActivity, Now())
    
    If Seconds >= 30 Then
        Unload Me
    End If
    
End Sub

or this

Option Explicit

Private mdtmLastActivity As Date

Private Sub Form_Load()
    mdtmLastActivity = Now()
    Timer1.Interval = 1000
    Timer1.Enabled = True
End Sub

Private Sub Timer1_Timer()
Static Seconds As Long

    Seconds = Seconds + 1
    
    If Seconds >= 30 Then
        Unload Me
    End If
    
End Sub

[Logophobic]

Ellis Dee's code is correct. Kusky is looking for an elapsed time of 30 minutes, not seconds.

Wierdly it says

56554272 minutes have elapsed

Apparently the mdtmLastActivity variable was either not initialized or not properly declared, as that number suggests that its value was zero (30 Dec 1899, 12:00:00 AM).

[randem]

Exactly why you should not use the date as a counter. If the date is reset the whole time changes. In the second way I posted a tick of the clock doesn't matter when the date is reset to anything.

[kusky]

I copied the code from elis again and this time it worked better(i must of declared the mdtmLastActivity incorectly), however i tested it for a minute and it closed after 34 seconds, any ideas why?

Option Explicit

Private mdtmLastActivity As Date

Private Sub Form_Load()
    mdtmLastActivity = Now()
    Timer1.Enabled = True
    Timer1.Interval = 1000
End Sub

Private Sub Timer1_Timer()
Static Seconds As Long

    Seconds = Seconds + 1
    If DateDiff("n", mdtmLastActivity, Now()) >= 1 Then
        Unload Me
        MsgBox DateDiff("n", mdtmLastActivity, Now()) & " minutes elapsed"
        Seconds = 0
    End If
    lblCount = Seconds
End Sub

[randem]

Possibly you should not use DateDiff in a timer...

[opus]

The code you (kusky) posted is a mixture of the code from EllisDee (datediff) and randem.
You create the Static Seconds and update it, but you don't use it for checking!
You use the DateDiff correctly, however you're telling the software to stop after one minute (which is something like 60 seconds AFAIK) and not 30 minutes. How did you stop the 34 seconds, exactly when the Form_lad was happening??
did you see the messagebox at all?, since this command is after Unload.Me I don't think so (it was the other way around in Ellis code!)

[kusky]

The code you (kusky) posted is a mixture of the code from EllisDee (datediff) and randem.
You create the Static Seconds and update it, but you don't use it for checking!
You use the DateDiff correctly, however you're telling the software to stop after one minute (which is something like 60 seconds AFAIK) and not 30 minutes. How did you stop the 34 seconds, exactly when the Form_lad was happening??
did you see the messagebox at all?, since this command is after Unload.Me I don't think so (it was the other way around in Ellis code!)

The reason my code has the seconds is simply for me to view something when im testing it.

I have found out that no matter when i open the form it will close when the system clock hits the first full minute. The Code does not wait for 1 minute after the form was opened.

IS the only way to make sure its full minutes to use what randem suggests and use seconds?

[krtxmrtz]

Sorry I haven't read all the posts but in case it may help, just place a timer in your form with interval set to e.g. 1000 (1 second) and paste this code:

Option Explicit
Private Declare Function GetTickCount Lib "kernel32" () As Long
Dim StartTime As Long
Dim EndTime As Long
 
Private Sub Form_Load()
 
    'Aplication must end after this
    'time (in minutes) has elapsed
    EndTime = 30
    'Convert to milliseconds
    EndTime = EndTime * 60 * 1000
    'Elapsed milliseconds since windows was started
    StartTime = GetTickCount
 
End Sub
 
Private Sub Timer1_Timer()
 
    'Is the elapsed time since application started
    'larger than the maximum allowed time?
    If GetTickCount - StartTime >= EndTime Then
        Unload Me
        End
    End If
 
End Sub

To avoid waiting, try to set EndTime to a small fraction of a minute to see how it works.

[Ellis Dee]

I have found out that no matter when i open the form it will close when the system clock hits the first full minute. The Code does not wait for 1 minute after the form was opened.

IS the only way to make sure its full minutes to use what randem suggests and use seconds?

No, DateDiff will work fine, although if you think the user might change the system time then go with randem's counter technique.

DateDiff() returns a 1 the moment the unit of time has changed. If you ask DateDiff() the difference in years between 12/31 and 1/1, it'll tell you a year has passed when in reality only a day has.

What that means is that you want to use the next size down whenever the value you're looking for is less than 10. When looking for 30 minutes, checking the DateDiff() minutes differential is fine. When looking for only a single minute, however, you'll want to check for 60 seconds:

If DateDiff("s", mdtmLastActivity, Now()) >= 60 Then

I dislike using counters because timer controls are unreliable. If the system is busy, timer controls don't bother to fire an event. Even worse is that timers don't "save up" missed events; they just flat out skip them. If you use the counter method and set a timer's interval for 60,000 as a way of counting minutes, then you just have to hope that each minute when the timer is about to fire your program doesn't happen to be busy.

Of course, that's the whole point of this thread -- tracking user inactivity -- but this is why I just don't like relying on timers to do any kind of calculation in general. So instead of counting intervals, I always opt for comparing the current time with the starting time.

To illustrate timers skipping iterations, create a project, add a command button and a timer control, then paste this into the form's module:

Option Explicit

Private Sub Command1_Click()
    MsgBox "Blocker - Timer1 is not firing"
End Sub

Private Sub Form_Load()
    Timer1.Interval = 1000
    Timer1.Enabled = True
End Sub

Private Sub Timer1_Timer()
    Static lngCount As Long
    
    lngCount = lngCount + 1
    Print lngCount & " seconds elapsed"
End Sub

Run it, then after a few seconds have gone by click the command button. Wait a few more seconds and then click the OK button on the messagebox.

[masterkert3]

i use this code to keep track of time elapsed

Private Sub Timer1_Timer()
Dim secs As Long
Dim mins As Long
Dim hour As Long
secs = Val(Text1.Text + 1)
Text1.Text = secs
If Text1.Text = 60 Then
Text1.Text = 0
mins = Val(Text2.Text + 1)
Text2.Text = mins
End If
If Text2.Text = 60 Then
Text2.Text = 0
hour = Val(Text3.Text + 1)
Text3.Text = hour
End If
End Sub

you could do a check like this:

if text2.text = 30 then
unload me
end if

and put it on a timer

[kusky]

All works great now. Thanks everyone for your help. I went with Ellis suggestion and works like a charm - thanks again

[krtxmrtz]

All works great now. Thanks everyone for your help. I went with Ellis suggestion and works like a charm - thanks again

Well, the code I posted in #18 is not having the problem that EllisDee refers to in #19 as it is based on the GetTickCount function. The timer may not fire but time is still being kept track of.

[Ellis Dee]

Well, the code I posted in #18 is not having the problem that EllisDee refers to in #19 as it is based on the GetTickCount function. The timer may not fire but time is still being kept track of.

Same basic idea as what I suggested. Using DateDiff (or the Timer function, which has the same precision as GetTickCount) has the added bonus of being native VB, so no API declarations are required.