Object variable or With block variable not set

[aikidokid]

I have this code below in the textbox Change event. It is part of an Auto-Complete code.
It all works ok, except when I try to change the textbox string to all three columns of the listview. This makes the Change event fire again and I get the error:

Object variable or With block variable not set

on this line:

lvwMembers.FindItem(txtSearch.Text, , , lvwPartial).Selected = True

My complete code is:

Private Sub txtSearch_Change()
On Error GoTo ErrTrap
 
Dim LvwItm As ListItem
Dim Strt As Integer
 
'If firing in response to a backspace or delete, don't run the auto-complete
'complete code. (Otherwise you wouldn't be able to back up.)
 
If blnBackSpace = True Or txtSearch.Text = vbNullString Then
     blnBackSpace = False
     Exit Sub
End If
 
'Run through the available items and grab the first matching one.
If lvwMembers.ListItems(lvwMembers.SelectedItem.index).EnsureVisible = True Then
    'search the first column (First Name)
    lvwMembers.FindItem(txtSearch.Text, , , lvwPartial).Selected = True
End If
 
'If something was chosen then we get the rest of it
Strt = Len(txtSearch.Text)
'add full name to txtSearch
If Len(lvwMembers.SelectedItem.SubItems(1)) = 0 Then
    txtSearch.Text = lvwMembers.SelectedItem.Text & " " & lvwMembers.SelectedItem.SubItems(2)
Else
    txtSearch.Text = lvwMembers.SelectedItem.Text & " " & lvwMembers.SelectedItem.SubItems(1) _
                                                 & " " & lvwMembers.SelectedItem.SubItems(2)
End If
txtSearch.SelStart = Strt
txtSearch.SelLength = Len(txtSearch.Text) - Strt
 
Exit Sub

[Ellis Dee]

The problem is that FindItem returns an object, and that object might legitimately be set to Nothing. So when you attempt to set a property of it to something, you'll get that error.

Generally speaking, I'm uncomfortable using any object until I've verified that it isn't Nothing. So I would do something like this:

Dim itm As MSComctlLib.ListItem

Set itm = lvwMembers.FindItem(txtSearch.Text, , , lvwPartial)
If Not itm Is Nothing Then
    itm.Selected = True
End If
Set itm = Nothing

An alternate (and more compact) way to go would be:

With lvwMembers
    Set .SelectedItem = .FindItem(txtSearch.Text, , , lvwPartial)
End With

This second way is nice because setting .SelectedItem = Nothing is a perfectly valid way to deselect the listview, and that's probably what you want if .FindItem returns Nothing anyway.

I'm not sure how well behaved the .SelectedItem object is if the listview supports multiple selections, though. If it does, using the .Selected property is the way to go.

[aikidokid]

Thanks Ellis Dee.

I couldn't get the second option to work, but I did get the first option, with a small change to work:

Set LvwItm = lvwMembers.FindItem(txtSearch.Text, , , lvwPartial)
If Not LvwItm Is Nothing Then
    'item found
    LvwItm.EnsureVisible
    LvwItm.Selected = True
Else
    'nothing to select
    LvwItm.Selected = False
End If
Set LvwItm = Nothing

The second part of the If statement - would this be correct to stop any selection if nothing is returned?

Thanks again.

[Ellis Dee]

No, it'll throw the same error (for the same reason) as in the OP. Instead, change the Else clause to this:

Set lvwMembers.SelectedItem = Nothing

The only other way to ensure no item is selected is to set up a For (Each) loop iterating all the list items, setting each one's .Selected property to False. Much more cumbersome, and much slower.

May I ask what the issue was with the second option? I don't see why the following wouldn't work, but my expertise is more for the similar TreeView control:

With lvwMembers
    Set .SelectedItem = .FindItem(txtSearch.Text, , , lvwPartial)
    If Not .SelectedItem Is Nothing Then .SelectedItem.EnsureVisible
End With

[aikidokid]

