[FAQ's: OD] How do I read/write to a document?

[RobDog888]

The methods of access to a Word document is done via the Document's .Content property, .Bookmark, .Section, .Page and .Paragraph objects. Also, the global object - Application.Selection.

Here's a couple of basic examples...

Word 2003 VB 6 Code Example (Read):

Option Explicit
 
Private Sub ReadStuff()
    
    Dim oApp As Word.Application
    Dim oDoc As Word.Document
    
    Set oApp = New Word.Application
    'Open an exisiting document
    Set oDoc = oApp.Documents.Open("C:\Document1.doc")
    oDoc.Activate
 
    'Multi-Line Textbox or RichTextBox control
    Form1.Text1.Text oDoc.Content
    oDoc.Close SaveChanges:=False
    Set oDoc = Nothing
    oApp.Quit
    Set oApp = Nothing
    
End Sub

[RobDog888]

Word 2003 VB 6 Code Example (Write):

Option Explicit
'Add a reference to MS Word xx.0 Object Library
Private Sub WriteStuff()
    
    Dim oApp As Word.Application
    Dim oDoc As Word.Document
    
    Set oApp = New Word.Application
    'Open either a blank new document or...
    Set oDoc = oApp.Documents.Add
    'open an exisiting document
    'Set oDoc = oApp.Documents.Open("C:\Document1.doc")
    oDoc.Activate
 
    'Move to the last line and add a new  line.
    oApp.Selection.GoTo What:=wdGoToLine, Which:=wdGoToLast
    oApp.Selection.TypeParagraph
    'Set a font size for our text
    oApp.Selection.Font.Size = 12
    'Enter in some meaningful text
    oApp.Selection.TypeText Text:="Meow,"
    'Turn the bold text format on
    oApp.Selection.Font.Bold = wdToggle
    'Enter in some text under the bold effect
    oApp.Selection.TypeText Text:="Meow,"
    'Turn bold formatting off
    oApp.Selection.Font.Bold = wdToggle
    'Turn italic formatting on
    oApp.Selection.Font.Italic = wdToggle
    'Increase the font size.
    oApp.Selection.Font.Size = 16
    'Enter in more text
    oApp.Selection.TypeText Text:="Meow"
    'Turn off formatting and revert size
    oApp.Selection.Font.Italic = wdToggle
    oApp.Selection.Font.Size = 12
    
    Set oDoc = Nothing
    Set oApp = Nothing
 
End Sub

[RobDog888]

Another method of writting contents to a Word document is by pasting the contents of the Windows Clipboard into your Word document.

Word 2003 VB 6 Code Example (Write):

Option Explicit
'Add a areference to MS Word xx.0 Object Library
Private Sub Command1_Click()
 
    Dim oApp As Word.Application
    Dim oDoc As Word.Document
    
    Set oApp = New Word.Application
    oApp.Visible = True
    Set oDoc = oApp.Documents.Add
    oDoc.Activate
    oDoc.Select
    oApp.Selection.Paste 'Pastes whatever is on the clipboard.
    'Clean up objects
    Set oDoc = Nothing
    Set oApp = Nothing
    
End Sub

[RobDog888]

Another method for converting a Word document into some other format.

VB 6 And Word 97-2007:

Option Explicit
'Add a reference to MS Word xx.0 Object Library
Private Sub Command1_Click()
    Dim oApp As Word.Application
    Dim oDoc As Word.Document
    Set oApp = New Word.Application
    'Open an exisiting document
    Set oDoc = oApp.Documents.Open("C:\Document1.doc")
    'Save it as some other format
    oDoc.SaveAs FileName:="C:\SomePath\SomeFile.txt", FileFormat:=wdFormatDOSTextLineBreaks  '(Or wdFormatDOSText)
    oDoc.Close SaveChanges:=False
    Set oDoc = Nothing
    oApp.Quit
    Set oApp = Nothing
End Sub