Help: Cmd Line Parse

[altf4]

OK I am looking for an API Function that can hopefully parse a command line and file path. If no API Exists to do this, does anyone have any simple functions to perform the task:

Example:

Dim sPath as String: sPath = "C:\Documents and Settings\something.exe -a -t -k -v"

Dim sFile as String: sFile = GetFile(sPath)
Dim sCmd as String: sCmd = GetCmd(sPath)

Making the following true:
sFile = "C:\Documents and Settings\something.exe"
sCmd = "-a -t -k -v"

So I need some file and command line parser either in WinAPI or some custom made function.
Anyone care to share a solution or idea. Feel Free. This has been bugging me for months.

[MartinLiss]

Dim sPath As String
Dim intStart As Integer
 
sPath = "C:\Documents and Settings\something.exe -a -t -k -v"
 
intStart = InStrRev(sPath, ".exe") + 4
 
MsgBox VBA.Left$(sPath, intStart)
MsgBox Mid$(sPath, intStart)

[Merri]

The proper format to have that line should be:

"""C:\Documents and Settings\something.exe"" -a -t -k -v"

Thus resulting into a string: "C:\Documents and Settings\something.exe -a -t -k -v

Windows always adds quotes around a filepath if it contains spaces. This is also true for parameters passed to the program. Now this allows us to use a QuoteSplit:

Public Function QuoteSplit(ByRef Expression As String, Optional ByRef Delimiter As String = " ", Optional ByVal Compare As VbCompareMethod = vbBinaryCompare) As String()
    Dim sParts() As String, N As Long
    sParts = Split(Expression, """")
    For N = 0 To UBound(sParts) Step 2
        sParts(N) = Replace(sParts(N), Delimiter, Delimiter & vbNullChar, , , Compare)
    Next N
    QuoteSplit = Split(Join(sParts, """"), Delimiter & vbNullChar)
End Function

And an usage example:

    Dim Parameters() As String

    Parameters = QuoteSplit("""C:\Documents and Settings\something.exe"" -a -t -k -v")

    ' now Parameters contains the following items:
    Parameters(0) = """C:\Documents and Settings\something.exe"""
    Parameters(1) = "-a"
    Parameters(2) = "-t"
    Parameters(3) = "-k"
    Parameters(4) = "-v"

And this should make your life easier