No, it'll throw the same error (for the same reason) as in the OP. Instead, change the Else clause to this:

Set lvwMembers.SelectedItem = Nothing

This throws the same error

May I ask what the issue was with the second option? I don't see why the following wouldn't work, but my expertise is more for the similar TreeView control:

With lvwMembers
    Set .SelectedItem = .FindItem(txtSearch.Text, , , lvwPartial)
    If Not .SelectedItem Is Nothing Then .SelectedItem.EnsureVisible
End With

With this I get the same error on the line starting"If Len"

With lvwMembers
    Set .SelectedItem = .FindItem(txtSearch.Text, , , lvwPartial)
    If Not .SelectedItem Is Nothing Then .SelectedItem.EnsureVisible
End With
 
 
'If something was chosen then we get the rest of it
Strt = Len(txtSearch.Text)
'add full name to txtSearch
If Len(lvwMembers.SelectedItem.SubItems(1)) = 0 Then
    txtSearch.Text = lvwMembers.SelectedItem.Text & " " & lvwMembers.SelectedItem.SubItems(2)
Else
    txtSearch.Text = lvwMembers.SelectedItem.Text & " " & lvwMembers.SelectedItem.SubItems(1) _
                                                 & " " & lvwMembers.SelectedItem.SubItems(2)
End If

[Ellis Dee]

Not to worry, that's easily fixable. Just remember that .SelectedItem is an object, so you need to always be sure it's valid before accessing its properties or methods. Try this:

With lvwMembers
    Set .SelectedItem = .FindItem(txtSearch.Text, , , lvwPartial)
    If Not .SelectedItem Is Nothing Then
        With .SelectedItem
            .EnsureVisible
            'If something was chosen then we get the rest of it
            Strt = Len(txtSearch.Text)
            'add full name to txtSearch
            If Len(.SubItems(1)) = 0 Then
                txtSearch.Text = .Text & " " & .SubItems(2)
            Else
                txtSearch.Text = .Text & " " & .SubItems(1) & " " & .SubItems(2)
            End If
        End With
    End If
End With

Note how .SelectedItem isn't accessed unless we've verified that it's valid. Also note that .SelectedItem simply begs to be referenced using a With...End With construct; the code reduces nicely when you don't have to write out the bulky object hierarchy each time. As an added bonus, it also executes faster.

[aikidokid]

Sorry if I am being a bit thick here, but the following is what I now have and I am now getting the error:

Method or Data member not found

on this line:

If Len(.SelectedItem.SubItems(1)) = 0 Then

My code in full now:

Private Sub txtSearch_Change()
On Error GoTo ErrTrap
 
Dim LvwItm As ListItem
Dim Strt As Integer
 
'If firing in response to a backspace or delete, don't run the auto-complete
'complete code. (Otherwise you wouldn't be able to back up.)
 
If blnBackSpace = True Or txtSearch.Text = vbNullString Then
     blnBackSpace = False
     Exit Sub
End If
 
With lvwMembers
    Set .SelectedItem = .FindItem(txtSearch.Text, , , lvwPartial)
    If Not .SelectedItem Is Nothing Then
        With .SelectedItem
            .EnsureVisible
            'If something was chosen then we get the rest of it
            Strt = Len(txtSearch.Text)
            'add full name to txtSearch
            If Len(.SelectedItem.SubItems(1)) = 0 Then
                txtSearch.Text = .Text & " " & .SubItems(2)
            Else
                txtSearch.Text = .Text & " " & .SubItems(1) & " " & .SubItems(2)
            End If
        End With
    End If
End With

[Ellis Dee]

Yeah, sorry about that, my bad. That's an honest to god bug that I introduced. I have since edited it out of the code in the post above.

The problem was that .SelectedItem was already included in the With construct, and I had it then referencing a .SelectedItem beneath that.

The literal value it was trying to interpret was:

lvwMembers.SelectedItem.SelectedItem.SubItems(1)

Which, unsurpisingly, threw an error.