[RESOLVED] Saving and loading settings of listbox checkstyle?

[stevevb6]

Hi, i am wondering how to save and load settings in a listbox with checkbox style. I want to have it so the user can click a button "save setting" and the list is stored and the selected checkboxes for the list are stored, so when the user starts the program again, the click "load setting" and the list and checked boxs are loaded.

[Logophobic]

You would need to write the information to a file.

Private Sub cmdLoadList_Click()
  Dim strItem As String
  Dim blnChecked As Boolean
  Dim fnum As Integer
  
  On Error GoTo ErrHandler
  fnum = FreeFile
  Open App.Path & "\SavedList.txt" For Input As #fnum
  List1.Clear
  Do Until EOF(fnum)
    Input #fnum, strItem, blnChecked
    List1.AddItem strItem
    List1.Selected(List1.NewIndex) = blnChecked
  Loop
  Close #fnum
  Exit Sub
ErrHandler:
  If Err.Number = 53 Then
    MsgBox "No saved list was found."
  Else
    MsgBox "Unhandle error: " & Err.Number
  End If
End Sub
 
Private Sub cmdSaveList_Click()
  Dim fnum As Integer
  Dim i As Long
  
  fnum = FreeFile
  Open App.Path & "\SavedList.txt" For Output As #fnum
  For i = 0 To List1.ListCount - 1
    Write #fnum, List1.List(i); List1.Selected(i)
  Next i
  Close #1
End Sub

[stevevb6]

Thanks that works perfect. Sorry for taking so long, i got my new system! e6300, asus p5b-deluxe, 2x 1gb ocz gold xtc, 7600gt. Got a 16.434 seconds in superpi 1m at 500fsb on stock cooler! temps only hit 57 full load 4 hours.

[Hack]

If you consider this resolved, would you please pull down the Thread Tools menu and click the Mark Thread Resolved menu item? That will let everyone know that you have your answer.

Thank you.